2つのエクセルファイルに2次元配列の貼り付け

Question

前提・実現したいこと

excelVBAを使い、２つのエクセルファイルに2次元配列を書き込みたいです。

VBAが書き込まれている実行する用のexcelファイルと、記録用のexcelファイルの二つがあり、
両方のファイルのシートに2次元配列を用いて書き込みを行いたいのですが、
”Worksheets("Sheet1").Range(Cells(1, 1), Cells(3, 1)).Value = tmp”
の部分で、実行する用のexcelファイル（自分自身）のシートの指定ができず、書き込みが行えません。
何かいい方法はないでしょうか？

※補足1
セルの範囲を指定する際には変数を使いたいので、Rangeとcellを組み合わせて範囲指定を行いたいです。

該当のソースコード

Sub test()
    
    Dim tmp() As Variant
    ReDim tmp(2, 0)

    'excelファイルを開く
    Dim wb As Workbook
    Set wb = Workbooks.Open("C:\～\test1.xlsx")
    
    tmp(0, 0) = "A"
    tmp(1, 0) = "B"
    tmp(2, 0) = "C"
    
    'シートに配列tmp()を貼り付ける
    wb.Worksheets("Sheet1").Range(Cells(1, 1), Cells(3, 1)).Value = tmp
    Worksheets("Sheet1").Range(Cells(1, 1), Cells(3, 1)).Value = tmp
    
    'excelファイル(DB用)を閉じる
    wb.Close SaveChanges:=True
 
End Sub

Answer 1

解決済みですか、こんな方法もあるということを覚えておくと有益だと思いますので、

With ステートメントを使うと変数宣言することなく、シンプルに記述できます。

With ステートメント (VBA) | Microsoft Docs

Dim wb As WorkBook: Set wb = Workbooks.Open("C:\～\test1.xlsx")

With wb.Worksheets("Sheet1")
    .Range(.Cells(1, 1), .Cells(3, 1)).Value = tmp
End With

With ThisWorkbook.Worksheets("Sheet1")
    .Range(.Cells(1, 1), .Cells(3, 1)).Value = tmp
End With

あるいは、

Dim wb As WorkBook: Set WB = Workbooks.Open("C:\～\test1.xlsx")
wb.Worksheets("Sheet1").Range("A1").Resize(3).Value = tmp
ThisWorkbook.Worksheets("Sheet1").Range("A1").Resize(3).Value = tmp

Comments

[Kazu_p8619]

ご回答いただきありがとうございます

Answer 2

「実行する用のexcelファイル」は自分自身ということですよね?
以下とすればよいのでは?

Worksheets("Sheet1").Range(Cells(1, 1) …
↓
ThisWorkBook.Worksheets("Sheet1").Range(Cells(1, 1) …

追記 ------------------

ああ、すいません。
test1.xlsx をオープンすることで test1.xlsxにActivateが移動して
しまっていますので、cellsにも修飾が必要でした。

cellsに対しても同じ記述をすればよいのですが、記述がゴチャゴチャ
してしまいますので、以下のいずれかを試してみてください。

(1)ActivateをThisworkBookのsheet1に切り替えてから操作する

ThisWorkbook.Worksheets("Sheet1").Activate
Range(Cells(1, 1), Cells(3, 1)).Value = tmp

(2)Worksheetを変数に入れて使う

Dim self As Worksheet: Set self = ThisWorkbook.Worksheets("Sheet1")
self.Range(self.Cells(1, 1), self.Cells(3, 1)).Value = tmp
Set self = Nothing

Comments

[Kazu_p8619]

ご回答ありがとうございます。
「実行する用のexcelファイル」というのは自分自身ということです。
試してみたのですがThisWorkBookを付け足すとエラーが出てしまいます。

[Kazu_p8619]

エラー内容は
エラー 1004 アプリケーション定義またはオブジェクト定義のエラーです。
です。

[h.horikoshi]

コメント欄だとコードが書けないため、回答のほうに追記しました

[Kazu_p8619]

ご丁寧にありがとうございます。
どちらの方法も試してみたところ、どちらもうまくいきました！
とても助かりました。ありがとうございます。