vbaのリストボックスとListCoutの動作

Question

お疲れ様です。pipiでございます。
vbaとexcelの連携が頭の中でごちゃごちゃの状態でございます。

.ListCountはリスト内の単純に行数を求めるとのことですが、いきなりリストボックス内の合計行数が求められるわけではないのでしょうか？

以下、エクセルの各行の値をリストボックスに反映させる部分のプログラムですが、
```
LastRow = Range("A600").End(xlUp).Row
    For i = 2 To LastRow
        .AddItem Cells(i, 1).Value
        Debug.Print i
        Debug.Print .ListCount

        .List(.ListCount - 1, 1) = Cells(i, 2).Value
        .List(.ListCount - 1, 2) = Cells(i, 3).Value
        .List(.ListCount - 1, 3) = Cells(i, 4).Value
        .List(.ListCount - 1, 4) = Cells(i, 5).Value
        .List(.ListCount - 1, 5) = Cells(i, 6).Value
        .List(.ListCount - 1, 6) = Cells(i, 7).Value
    Next
    
    End With
```

debug.print で.ListCountを見てみたとき、
i=2のときは、ずっと1
i=3のときは、ずっと2
i=4のときは、ずっと3
i=7のときは、ずっと6となり、リストボックス内の行数6行と一致しております。

.ListCountでリスト内の行数を求めるといっても、結局はfor文でループさせて求める
ものなのでしょうか？.ListCountは、一発でリストボックス内の行数が求められると
思っていたもので・・・・。

![イメージ説明](13f4e916ed5a6f8ceadb54c46775c599.png)

どなたかご教授願います。

Accepted Answer

> .AddItem Cells(i, 1).Valueは、エクセルの行と列を見ているだけではないのですか？
> 2行目1列目、3行目1列目と・・・・

エクセルのワークシートとリトスボックスは同じようなものであると誤解しているのでは。
エクセルのワークシートは開いた直後から、最大行数、最大列数が確保されていて、どこにも入力できます。
が、リストボックスはそうではありません。開いた直後は、行数は0です。列数は、ColumnCountプロパティで設定した数だけです。


初期状態の行数0のリストボックスに、行（データ）を追加する方法はいろいろあります。

addItem は１行ずつ追加していきます。

```vba
With ListBox1
    Debug.Print .ListCount '0

    .AddItem "データ1"
    Debug.Print .ListCount '1

    .AddItem "データ2"
    Debug.Print .ListCount '2

    .AddItem "データ3"
    Debug.Print .ListCount '3
End With
```


一度にデータを追加する方法もあります。
Listプロパティは配列なので、それに配列を代入できます。

```vba
    With ListBox1
        ListBox1.List = Array("配列1", "配列2", "配列3")
        Debug.Print .ListCount    '6
    End With
```

上記は、Array関数で配列を生成して代入してますが、Range も配列なので、それを一気に代入することもできます。今回の質問のコードなら、下記のコードでも同じ結果になります。

```vba
    With ListBox1
        ListBox1.List = Range("A2:G7").Value
        Debug.Print .ListCount    '6
    End With
```


データ（行）を追加した後、その行の列を更新, 参照する場合は、Listプロパティを使用します。

```vba
With ListBox1
    Debug.Print .ListCount '0

    .AddItem "" '１行追加
    .List(0,0) = "１行目１列目"
    .List(0,1) = "１行目２列目"
    .List(0,2) = "１行目３列目"
    Debug.Print .ListCount '1

    .AddItem "" '１行追加
    .List(1,0) = "２行目１列目"
    .List(1,1) = "２行目２列目"
    .List(1,2) = "２行目３列目"
    Debug.Print .ListCount '2

End With
```

Listプロパティは２次元配列になっていて、インデックスは0から始まります。

行を追加せずに、行数以上の範囲をListで参照すると「インデックスは無効です」というエラーになります。

```vba
With ListBox1
    Debug.Print .ListCount '0

    .AddItem "" '１行追加
    .List(0,0) = "１行目１列目"
    .List(0,1) = "１行目２列目"
    .List(0,2) = "１行目３列目"
    Debug.Print .ListCount '1

'    .AddItem "" '１行追加      'ここをコメントアウトすると
    .List(1,0) = "２行目１列目" 'ここでインデックス無効エラー
    .List(1,1) = "２行目２列目"
    .List(1,2) = "２行目３列目"
    Debug.Print .ListCount '2

End With
```


これらのコードの意味が理解できたら、 AddItemメソッド、List、ListCountプロパティのそれぞれの意味は理解できませんか？

Answer

> .ListCountでリスト内の行数を求めるといっても、結局はfor文でループさせて求める 
> ものなのでしょうか？.ListCountは、一発でリストボックス内の行数が求められると 
> 思っていたもので・・・・。 
Forループでやってる
```vba
.AddItem Cells(i, 1).Value
```
を忘れていませんか？

AddItemで今回追加されたListItemを指すために
.ListCount-1
を使っているだけです

今回のコードでは**.ListCount-1**行目が新しく追加された行を指し
```vba
        .List(.ListCount - 1, 1) = Cells(i, 2).Value
        .List(.ListCount - 1, 2) = Cells(i, 3).Value
        .List(.ListCount - 1, 3) = Cells(i, 4).Value
        .List(.ListCount - 1, 4) = Cells(i, 5).Value
        .List(.ListCount - 1, 5) = Cells(i, 6).Value
        .List(.ListCount - 1, 6) = Cells(i, 7).Value
```
の一連のコードで**新しく追加された行**の各列に値を設定している

余談ですが
```vba
    i=1       '何個目のListItemを処理しているか/A1から何行目のセルを見ているか
    Do While Range("A1").Offset(i,0)<>""        'A列になにか値がある間は実行
        'ListItemを1個(1行)追加
        .AddItem Range("A1").Offset(i,0).Value

        '追加した行の各列に値を設定
        .List(i, 1) = Range("A1").Offset(i,1).Value
        .List(i, 2) = Range("A1").Offset(i,2).Value
        .List(i, 3) = Range("A1").Offset(i,3).Value
        .List(i, 4) = Range("A1").Offset(i,4).Value
        .List(i, 5) = Range("A1").Offset(i,5).Value
        .List(i, 6) = Range("A1").Offset(i,6).Value

        i=i+1       '次のListItem/A1から何行目のセルを見ているかを次の行にする
    Loop
```
ちゃんと書けているかわかりませんが...