Excelで常に実行したい

Question

現在フォームコントロールのボタン操作で下記を実行しています。
C2,C3のセルの値を変えることで自動で実行することは可能でしょうか？
Worksheet_Changeイベントで作成しないといけないことは分かったのですが
構文がわかりません。
そのままコピーしてもダメだったため教えてください。
詳しい方が近くにいません。
お忙しい中申し訳ございませんがよろしくお願いいたします。

Sub DatePeriod()
Const sCol As Long = 15
Const eCol As Long = 379
'全表示
Range(Columns(sCol), Columns(eCol)).Hidden = False
'非表示設定
If IsDate(Range("C2").Value) And IsDate(Range("C3").Value) Then
Dim mDate As Long: mDate = Cells(2, sCol).Value2
Dim mDate2 As Long: mDate2 = Cells(2, eCol).Value2
Dim sDate As Long: sDate = Range("C2").Value2
Dim eDate As Long: eDate = Range("C3").Value2
Dim memo As Long
'開始より前を非表示
If sDate > mDate Then
memo = sDate - mDate + sCol - 1
Range(Columns(sCol), Columns(memo)).Hidden = True
Cells(2, memo + 1).Activate
End If
'終了より後を非表示
If mDate2 > eDate Then
memo = eDate - mDate + sCol + 1
Range(Columns(memo), Columns(eCol)).Hidden = True
End If
End If
End Sub

Answer 1

VisualBasicEditorの左側でファイル（ModuleとかFormとか）を選択できますよね？
そこにシートが表示されていると思いますが、対象セル（C2とC3）が存在するシートをダブルクリックしてください。

すると、表示されたウインドウの上部にイベントを選ぶコンボボックスが出てくるので、「WorkSheet」と「Changed」イベントを選択するとWorksheet_Changedイベントが勝手に作成されたはずです。
（余分なイベントも作成されることがあるので適宜消してください）

たしか、引数にTarget As Rangeがあると思うので、その情報をもとに「C2、C3が変更されたかどうか？」を判定し、変更された場合のみ質問文のプロシージャを呼べばよいのではないでしょうか？
Target引数には編集したセルがRangeオブジェクトで入っています。

Private Sub Worksheet_Change(ByVal Target as Range) 
    ' 編集されたセルが1つでない場合は処理しない
    If Target.Count <> 1 Then Exit Sub

    ' C行は3番目（A, B, C）
    If 2 <= Target.Row And Target.Row <= 3 And Target.Column = 3 Then
        ' DatePeriodプロシージャを呼ぶ（DatePeriodを同じファイルに置いたら分かりやすい）
        ' 「Module1」ファイルの中に「DatePeriod」があるなら、「Module1.DatePeriod」とした方がいいかも
        Call DatePeriod()
    End If
End Sub

あと、ひとつ気になるのはDatePeriodプロシージャの処理で、Range("C2")と表記していますが、この書き方だとActiveSheet.Range("C2")という意味になります。これだと、現在表示されているシートに対して処理を行ってしまうので、複数シートある場合は他のシートへ処理が及んでしまう危険性もあるため注意です👀

Sheets("シート名").Range("C2")
みたいにするか...
シートのオブジェクト名.Range("C2")
（例）Sheet1.Range("C2")
みたいにするのが無難です。
オブジェクト名は一番初めに説明した左側にあるウインドウのシートをクリックすると、プロパティウインドウで変更できます。（Excelに表示されている名前とVBAで使うオブジェクト名は違うんです。Sheets関数はExcelに表示されている名前からシートを取得してね～という関数ですが、Excelに表示されているシート名は簡単に編集できてしまうのであまりお勧めできないです。）

あと、おせっかいだったらすいませんが、Range関数はもともと範囲を作成したいときに使う関数なので、厳密にはRange("C2")という使い方はあまり推奨されてないかもです。Cells(2, 3)とかCells(2, "C")の方がよくつかわれている印象はありますね！
Range(Cells(2, 3), Cells(3, 3))（C2:C3の範囲）みたいなときはRange関数がよくつかわれます。

参考になれば幸いです^^

Answer 2

シンプルに、C2,C3のセルに変更があったら、DatePeriodを呼び出して実行するなら以下でいけるかと。
シートモジュールに貼り付けてくださいね。

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("C2:C3")) Is Nothing Then
        Call DatePeriod
    End If
End Sub