複数行選択しているセルの最初と最後の行と列の取得の仕方

Question

選択しているセルの最初の列行と最後の列行を取得する方法を教えてください。

やりたいこととしては、
VBAを作成していて、下記を埋める時に

    For i =　選択している最初の行　to 選択している最後の行
    For j =　選択している最初の列　to 選択している最後の列

としたいです。

例としては、
A1からC3まで選択していたら・・・

    For i =　1　to 3
    For j =　1　to 3

となるような感じです。

Answer 1

    Dim i As Long, j As Long
    
    With Selection
        For i = .Cells(1, 1).Row To .Cells(.Rows.Count, 1).Row
            For j = .Cells(1, 1).Column To .Cells(1, .Columns.Count).Column
                Debug.Print i; j
            Next
        Next
    End With

という感じかな？

選択範囲すべてのセルに同じ処理をするのなら、For Each を使った方がシンプルになりますが、最終的に何をしたいのか不明なので、とりあえずは要件にそった回答。

Answer 2

ええと、、、

まず最初に、
セル範囲は、「セルの集まり」だというところから認識してください。
そして、エクセルVBA的には、セル範囲は4つの形態として認識できます。
1）各単体のセルの集まり（Cells）
2）行の集まり（Rows)
3）列の集まり（Columns)
4）矩形に区切られたセルの集まり（Areas)

つまり、
C3セルからE5セルのセル範囲
と指定した時、
単体のセルの集まりの1番目のセルは？
と、エクセル君に聞くと、
C3セルを返します。
そして、
セルの集まりの9番目のセルは？と聞くと、
E5セルを返します。

Magbox　Range("C3:E5").Cells(9).Address

同じように3番目の行は？と聞くと、
C5セルからE5セルの行を返します。

Msgbox Range("C3:E5").Rows(3).address

※↑のコードを1行コピーして、イミディエイトウィンドウに貼りつけたあと、
Enterキー押下で動作を確認してみてください。

それで、
最初の行は1番目の行なので1でいいですね？
最後の行は、
例えばセル範囲が5行あれば、5番目、
10行あれば10番目の行ですよね？
つまり、セル範囲の行の数を数えればいいわけです。
これは、Countプロパティで取得できます。

Msgbox　Range("C3:E5").Rows.Rount

日本語で書くと、

メッセージボックスに表示。セル範囲（C3セルからE5セル）の行の集まりの数。

となります。

次に、
「選択しているセル」ですが、
これはExcelVBAでは、
Cellection
と表現します。（ただし、選択されるものは、セルだけではないので、要注意）

ということを踏まえると、

Sub test()
    Dim i As Long, j As Long

    For i = 1 To Selection.Rows.Count
        For j = 1 To Selection.Columns.Count
            MsgBox Selection.Cells(i, j).Address(False, False)
        Next
    Next
End Sub

こういう感じになります。
が、あえてわざわざ行の数や列の数の値をセル範囲から取り出して、
それを使う必要はないかも知れません。

集まりの話をしましたが
「集まり」のことを「コレクション」といいます。
この、コレクション内を巡回するするときは、
For Each ステートメントを使います。

Sub test2()
    Dim r As Range, c As Range
    
    For Each r In Selection.Rows
        For Each c In r.Columns
　　　　　　　c.Select
            MsgBox c.Address(falsse, False)
        Next
    Next
End Sub

意味的には、

選択範囲の行の集まりを要素（この場合は各行）毎に繰り返す
　　各行の列の集まりを要素（この場合は各列）ごとに繰り返す
　　（結局1行の各列なので単体のセルになる）
　　　　そのセルを選択
　　　　そのセルのアドレスを表示
　　次へ
次へ

というような感じになります。
ここで、

1）各単体のセルの集まり（Cells）

という話をしました。

つまりセル範囲を各セルの集まりと見立てることも出来るわけです。

Sub test3()
    Dim c As Range
    
    For Each c In Selection.Cells
        c.Select
        MsgBox c.Address(False, False)
    Next
End Sub

このように、
「あるセル範囲の内、各セルに対して何か操作をしたい。」
と思った時には、
行番号がどうとか、何番目がどうとかあえて考えなくても、
あるセル範囲というもの中にそれらの情報は内包されていますので、
「操作対象のセル範囲を各各巡回する」と
命令文を書けばいいです。

For Each ステートメント

ぜひ覚えてください。

Comments

[退会済みユーザー]

すごく詳しく教えてくださりありがとうございます。
勉強になりました。

Answer 3

列始 = ActiveCell.Column
行始 = ActiveCell.Row
列終 = C1 + Selection.Columns.Count - 1
行終 = R1 + Selection.Rows.Count - 1

Comments

[hatena19]

ActiveCell が必ず選択範囲の左上とは限らないです。
例えば左上方向に向かって選択した場合は、右下がActiveCellになります。

[Dot]

そうですね
必ず左上からやってたのでこれではだめですね
ありがとうございます