継承したFontプロパティの文字サイズを大きくしてもサイズが大きくならない

Question

###実現したいこと
四角形や円などの図形と文字列を同時に生成する自作コンポーネントを作成すること．

###困っていること
CustomControlクラスを継承したクラスを作成し，CustomControlのプロパティであるFontを継承しました．ですが，テストアプリでFontのSizeプロパティを変更しても文字列のサイズが変更せずに困っています．

図1　文字列のサイズが変わらないインスタンス

図2　Sizeプロパティを16にした時の画面

###実現方法
文字列のサイズを変更する方法はウィンドウメッセージのWM_SETFONTイベントを発生させる必要があるだろうと思っています．ですが，WM_SETFONTイベントの発生させ方が分からず困っています．どなたがご教授お願いいたします．

###ソースコード
文字数が10,000文字以上になるため，各種メソッド部分をわざと消しています．

unit Door;
//  Delphi
interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes,
  Vcl.Controls, Vcl.Graphics, Vcl.Forms, Vcl.StdCtrls, Vcl.ExtCtrls, Vcl.Dialogs;

type
  TDoor = class(TCustomControl)
  private
    { Private 宣言 }
    FCaption: UnicodeString;
    FShape: TShapeType;
    FShapeColor: TColor;
    FWidth_C: Integer;
    FHeight_C: Integer;

    procedure SetShape(Value: TShapeType);
    procedure SetShapeColor(Value: TColor);
    procedure SetCaption(Value: UnicodeString);
    procedure SetWidth_C(Value: Integer);
    procedure SetHeight_C(Value: Integer);
  protected
    { Protected 宣言 }
  public
    { Public 宣言 }
    left: Integer;
    top: Integer;

    //  コンストラクタ(オーバーライド)
    constructor Create( AOwner: TComponent ); override;
    procedure Paint; override;
  published
    { Published 宣言 }
    //  プロパティにdefaultを付けるとデフォルト値にできる
    property Shape: TShapeType read FShape write SetShape default stRectangle;
    property ShapeColor: TColor read FShapeColor write SetShapeColor;
    property Caption: UnicodeString read FCaption write SetCaption;
    property Width_C: Integer read FWidth_C write SetWidth_C;
    property Height_C: Integer read FHeight_C write SetHeight_C;
    //  継承プロパティ(再宣言するとオブジェクトインスペクタに表示できるようになる)
    property Anchors;
    property Color;
    property Enabled;
    property Font;
    property Name;
    property ParentColor;
    property Visible;
    property OnClick;
    property OnDblClick;
  end;

procedure Register;

//---------------------------------------------------------------------------
implementation

const
  DelphiWindows: array [1 .. 1] of PWideChar = ('TAppBuilder');

procedure Register;
begin
  //  「Samples」パレットにドアを登録
  RegisterComponents('Samples', [TDoor]);
end;

//  WM_PAINTメッセージで起動
//  クライアントエリアに更新領域が存在するときにコール
procedure TDoor.Paint;
var
  x1, y1: Integer;
  x2, y2: Integer;
  x_space, y_space: Integer;

