ユーザーフォームのクリックされたコマンドボタンのを結果を取得する

Question

UserForm1にCommandButton1とCommandButton2が存在し、どちらがクリックされたかによってBeforeCloseイベントの処理を分岐させたいのですがうまくいきません。。
イメージとして以下の様なイメージでコードを書いているのですが、ThisWorkBookモジュールでPatternの値を取得してくれません、解決方法にお力添え頂けますでしょうか。
宜しくお願い申し上げます。

'ThisWorkBookモジュール
Private Sub Workbook_BeforeClose(Cancel As Boolean)
 Dim Pattern As String
 UserForm1.Show
 if Pattern=A Then
  '処理
 Endif
End Sub

'ユーザーフォームモジュール
Private Sub CommandButton1_Click()
    Unload Me
    Pattern = "A"
End Sub

Private Sub CommandButton2_Click()
    Unload Me
     Pattern = "B"
End Sub

Answer 1

解決済みですが、

こんな方法もあるということで、
別案を出しておきます。

UserForm1のモジュール

Option Explicit
Private vPattern As String

Public Property Get Pattern() As Variant
    Me.Show vbModal
    Pattern = vPattern
    Unload Me
End Property

Private Sub CommandButton1_Click()
    vPattern = "A"
    Me.Hide
End Sub

Private Sub CommandButton2_Click()
    vPattern = "B"
    Me.Hide
End Sub

ThisWorkBookモジュール

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Select Case UserForm1.Pattern()
    Case "A"
        '処理A
    Case "B"
        '処理B
    End Select
End Sub

ユーザーフォームにプロパティ(Property)を実装して、それを参照するようにすれば、関数のように扱えてシンプルになります。動作原理については、下記で詳細に解説していますので、参考にしてください。

ユーザーフォームで入力ダイアログを作成する - hatena chips

また、グローバル変数(標準モジュールのPublic変数)を置く必要もなくなります。

グローバル変数は、コードが分散して可読性が落ち、バグの可能性が高くなるのでできれば避けると言うのが定説です。

---

上記の方法かちょっと難解だという場合は、
グローバル変数ではなく、
ThisWorkBookのモジュールレベル変数として宣言したほうがいいでしょう。

ThisWorkBookモジュール

Option Explicit
Public Pattern As String

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    UserForm1.Show    
    If Pattern = "A" Then
        '処理A
    End If
End Sub

ユーザーフォームモジュール

Private Sub CommandButton1_Click()
    ThisWorkbook.Pattern = "A"
    Unload Me
End Sub

Private Sub CommandButton2_Click()
    ThisWorkbook.Pattern = "B"
    Unload Me
End Sub

Answer 2

標準モジュールを追加してしてください。
モジュールの先頭へ以下の行を追加してください。

Option Explicit
Public Pattern As String

さらに、ThisWorkBookモジュールの
Dim Pattern As Stringは削除してください。

Comments

[pegy]

コメントありがとうございます。
なるほど、public scopeの変数は標準モジュールに定義すればよいのですね。
大変助かりました！改めて御礼申し上げます。