ExcelVBAで電卓を作ろうとしたのですが減算の値の処理がうまくいきません

Question

ExcelVBAで電卓を作ろう-その3 「コードを書こう」 - パソコンカレッジ　スタッフのひとりごと

のサイトを拝見し、ExcelVBAを用いた電卓の作成を試みました。
コードは上記サイトの手順通りに作成（というか全て引用なのですが…）しまして、なんとかExcel上で形にはなりました。作った電卓のファイルはこちらにあります。

ただ、実際に動かしてみますと…下記のような不具合が起き、普通の電卓のような挙動になりません。

―――――――――――――――――
・「-」「5」と入力しているのに、結果の画面上には「5」のみしか表示されません。
・「-」「5」「×」「-」「5」「=」と入力すると、2つ目の「-」の時点で「25」という値になり、最後の「=」で、20という値が出てきてしまいます。（正しくは「=」を押した後に「25」ですが）
―――――――――――――――――

VBAのどこをどう修正すれば、これらの問題を解決できるのかにつきまして、試行錯誤しても判らず…「Case Act.Minus」「Private Sub Minus_Click()」の辺りを直せばいけそうな気もするのですが…。

お力添えをいただけますと助かります。よろしくお願い致します。

※コードをリンク先ではなく、ここに貼り付けます。

ユーザーフォーム

Option Explicit

Private NumBtn(0 To 9) As New Class1
Private stack(0 To 1) As Currency
Private Action As Integer

Private Enum Act
    Equal
    Plus
    Minus
    Multi
    Devi
End Enum

Private Sub UserForm_Initialize()

    'インスタンスの生成
    Dim i As Integer
    For i = 0 To 9
        NumBtn(i).NewClass Controls("b" & i), i
    Next

    '表示設定
    TextBox1.Text = 0

    '初期化処理
    InitCalc

End Sub


Private Sub InitCalc()
    '初期化処理

    'スタックと記号の初期化
    stack(0) = 0
    stack(1) = 0
    Action = Act.Plus

    '表示クリアフラグの初期化
    IsNew = True

End Sub

Private Sub Calc(ByVal CurrentAction As Integer)
    '計算処理（記号ボタンが押されると呼び出される）

    '電卓窓の数字を変数に格納
    Dim n As Long
    n = CLng(TextBox1.Text)
    stack(1) = n

    '計算結果を格納する変数
    Dim Ans As Double

    Select Case Action
        Case Act.Equal
            '=
            Action = Act.Equal
        Case Act.Plus
            '+
            Ans = stack(0) + stack(1)
            stack(0) = Ans
            stack(1) = 0
            TextBox1.Text = Ans
        Case Act.Minus
            '-
            Ans = stack(0) - stack(1)
            stack(0) = Ans
            stack(1) = 0
            TextBox1.Text = Ans
        Case Act.Multi
            '*
            Ans = stack(0) * stack(1)
            stack(0) = Ans
            stack(1) = 0
            TextBox1.Text = Ans
        Case Act.Devi
            '/
            If stack(1) = 0 Then
                Ans = 0
            Else
                Ans = stack(0) / stack(1)
            End If
            stack(0) = Ans
            stack(1) = 0
            TextBox1.Text = Ans
    End Select

    '引数で受け取った記号を格納
    Action = CurrentAction
    '新規入力にする
    IsNew = True

End Sub

Private Sub Plus_Click()
    '足し算

    'サブプロシージャの呼び出し
    Calc Act.Plus

End Sub


Private Sub Minus_Click()
    '引き算

    'サブプロシージャの呼び出し
    Calc Act.Minus

End Sub


Private Sub Multi_Click()
    '掛け算

    'サブプロシージャの呼び出し
    Calc Act.Multi

End Sub

Private Sub Devi_Click()
    '割り算

    'サブプロシージャの呼び出し
    Calc Act.Devi

End Sub

Private Sub btnEnter_Click()
    '＝の処理

    'サブプロシージャの呼び出し
    Calc Act.Equal

End Sub
Private Sub btnAC_Click()
    'ACボタンの処理

    TextBox1.Text = 0

    '初期化処理
    InitCalc

End Sub

標準モジュール

Option Explicit

Public IsNew As Boolean

Public Sub ShowCalc()
    frmCalc.Show
End Sub

クラスモジュール

Option Explicit

'イベントを持つコマンドボタン型の変数を宣言
Private WithEvents Btn As MSForms.CommandButton
'ボタンの数字を格納する変数を宣言
Private Index As Integer

Public Sub NewClass(ByVal c As MSForms.CommandButton, _
                    ByVal i As Integer)
    'いわゆるコンストラクタ処理

    '引数のコマンドボタンを変数に格納
    Set Btn = c
    'コマンドボタンの数字を変数に格納
    Index = i
End Sub

