VBAからOutlookでHTMLメール送る際に、元のコードから改変されるのを防ぎたい

Question

前提・実現したいこと

VBAからOutlookを通して送るHTMLメールが、元のコードのままで送られるようにしたい。
（Outlook側の設定で解決できるのであれば、その設定をお教えいただきたいです。）

発生している問題

＜iOSでメールを見た場合＞
デフォルトメールアプリだけでなくGmailアプリなどで見ても、font-familyが効いておらず、iOSデフォルトの明朝体で表示される。
その他にも、幅100%を指定していても左右にmarginが発生する。それ以外のスタイルは反映している。

＜WindowsやMacOSで見た場合＞
上記のような問題は見られない。

＜送信確認画面で送信ファイルをhtml形式で保存してソースを見てみる＞
元のコードはスタイルをすべてインラインにしたもので、font-familyは*にあてていたのに、送信時のhtmlファイルはfont-familyの一部が消えていたりする。（font-family自体は一部残っている）

Outlookを起動するVBAコード

Sub sendMailByOutlook_UTF8()
    
    Dim objOutlook As Outlook.Application
    Set objOutlook = New Outlook.Application
    Dim objMail As Outlook.MailItem
    Set objMail = objOutlook.CreateItem(olMailItem)
    
    Dim oAccount As Outlook.Account
    Set oAccount = Session.accounts("メールアカウント") 
    
    Dim mailBody As String, Target As String
    Target = メール本文になるHTMLファイルのパス
    With CreateObject("ADODB.Stream")
        .Charset = "UTF-8"
        .Open
        .LoadFromFile Target
        mailBody = .ReadText
        .Close
    End With
    With objMail
        .To = "宛先アドレス"
        .Subject = "メールタイトル"
        .HTMLBody = mailBody
        .BodyFormat = olFormatHTML
        .SendUsingAccount = oAccount
    End With
    
    '送信画面の確認
    objMail.Display
End Sub

試したこと

・発送元メールアドレスがGmailなので、CDOで送った場合は上記の問題は起こらなかったため、Outlookを通して送ることで問題が発生しているのではと予想している（CDOはセキュリティ上、使いたくない）
・HTML本文の設定（スタイルや文字コード、宣言など）を数々試したが、どれも同じ結果になった。

補足情報（FW/ツールのバージョンなど）

Office 365を使用しています。

Google APIを使用するしかないのかと考えているのですが、それはそれで骨が折れる方法なようなので、Outlookの設定やVBAで回避できる方法があるようでしたらご教示いただきたくご質問をさせていただきます。

よろしくお願いいたします。

Answer 1

Outlookで一度メールを作成して、「名前を付けて保存」でmsgファイルを出力した後、VBAでそのファイルを開いて送れば、そのままの状態で送信することが可能ですよ。

プラス、簡単に修正も出来きるので便利ですよ。

Dim application As Object
Dim mailItem As Object

Set application = CreateObject("Outlook.Application")
Set mailItem = application.Session.OpenSharedItem(FileName)'FileNameは任意

Comments

[furumototatsuya]

ありがとうございます！早速試してみます！！

[stdio]

ただ、この方ではmsgファイルのなかの中のHTMLをガチ読みしなければ、VBAでの変更や追加は難しいですよ。

[furumototatsuya]

ご丁寧にありがとうございます。

Answer 2

#原因
私が記述したコードで言うと、次の部分が原因でした。

objMail.Display 'Outlookで送信画面を開く

#解決方法
Outlookで送信画面を開くプロセスでHTMLコードが改変されてしまっているので、.Displayで開いた送信画面から送らないことが回避策となり、objMail.SendでOutlookを開かず送信することで記述通りのHTMLコードを送ることができました。

ちなみに、送信前にやはり一度送信メールを確認したかったので、次のような形にすることでVBAを途切れさせずに送信することができました。

    With objMail 'これより前は最初に書いたものと同じコードです。（上記参照）
        .Subject = "メールタイトル"
        .HTMLBody = mailBody
        .BodyFormat = olFormatHTML
        .SendUsingAccount = oAccount 
        .Display  '送信画面の確認
        Dim whetherToSend As Long
        whetherToSend = MsgBox("この内容でメール送信してOKですか？", vbOKCancel, "送信確認")
        If whetherToSend = 2 Then
            Exit Sub 'キャンセルの場合はここでプロシージャを抜ける
        Else
            .Close (olDiscard) '保存せずにOutlookを閉じる
            .To = "宛先のメールアドレス" '確認画面でご送信しないように、ここで宛先を代入
            .Send 'Outlookを開かずに送信
        End If
    End With

Gmailを使っていて、CDO経由での送信は送信内容に異常は出なかったのですが、セキュリティが問題だったので、GoogleAPIを使わないといけないのかと悩んでいましたが。。
簡単な部分で解決できてよかったです。

ご助言いただいた方、ありがとうございました。