バッチで*（アスタリスク・ワイルドカード）を文字として扱うには？

Question

バッチファイルで*（アスタリスク・ワイルドカード）を文字として扱うにはどうすればいいんですかね？

例：abcde を abcZdeにする。 を文字として認識し Z に置き換え。

遅延環境変数とかエスケープとか色々試しましたが、どうしてもできませんでした。

何か方法がありましたら教えて下さい。

Comments

[nskydiving]

具体的に試したコマンドはどんなものでしょうか？

Answer 1

ちょっと大げさですが、for でやる方法もあります。

@echo off
setlocal

set AA=abc*de
for /f "delims=* tokens=1,2" %%i in ("%AA%") do set BB=%%iZ%%j
echo %BB%

endlocal

実行結果

abcZde

Comments

[kankan0]

ありがとうございます。
delimsが*を文字として認識してくれるとは気付きませんでした。
*が入っている文字列と入っていない文字列のどちらにも使えるような記述を目指していますので、
もう少し考えてみます。

Answer 2

@echo off
FOR /F "usebackq" %%i IN (`powershell -ExecutionPolicy ByPass -c "'abc*de' -replace '*', 'Z'"`) DO SET RESULT=%%i
echo %RESULT%

Comments

[Zuishin]

コメント削除

[kankan0]

ありがとうございます。
やはりパワーシェルの力を借りるのが現実的ですかね。
パワーシェルについての知識があまりありませんので、勉強しないとです。

[Zuishin]

バッチの知識はもう勉強しなくても十分あるんでしょうか？
どのみち勉強が必要なら、同じことではありませんか？

バッチは外部コマンドを呼び出すためのもの。
PowerShell 等を呼び出すのが本来の使い方です。

そして PowerShell を使えばバッチはたいていの場合不要になります。
覚えない理由がありません。

Answer 3

仕様的には下記でできそうな気がしますが、だめですね。^*という文字列を置換してしまいます。

set A=ABC*DE
echo %A:^*=Z%
→ ABC*DE

set "A=ABC^*DE"
echo %A:^*=Z%
→ ABCZDE

ループを回して1文字ずつ見るしかないかと。

set A=ABC*DE

set B=
:LOOP
if "%A%" == "" goto END
set C=%A:~0,1%
if "%C%" == "*" set C=Z
set B=%B%%C%
set A=%A:~1%
goto LOOP
:END
set A=%B%

echo %A%

可能なら、バッチスクリプト以外の方法がよいと思います。
#追記
for /f "delims=*を使うなら、*の数が25個以下として、

set Z=Z
set A=ABC*DEF
for /f "delims=* tokens=1-26" %%A in ("%A%") do (
	if not "%%Z" == "" (
		set A=%%A%Z%%%B%Z%%%C%Z%%%D%Z%%%E%Z%%%F%Z%%%G%Z%%%H%Z%%%I%Z%%%J%Z%%%K%Z%%%L%Z%%%M%Z%%%N%Z%%%O%Z%%%P%Z%%%Q%Z%%%R%Z%%%S%Z%%%T%Z%%%U%Z%%%V%Z%%%W%Z%%%X%Z%%%Y%Z%%%Z
	) else if not "%%Y" == "" (
		set A=%%A%Z%%%B%Z%%%C%Z%%%D%Z%%%E%Z%%%F%Z%%%G%Z%%%H%Z%%%I%Z%%%J%Z%%%K%Z%%%L%Z%%%M%Z%%%N%Z%%%O%Z%%%P%Z%%%Q%Z%%%R%Z%%%S%Z%%%T%Z%%%U%Z%%%V%Z%%%W%Z%%%X%Z%%%Y
	・・・・・中略・・・・・
	) else if not "%%C" == "" (
		set A=%%A%Z%%%B
	) 
)

ちょっと手で書く気がしませんね。いずれにせよ、個数上限がないと無理です。

Comments

[sazi]

ググってみると、エスケープは前ではなく後ろ(*^)な気がします。

[otn]

=をエスケープすると言う事ですか？どういう意図なんでしょうね。

[sazi]

set "A=ABC*^DE"
echo %A:*^ =Z%
→　ABC*DE

[sazi]

^の前後は関係なさそうです、=の前に空白入れれば同じでした。
set "A=ABC^*DE"
echo %A:^* =Z%
→ ABC*DE

[kankan0]

set "A=ABC^*DE"
echo %A:^*=Z%
であれば、置換はできるもののあらかじめ文字列の*の前にエスケープを入れないといけないようですね。

[otn]

はい。置換では無理です。

[sazi]

*を文字として認識させてZに変換ですね。盛大に勘違いでした。すみません。