ESP-WROOM-02をWi-FiモジュールとしてArduinoに接続(SoftwareSerial)してMilkcocoa Arduino SDKを使用する方法について

Question

###前提・実現したいこと
ArduinoにESP-WROOM-02をあくまでWi-FiモジュールとしてSoftwareSerialで接続した場合(ESP-WROOM-02にはプログラミングは行わない)、
どのようにしたらMilkcocoa Arduino SDKでMilkcocoaとやり取りできるようになるのでしょうか？
###ここまではできました
ESP-WROOM-02とArduino UNOでhttp通信のサンプルを基にSoftwareSerialでArduino～ESP8266のシリアル通信・サーバー上のPHPから値取得はできています。SoftwareSerialをMilkcocoa Arduino SDKに渡す部分で悩み中です。
###SoftwareSerialからEthernetClientへ置換えられないか
ESP8266やArduinoでMilkcocoaを使う方法(Milkcocoa Arduino SDK)
にて、

// 'client'は、Ethernet or WiFiのClient
Milkcocoa milkcocoa = Milkcocoa(&client, MQTT_SERVER, MILKCOCOA_SERVERPORT, MILKCOCOA_APP_ID, MQTT_CLIENTID);

Milkcocoaコンストラクタの第1引数にArduino基本クラスのEthernetClientのインスタンスを渡すとのことなのですが、ArduinoとESP-WROOM-02間はSoftwareSerialでシリアル通信しているので、そこをEthernetClientへ置き換えられればうまくいくのではないかと考えたのですが、解決方法がわからずこちらで質問させていただきました。
###ソースコード
ほぼ上記の記事のサンプルのままです。それにSoftwareSerialを追記しています。

#include "ESP8266.h"
#include <SoftwareSerial.h>
#include <Milkcocoa.h>

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "...SSID..."
#define WLAN_PASS       "...PASS..."


/************************* Your Milkcocoa Setup *********************************/

#define MILKCOCOA_APP_ID      "...YOUR_MILKCOCOA_APP_ID..."
#define MILKCOCOA_DATASTORE   "esp8266"

/************* Milkcocoa Setup (you don't need to change this!) ******************/

#define MILKCOCOA_SERVERPORT  1883

/************ Global State (you don't need to change this!) ******************/

SoftwareSerial mySerial(12, 11); /* RX:12, TX:11 */
ESP8266 wifi(mySerial);

const char MQTT_SERVER[] PROGMEM    = MILKCOCOA_APP_ID ".mlkcca.com";
const char MQTT_CLIENTID[] PROGMEM  = __TIME__ MILKCOCOA_APP_ID;

Milkcocoa milkcocoa = Milkcocoa(mySerial, MQTT_SERVER, MILKCOCOA_SERVERPORT, MILKCOCOA_APP_ID, MQTT_CLIENTID);

void setup() {
  Serial.begin(115200);
  delay(10);

  Serial.println(F("Milkcocoa SDK demo"));

  /*
  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  */
  Serial.println( milkcocoa.on(MILKCOCOA_DATASTORE, "push", onpush) );
};

void loop() {
  milkcocoa.loop();

  DataElement elem = DataElement();
  elem.setValue("v", 1);

  milkcocoa.push(MILKCOCOA_DATASTORE, elem);
  delay(7000);
};

void onpush(DataElement elem) {
  Serial.println("onpush");
  Serial.println(elem.getInt("v"));
};

###Milkcocoaを使いたい！
この壁さえ越えられれば、私のような趣味で電子工作をやっている人間でもArduinoからMilkcocoaを使って楽しい電子工作ライフを満喫できると思うので、なんとかして実現したいです。。

Comments

[kiyopikko]

現状どこまで出来ているのか（SoftwareSerialでArduino・ESP8266間の通信まではできている等）教えて頂ければ、最短で解決策にいけそうな気がしています。（私もまだ試行錯誤中です。。）
また、そのコードも記載頂ければ幸いです！

[umi_kappa]

ご協力いただきありがとうございます。
現状とソースコードを追記しました。

Answer 1

Milkcocoa開発チームのものです。

こちら、exshondaさんの力によって、実現に向かっています...！