begin
  //  四角形の場合
  if FShape = stRectangle then
  begin
    with Canvas do begin
      //  FSahpeColor色で塗りつぶし
      Brush.Color:= FShapeColor;
      Brush.Style:= bsSolid;
      FillRect(Rect(Left, Top, (Left+Width), (Top+Height)));
      //  黒色で太さ1で枠線描画
      Pen.Color:= clBlack;
      Pen.Style:= psSolid;
      Pen.Width:= 1;
      Rectangle(Rect(Left, Top, (Left+Width), (Top+Height)));

      //  文字列の描画
      TextOut(FWidth_C, FHeight_C, FCaption);
    end;
  end
  //  円の場合
  else if FShape = stCircle then
  begin
    with Canvas do begin
      //  Color色で塗りつぶし
      Brush.Color:= Color;
      Brush.Style:= bsSolid;
      FillRect(Rect(Left, Top, (Left+Width), (Top+Height)));

      if Width > Height then
      begin
        x_space:= Width - Height;
        x1:= Left + (x_space div 2);
        y1:= Top;
        x2:= x1 + Height;
        y2:= y1 + Height;
      end
      else
      begin
        y_space:= Height - Width;
        x1:= Left;
        y1:= Top + (y_space div 2);
        x2:= x1 + Width;
        y2:= y1 + Width;
      end;

      //  FSahpeColor色で塗りつぶし
      Brush.Color:= FShapeColor;
      Brush.Style:= bsSolid;
      //  黒色で太さ1で枠線描画
      Pen.Color:= clBlack;
      Pen.Style:= psSolid;
      Pen.Width:= 1;
      Ellipse(x1, y1, x2, y2);

      //  文字列の描画
      TextOut(FWidth_C, FHeight_C, FCaption);
    end;
  end
  //  楕円の場合
  else if FShape = stEllipse then
  begin
    with Canvas do begin
      //  Color色で塗りつぶし
      Brush.Color:= Color;
      Brush.Style:= bsSolid;
      FillRect(Rect(Left, Top, (Left+Width), (Top+Height)));
      //  FSahpeColor色で塗りつぶし
      Brush.Color:= FShapeColor;
      Brush.Style:= bsSolid;
      //  黒色で太さ1で枠線描画
      Pen.Color:= clBlack;
      Pen.Style:= psSolid;
      Pen.Width:= 1;
      Ellipse(Left, Top, (Left+Width), (Top+Height));

      //  文字列の描画
      TextOut(FWidth_C, FHeight_C, FCaption);
    end;
  end
  //  角の丸い四角形の場合
  else if FShape = stRoundRect then
  begin
    with Canvas do begin
      //  Color色で塗りつぶし
      Brush.Color:= Color;
      Brush.Style:= bsSolid;
      FillRect(Rect(Left, Top, (Left+Width), (Top+Height)));
      //  FSahpeColor色で塗りつぶし
      Brush.Color:= FShapeColor;
      Brush.Style:= bsSolid;
      //  黒色で太さ1で枠線描画
      Pen.Color:= clBlack;
      Pen.Style:= psSolid;
      Pen.Width:= 1;
      RoundRect(Left, Top, Width, Height, 10, 10);

      //  文字列の描画
      TextOut(FWidth_C, FHeight_C, FCaption);
    end;
  end
  //  角の丸い正方形の場合
  else if FShape = stRoundSquare then
  begin
    with Canvas do begin
      if Width > Height then
      begin
        x_space:= Width - Height;
        x1:= Left + (x_space div 2);
        y1:= Top;
        x2:= x1 + Height;
        y2:= y1 + Height;
      end
      else
      begin
        y_space:= Height - Width;
        x1:= Left;
        y1:= Top + (y_space div 2);
        x2:= x1 + Width;
        y2:= y1 + Width;
      end;

      //  Color色で塗りつぶし
      Brush.Color:= Color;
      Brush.Style:= bsSolid;
      FillRect(Rect(Left, Top, (Left+Width), (Top+Height)));
      //  FSahpeColor色で塗りつぶし
      Brush.Color:= FShapeColor;
      Brush.Style:= bsSolid;
      //  黒色で太さ1で枠線描画
      Pen.Color:= clBlack;
      Pen.Style:= psSolid;
      Pen.Width:= 1;
      RoundRect(x1, y1, x2, y2, 10, 10);

      //  文字列の描画
      TextOut(FWidth_C, FHeight_C, FCaption);
    end;
  end
  //  正方形の場合
  else if FShape = stSquare then
  begin
    with Canvas do begin
      //  Color色で塗りつぶし
      Brush.Color:= Color;
      Brush.Style:= bsSolid;
      FillRect(Rect(Left, Top, (Left+Width), (Top+Height)));

      if Width > Height then
      begin
        x_space:= Width - Height;
        x1:= Left + (x_space div 2);
        y1:= Top;
        x2:= x1 + Height;
        y2:= y1 + Height;
      end
      else
      begin
        y_space:= Height - Width;
        x1:= Left;
        y1:= Top + (y_space div 2);
        x2:= x1 + Width;
        y2:= y1 + Width;
      end;

      //  FSahpeColor色で塗りつぶし
      Brush.Color:= FShapeColor;
      Brush.Style:= bsSolid;
      //  黒色で太さ1で枠線描画
      Pen.Color:= clBlack;
      Pen.Style:= psSolid;
      Pen.Width:= 1;
      Rectangle(Rect(x1, y1, x2, y2));

      //  ためしにやってみたが，フォントサイズが変更しなかった．
      Font.Assign(Font);
      //  文字列の描画
      TextOut(FWidth_C, FHeight_C, FCaption);
    end;
  end;