Private Sub Btn_Click()
    '数字のボタン（0～9)を押した時の処理

    'frmCalcフォームのTextBox1に、
    '変数Indexの中身を表示する

    If IsNew Then
        '数字の新規入力時
        frmCalc.TextBox1.Text = Index
    Else
        '数字の入力途中
        frmCalc.TextBox1.Text = _
                CLng(frmCalc.TextBox1.Text & Index)
    End If

    '数字の入力途中にする
    IsNew = False
End Sub

Comments

[hatena19]

URLは、ツールバーの[リンクの挿入]で、リンクにしてください。
コードは、gist へのリンクではなくツールバーの[<code>]で挿入してください。
質問の書き方は下記を参考にしてください。
https://teratail.com/help/question-tips#questionTips3-7

[hatena19]

最初のリンク先のコードと、gist のコードはまったく別物です。
gist のコードの方の参考にしたリンク先を提示してください。

[ControlSource]

すみません初めての質問で、ルールを十分把握しておりませんでした。読みみにくく申し訳ないです。
修正してみました。他に不十分な点がありましたら、お手数ですがご指摘のほど、よろしくお願い致します。

[hatena19]

参考にしたページは下記ではないですか。
https://blog.goo.ne.jp/pc_college/e/7a8247554435af7d4d139cb65f54c752

質問の最初のリンク先を上記に変更しておいてください。

[ControlSource]

そうでした、失礼しました！

Answer 1

引き算の-と符号としてのマイナスは、別のボタンに役割を分けないとだめじゃないですかね？
シャープ電卓
カシオ電卓
符号反転(+/-)キーの追加

Comments

[Zuishin]

「+-」ボタンは正負反転のためのボタンで、普通の電卓ではマイナスボタンでもマイナス入力できるんじゃないかと思います。

[ControlSource]

ご回答ありがとうございます。そうですね。符号反転ボタンというのは馴染みがないので…できるだけ、普通の電卓に近付けたいと考えております。

[mattuwan]

普通の電卓で、
「-」「5」「×」「-」「5」と押すと、-10になりました。
単に0-5　→　-5
-5-5　→　-10
と計算されて×の操作はやり直しとして無効になるようです。
やはりマイナスの計算があるときはサインチェンジキーでマイナスの符号をつけるのが、
普通の電卓の使い方のようです。

http://www.sguc.ac.jp/i/st/learning/statistics/calculator/index1.pdf

[mattuwan]

まぁ、自作するんだから、自分で仕様を決めちゃってもいいのでしょうが、
引き算の記号は表示しない仕様なら、マイナスの表示をしたいときは別途ボタンを用意しないと、
おかしなことになるような気がします。

Answer 2

指摘したいことがいっぱいあるが、とりあえずは、下記の点を修正することから、始めてください。

Calcプロシージャ内で、下記のように変数を宣言してますが、

    '電卓窓の数字を変数に格納
    Dim n As Long


    '計算結果を格納する変数
    Dim Ans As Double

「-」は数値ではないので、数値がだの変数には格納できません。
また、Long では小数も格納できません。

「-」「.」を電卓窓に表示させたいのなら、String型にする必要があります。

演算するとき(「=」をクリックしたとき)に、Val関数で数値に変換して演算するか、
あるいは Application.Evaluate を使えば String型 のまま演算できます。

Comments

[ControlSource]

hatena19さんありがとうございます、そうだったんですね。
修正してみます。「=」を押した後ですね。

電卓窓で「-」「5」「×」「-」と押すと、イコールを押す前に「25」と出てきます。
この段階では「-」（2つ目の値の符号）だけ、電卓に表示されるべきだと思うのですが。
「=」を押す前に、なぜ「25」が出てくるのかというのも判らなく、どう修正すれば正しく動いてくれるのか悩んでおります。

[hatena19]

回答する前に下記に点について確認させてください。
この電卓プログラムは、プログラミングの勉強の為ですか。
それとも、実用性を目指して作成していますか（運用中に、実際に使うことがある。）
実用性を目指すなら、無理に実際の電卓に近づける必要性はないように思います。
電卓のように狭い画面に縛られることはないので。
例えば、電卓窓には、
「-5*-5」というように入力した通りに表示させて、「=」のクリックで、
TextBox1.Text = Application.Evaluate("-5*-5")
とすれば 25 と表示されます。
こちらの方がコードがシンプルだし、途中式を表示されるので入力間違いを確認しやすくて実用的だと思いますが。

[ControlSource]

実用性ではなく、プログラミングの勉強の為になります。
本物の電卓のように、小数点の計算や関数電卓のようなことはでもなくていいので、四則演算ぐらいができるものが作れたらと考えております。

[hatena19]

四則演算に関しては、自作しなくても上記の Application.Evaluate を使えば簡単にできます。
勉強のために四則演算も自作するというのなら、回答にも書いたように、String型変数に入力値を格納するようにしないと、「-」とか「.」を電卓窓に表示できません。まずは、電卓窓に マイナスや小数を表示できるところまでトライしてみてください。演算はそれからです。