具体的には、従来のMilkcocoa Arduino SDKが以下の2種類に分かれました。

• Milkcocoa ESP8266 SDK（今までのESP8266をArduino化するもの）
• Milkcocoa Arduino SDK（ArduinoからESPのATコマンド経由で使う方法）

後者のMilkcocoa Arduino SDKをexshondaさんにコントリビューターとして開発を進めて頂いています。
性能の都合上Arduino M0から優先的に対応して、UNOへの対応は「可能であれば」とのことです。

いち早く試したい場合は、Arduino M0をお買い求め頂くことをおすすめします...！

Comments

[umi_kappa]

Milkcocoa開発チームのみなさま、exshondaさんありがとうございます！
SDKまでアップデートしていただいて恐縮です。。

Arduino M0の購入も検討させていただきます。
私の方でも引き続き試行錯誤していきたいとおもいます。

Answer 2

みなさまのご協力のおかげでArduino M0 + ESP-WROOM-02でMilkcocoaにアクセス出来ました！
Arduino UNO R3でダメ元で試してみたのですが、SRAMの容量の関係でスケッチが書き込めずという悔しい結果でした(容量をクリアできればSoftwareSerialでうまくいきそうです)。

下記に今回のArduinoスケッチを。
これからMilkcocoaライフを楽しみます！

#include "ESP8266.h"
#include "Milkcocoa.h"
#include "Client_ESP8266.h"

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "SSID"
#define WLAN_PASS       "パスワード"


/************************* Your Milkcocoa Setup *********************************/

#define MILKCOCOA_APP_ID      "Milkcocoa App Id"
#define MILKCOCOA_DATASTORE   "esp8266"

/************* Milkcocoa Setup (you don't need to change this!) ******************/

#define MILKCOCOA_SERVERPORT  1883

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266Client class to connect to the MQTT server.
ESP8266Client wifi;

const char MQTT_SERVER[] PROGMEM    = MILKCOCOA_APP_ID ".mlkcca.com";
const char MQTT_CLIENTID[] PROGMEM  = __TIME__ MILKCOCOA_APP_ID;

Milkcocoa milkcocoa = Milkcocoa(&wifi, MQTT_SERVER, MILKCOCOA_SERVERPORT, MILKCOCOA_APP_ID, MQTT_CLIENTID);

int cnt;

void setup() {
  SerialUSB.begin(9600);
  delay(10);

  Serial5.begin(9600);
  while (!Serial5) {
    ;
  }

  SerialUSB.println("Milkcocoa SDK demo");

  // Connect to WiFi access point.
  SerialUSB.println(); SerialUSB.println();
  SerialUSB.print("Connecting to ");
  SerialUSB.println(WLAN_SSID);

  wifi.begin(Serial5, 9600);

  SerialUSB.print("FW Version:");
  SerialUSB.println(wifi.getVersion().c_str());

  if (wifi.setOprToStation()) {
    SerialUSB.print("to station ok\r\n");
  } else {
    SerialUSB.print("to station err\r\n");
  }

  if (wifi.joinAP(WLAN_SSID, WLAN_PASS)) {
    SerialUSB.print("Join AP success\r\n");
    SerialUSB.print("IP: ");
    SerialUSB.println(wifi.getLocalIP().c_str());
  } else {
    SerialUSB.print("Join AP failure\r\n");
  }

  if (wifi.disableMUX()) {
    SerialUSB.print("single ok\r\n");
  } else {
    SerialUSB.print("single err\r\n");
  }

  if (milkcocoa.on(MILKCOCOA_DATASTORE, "push", onpush)) {
    SerialUSB.println("milkcocoa on sucesss");
  }
  else {
    SerialUSB.println("milkcocoa on failure");
  }

  cnt = 0;
};

void loop() {
  milkcocoa.loop();

  DataElement elem = DataElement();
  elem.setValue("v", cnt++);
  milkcocoa.push(MILKCOCOA_DATASTORE, &elem);

  delay(1000);
};

void onpush(DataElement *pelem) {
  SerialUSB.println("onpush");
  SerialUSB.println(pelem->getInt("v"));
};