バッチファイルに記載されているコマンドの意味について

Question

後述するバッチの構文で以下の部分の

"!export_pass!!DIRNAME:*workspace=!"

で

!DIRNAME:*workspace=!

の箇所は何のために行っているのかどのような意味があるのかがわからないです。
If existsの意味は分かるのですがこの箇所だけ何をしてるのか調べてもわかりませんでした。
分かる方がいましたらご教授願います。
また、このような記述に関して何か参考資料がありましたら教えていただきたいです。
以上です。
宜しくお願いいたします。

          rem 指定先にディレクトリ(サブも含む)を作成。
          rem ディレクトリ存在チェック
          if exist "!export_pass!\!DIRNAME:*workspace\=!" (
            echo !export_pass!\!DIRNAME:*workspace\=!が存在するためスキップします。
          ) else (
              mkdir !export_pass!\!DIRNAME:*workspace\=!
              echo !export_pass!\!DIRNAME:*workspace\=!を作成しました。
          )

以下に全体ソースを添付いたします。

環境設定.bat

rem エクスポート先のディレクトリ名を記載してください。
set export_pass=***

rem workspaceパスを記載してください。
set workspace_pass=***

@echo off
setlocal EnableDelayedExpansion

call 環境設定.bat


echo %date% %time% エクスポートを開始します。 >> export_file.log

rem 外部ファイルからエクスポートしたいファイル名を一行ずつ取得。
for /f %%a in (file_list.txt) do (
  
  rem ファイル名を代入。
  set FILENAME=%%a
    
    rem 対象ファイルのフルパスを取得。
    for /f "usebackq delims=" %%i in (`where /R !workspace_pass! !FILENAME!`) do (
      
      rem フルパスを代入。
      set DIRNAME_FULL=%%i
      
      rem フルパスに「WebContent\WEB-INF\classes」が含まれていないかチェック。
      echo !DIRNAME_FULL! | find "WebContent\WEB-INF\classes" >NUL
      if not ERRORLEVEL 1 (
        rem 
       ) else (
          rem フルパスからファイル名を除外し、ディレクトリ名を取得。
          set DIRNAME=%%~pi
          
          rem 指定先にディレクトリ(サブも含む)を作成。
          rem ディレクトリ存在チェック
          if exist "!export_pass!\!DIRNAME:*workspace\=!" (
            echo !export_pass!\!DIRNAME:*workspace\=!が存在するためスキップします。
          ) else (
              mkdir !export_pass!\!DIRNAME:*workspace\=!
              echo !export_pass!\!DIRNAME:*workspace\=!を作成しました。
          )
          
          rem 対象ファイルを指定先ディレクトリにコピー。
          copy !DIRNAME_FULL! !export_pass!\!DIRNAME:*workspace\=!
          echo 対象ファイル:!FILENAME!
          
          rem ログ出力用
          echo !export_pass!\!DIRNAME:*workspace\=!!FILENAME! >> export_file.log
          
      )
    )
)

echo %date% %time% エクスポートが終了しました。 >> export_file.log
pause

Answer 1

setlocal enabledelayedexpansionしてある場合は、!変数名!で環境変数の参照が出来ると言うことは理解していますか？
!DIRNAME:*workspace=!は、環境変数の参照時に文字列を置換する機能です。説明は、コマンドプロンプトで、set /?と打つと出てきます。この場合は先頭からworkspaceまでを空と置換（＝削除）ですね。

これに限らずコマンドの説明は、コマンド名 /?で表示されます。環境変数に関することはsetコマンドに説明があります。

Comments

[soso0programmer]

返信が遅れて申し訳ありません。
回答ありがとうございました。
解決いたしました。