【Arduino】特定文字での文字列の分割(split関数に似たもの)

Question

やりたいこと

Arduinoで特定文字での文字列の分割したいです。
func関数は元の文字列、分割文字、indexを受け取ってindexに沿った文字列を返します。
分割数に指定はなく、分割文字がいくつでも結果を返せる関数です。

完成例1:
String str = "Arduino ok";
String part0 = func(str,' ',0);   //結果part0 = Arduino
String part1 = func(str,' ',1);   //結果part1 = ok

完成例2：
String str = "Arduino ok hallo";
String part0 = func(str,' ',0);   //結果part0 = Arduino
String part1 = func(str,' ',1);   //結果part1 = ok
String part2 = func(str,' ',2);   //結果part2 = hallo

ソースコード

#include <stdio.h>
#include <string.h>

char recieveData[256];
char sendData[256];
int count = 0 ;

String Func(String data, char separator, int index)
{
    int found = 0;
    int strIndex[] = {0, -1};
    int maxIndex = data.length();
    int endcheck = false;
    
    for(int i=0; i < maxIndex; i++){
        if( data.charAt(i) == separator ){
            found++;
            if ( found == index ){ strIndex[0] = i+1; }
            if ( found == index+1 ){ strIndex[1] = i; endcheck=true; }
            if(endcheck){ break; }
        }
    }
    //確認用
    Serial.print("Func関数の確認: ");
    Serial.print("found" + String(found) + " ");
    Serial.print("index" + String(index) + " ");
    Serial.print("strIndex[0]:" + String(strIndex[0]) + " ");
    Serial.println("strIndex[1]:" + String(strIndex[1]));
    return (strIndex[1]==-1) ? data.substring(strIndex[0]) : data.substring(strIndex[0], strIndex[1]);
}
//分割文字の数
int Keywordcounter(String Original,char Keyword) {
    int Keywordcount = 0;
    for (int i = 0; i < Original.length(); i++){
        if (Original.charAt(i) == Keyword) { Keywordcount++; }
    }
    return Keywordcount;
}

void Check_command(String command) {
    String part[] = {"\0"}; // 分割された文字列を格納する配列
    char buf[256];
    
    command.remove(command.length()-1);   //'\n'を消去
    Serial.println("分割前確認：" + String(command));

    //分割文字の数
    int count = Keywordcounter(command, ' ');

　　//文字列 = Func(元の文字列,分割文字列,分割した後何番目の文字列か)
    for (int i = 0; i < count+1; i++){
        part[i] = Func(command,' ',i);
    }

    Serial.print("分割後確認 ");
    for (int i = 0; i < count+1; i++){
        Serial.print(String(i) + ":" + part[i] + " "); 
    }
    Serial.println("");
    Serial.println("");
}

void setup() {
    Serial.begin(9600);//シリアル通信のレートを9600に設定 
}

void loop() {
    if (Serial.available()) {
        recieveData[count] = Serial.read(); // 文字列受信 
        if (count > 30 || recieveData[count] == '\n') {
            Check_command(String(recieveData));
            for (int i =0; i <= count; i++) { recieveData[count] == '\0'; }
            count=0;
        } else { count++; }
    }
}

実行結果

分割文字が1文字の場合は成功しますが、2個以上の場合うまくいきません。

Comments

[t_obara]

foundが0なので、Funcに渡されたdataの内容を確認してみては？

Answer 1

まず気のついたところを

String part[] = {"\0"}; // 分割された文字列を格納する配列

これでは、partの中身はこの文字列分しか確保されません
これではまずいですね

String part[1] = {"\0"};

ってことで、
part[1]="なんちゃら";
とするとアクセス違反です

Comments

[退会済みユーザー]

ありがとうございます。

int count = Keywordcounter(command, ' ');　の後で、
String part[count+1];
と宣言したらおおよそ直りました。

他にも悪いところがあったようで、
void loop()内も以下のように修正したら完全に良くなりました。
誤：　for (int i =0; i <= count; i++) { recieveData[count] == '\0'; }
正：　for (int i =0; i <= count; i++) { recieveData[i] = '\0'; }

Answer 2

y_waiwaiさんご指摘のところを直せばそれっぽく動きますね。配列の範囲外への書き込みでいろいろデータ破壊が起こっているのでしょう。

void Check_command(String command) {
  //String part[] = {"\0"}; // これはやめる
<略>

  //分割文字の数
  int count = Keywordcounter(command, ' ');
//どちらかでpartの配列の要素数をcount個に宣言
  String* part = new String[count];
  //String part[count + 1];
 <略>
  delete[] part; //newで配列を作ったときはdeleteしておく
}

とかなんとか。
(書いてるうちに解決済になっちゃった。receiveData[count]は気が付かなかった...)

それはともかく、String::indexOf()という関数があるのだから使いませんか。

    for(int i=0; i < maxIndex; i++){
        if( data.charAt(i) == separator ){

のループは

  for (int i = 0; i < index ; i++) {
    strIndex[0] = data.indexOf(separator, strIndex[0])+1;
  }
  strIndex[1] = data.indexOf(separator, strIndex[0]);

で用が足りるし、Keywordcounter()関数も

//分割文字の数
int Keywordcounter(String Original, char Keyword) {
  int Keywordcount = 0;
  int sep = 0;
  while ( (sep = Original.indexOf(Keyword, sep)) > 0) {
    Keywordcount++;
    sep++;
  }
  return Keywordcount;
}

とか書けます。
あ、あと直してませんが、charの値にKeywordという名前はちょっと不適切な感じがします。