シフトレジスタを２個にするときどうすればいいですか

Question

以下のサイトのプログラムを使用したのですが、シフトレジスタを増やす場合二進数の数を増やせばいいのでしょうか？
それとももっと簡単な手段があるのでしょうか。
シフトレジスタ制御

コード
#define SRCLK   (5)
#define RCLK    (6)
#define SER     (7)

void setup() {
  pinMode(SRCLK, OUTPUT);
  pinMode(RCLK,  OUTPUT);
  pinMode(SER,   OUTPUT);
}

// 点灯パターン(1=点灯, 0=消灯)
const uint8_t PATTERNS[] = {
  0b00000001,
  0b00000010,
  0b00000100,
  0b00001000,
  0b00010000,
  0b00100000,
  0b01000000,
  0b10000000,
};

void loop() {
  
  // 点灯パターンの数
  int max_pattern = sizeof(PATTERNS)/sizeof(PATTERNS[0]);

  for (uint8_t i=0; i<max_pattern; i++) {
    // 8ビット分のデータをシフトレジスタへ送る
    shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i]); 

    // シフトレジスタの状態をストレージレジスタへ反映させる
    digitalWrite(RCLK,  LOW);
    digitalWrite(RCLK,  HIGH);

    delay(200);
  }

Comments

[ikadzuchi]

「二進数の数を増や」すというのがどのようなことを指しているのか分かりません。
具体的にどのようなコードにしようとしているのかを書いてください。

[aoi729]

シフトレジスタが一つの場合
0b11111111
二つの場合
0b0000000011111111
のように、シフトレジスタを増やすたびに数を増やせば制御できるという浅はかな考えですが、この考えは間違ってますか？

[ikadzuchi]

まだいまいちどこをどう書き換えるつもりなのか分かりませんが、
少なくともshiftOut()関数の中身を変えないと駄目でしょうね。

[aoi729]

なるほど、いろいろ試してみます

Answer 1

単純にSN74HC595をArduinoに2系統つなぐ場合、
例えば8,9,10ピンを使うとしたら、こんな感じかなと思います。

#define MAX_CH 2

const uint8_t SRCLK[MAX_CH] = { 5,  8 };
const uint8_t RCLK[MAX_CH]  = { 6,  9 };
const uint8_t SER[MAX_CH]   = { 7, 10 };

void setup() {
    for(int ch = 0;ch < MAX_CH;ch++){
        pinMode(SRCLK[ch], OUTPUT);
        pinMode(RCLK[ch],  OUTPUT);
        pinMode(SER[ch],   OUTPUT);
    }
}

// 点灯パターン(1=点灯, 0=消灯)
const uint16_t PATTERNS[] = {
  0b0000000000000001,
  0b0000000000000010,
  0b0000000000000100,
  0b0000000000001000,
  0b0000000000010000,
  0b0000000000100000,
  0b0000000001000000,
  0b0000000010000000,
  0b0000000100000000,
  0b0000001000000000,
  0b0000010000000000,
  0b0000100000000000,
  0b0001000000000000,
  0b0010000000000000,
  0b0100000000000000,
  0b1000000000000000,
};

void loop()
{
    // 点灯パターンの数
    int max_pattern = sizeof(PATTERNS)/sizeof(PATTERNS[0]);

    for (uint8_t i=0; i<max_pattern; i++) {
        // 8ビット分のデータをシフトレジスタへ送る
        for(int ch = 0;ch < MAX_CH;ch++){
            shiftOut(SER[ch], SRCLK[ch], LSBFIRST, PATTERNS[i] >> (8*ch)); 
        }

        // シフトレジスタの状態をストレージレジスタへ反映させる
        for(int ch = 0;ch < MAX_CH;ch++){
            digitalWrite(RCLK[ch],  LOW);
            digitalWrite(RCLK[ch],  HIGH);
        }

        delay(200);
    }
}

74HC595を使ってarduinoの16ビットパラレル出力に挑んでみた
みたいにArduinoとの接続が1系統でキャリービットもう1系統につなぐ場合は
shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i]);
shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i] >> 8);
とすればいいと思います。

Comments

[aoi729]

ありがとうございます！とても分かりやすく参考になります。

[aoi729]

二進数で場所をしていると思うのですが、十進数で指定することなど可能ですか？

[nomuken]

可能です。
例えば　0b00010000　と書いてある箇所は　16と書いてもいいですし、0x10と書いてもいいです。

[aoi729]

なるほど、わかりました！
あと、一系統でする場合、
shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i]);
shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i] >> 8);
このプログラムを
私が提示したプログラムに付け加えたらいいのですか、それともあなたが提示したプログラムに付け加えればいいのですか？

[nomuken]

aoi729さんのコードに付け加えてください。y_waiwaiさんが回答した内容と同じになります。

[aoi729]

お久しぶりです！無事、シフトレジスタを、二個制御できました！
次、五個制御にチャレンジしたいのですが、同じshift Outのところを変更すればいいのですか？

[nomuken]

はい。shiftOutを２回呼び出していたところを５回呼び出してください。40bitのデータの持ち方についてはご自身で検討ください。

Answer 2

 
// 点灯パターン(1=点灯, 0=消灯)
const uint16_t PATTERNS[] = {
  ...
};

void loop() {

  // 点灯パターンの数
  int max_pattern = sizeof(PATTERNS)/sizeof(PATTERNS[0]);

  for (uint8_t i=0; i<max_pattern; i++) {
    // 16ビット分のデータをシフトレジスタへ送る
    shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i]>>8); 
    shiftOut(SER, SRCLK, LSBFIRST, PATTERNS[i]&0xff); 

    // シフトレジスタの状態をストレージレジスタへ反映させる
    digitalWrite(RCLK,  LOW);
    digitalWrite(RCLK,  HIGH);

    delay(200);
  }

これで１６ビット分

Comments

[y_waiwai]

ちと勘違いしてたんで修正

[aoi729]

プログラムの提示ありがとうございます！
参考にさせてもらいます！

[aoi729]

shiftOutの>>8と＆0xffの関係性を教えてください！