//  FCaption.
//  Font.Size
end;


//Createメソッド省略
//SetShapeメソッド省略
//SetShapeColorメソッド省略
//SetCaptionメソッド省略
//SetWidth_Cメソッド省略
//SetHeight_Cメソッド省略

end.

Comments

[y_waiwai]

ソースもないことには答えようがないですが。

[dem0nmichik0]

y_waiwai様
申し訳ありませんでした．遅くなりましたが，ただ今抜粋的にソースコードを記載いたしました．
よろしくお願いいたします。

Answer 1

Paintメソッドの実装がないので予想ですが、テキストの描画はPaintメソッド内で実行しているのですよね。
であれば、テキストの描画をする前に下記のようにカンバスにフォントを設定してから描画すれば設定したフォントが反映されると思います。

paintメソッド
:
Canvas.Font.Assign(Font);
Canvas.TextOut(...);
:

Comments

[dem0nmichik0]

au2010様，回答ありがとうございます．
Paintメソッド内にはFShapeプロパティによって，四角形，正方形，円，楕円などをサイズ変更して再描画しており，最後にTextOutで文字列も描画しています．なので，おしえていただいた「Font.Assign(Font)」を正方形の場合のときに，TextOutの前に設定してやってみましたが，フォントサイズが変更されませんでした．
Paintメソッドの中身を実装しましたので，お時間ありましたら，ご教授お願いいたします．

[au2010]

Withブロック内なのでCanvasのフォントとControlのフォントの区別が付かない状態になっているのではないかと思います。
Canvas.Font.Assign(Self.Font);としてみたらどうでしょう？

[dem0nmichik0]

au2010様，回答ありがとうございます．
Canvas.Font.Assign(Self.Font)でフォントサイズが変更しました．2点質問があります．
１．Assignメソッドは「プロパティのコピー」とHPに記載されていますが，なぜ，プロパティをコピーすると実現できるのでしょうか？自分自身では，フォントサイズを変更したら何かしらのウィンドウメッセージが発生し，発生したウィンドウメッセージに対してフォントサイズの再描画処理を記述すると思っていました．
２．Canvas.Font.Assign(Self.Font)とCanvas.Font.Assign(Self.Font)の違いは「Assign(Self.Font)」か「Assign(Font)」ですが，なぜ，「Assign(Font)」だとだめなのでしょうか？「Assign(Self.Font)」だとCanvasのFontで，「Assign(Font)」だとTCustomControlのFontなため，「Self」が必要なのでしょうか？
回答お願いいたします．

[au2010]

1については、コントロールの描画を自作する場合、コントロールのFontプロパティと実際に描画を行うCanvasのFontプロパティは別で特にリンクしている訳ではないので自分で描画する時に設定する必要があるからです。これはPenとかBrushについても同じです。
2については、コントロール自身とCanvasはそれぞれ個別にFontプロパティを持っています。Withブロック内で単にFontとした場合、どちらのFontと解釈されるかは判りませんがコピー元とコピー先が同じになるからダメだったのでしょう。作成しているコントールのFontプロパティをCanvasのFontにコピーする必要があるのです。

[dem0nmichik0]

au2010様，回答ありがとうございます。
１，２の説明により，「自作しようとしているコントロール(TCustomControl)」と「Canvas」のFontプロパティは別々なこと，オブジェクトインスペクタによって自作しようとしているコントロール(TCustomControl)のFontプロパティが変化するから，Canvas.Font.Assign(Self.Font)によって，自作しようとしているコントロール(TCustomControl)のFontプロパティをCanvasのFontプロパティにコピーする。そして，文字列の描画で反映されることが分かりました。

丁寧なご教授ありがとうございました。