Excelのシート上に設置したActiveXのコンボボックスの複数ループについて

Question

前提・実現したいこと

Excelでシート上に複数のコンボボックスがあるのですが
シート上なので起動する度にリストが消えてしまいます。
起動する度に各リストに表示
もしくは、一度代入した値を保存できる方法を調べてみたのですが
どうしても分かりませんでした。
ご教示よろしくお願い致します。

コンボボックスはActiveXでシート上に追加しています。

発生している問題・エラーメッセージ

実行時エラー'438':
オブジェクトは、このプロパティまたはメソッドをサポートしていません。

一つ目、二つ目共にこのメッセージです。

該当のソースコード

Private Sub Workbook_Open()

For i = 1 To 24 "一つ目のパターン
    With Worksheets("sheet").OLEObjecs("ComboBox" & i) "ここでエラー。最後に.Objectを付けてもエラー。
        .Clear
        .AddItem "値1"
        .AddItem "値2"
        .AddItem "値3"
    End With
Next i

For i = 1 To 24 "二つめのパターン
    With Worksheets("sheet").Controls("ComboBox" & i) "同じくここでエラー
        .Clear
        .AddItem "値1"
        .AddItem "値2"
        .AddItem "値3"
    End With
Next i

試したこと

OLEObjectsやControlsでない何かがあるのかも調べてみましたが
有力な情報は得られませんでした。
モジュールからコードを打ち込んで起動しても同じ結果になりました。

補足情報（FW/ツールのバージョンなど）

Excel 2013です。

Answer 1

With Worksheets("sheet").OLEObjecs("ComboBox" & i)

• sheet という名前のシートは本当にあるのか。
• OLEObjecs は、正しくは、OLEObjects
• 最後に、.Object をつける必要がある。

Option Explicit

Private Sub Workbook_Open()
    Dim i As Long
    For i = 1 To 24
        With Worksheets("Sheet1").OLEObjects("ComboBox" & i).Object
            .Clear
            .AddItem "値1"
            .AddItem "値2"
            .AddItem "値3"
        End With
    Next i
End Sub

Option Explicit 宣言(変数宣言強制)はするようにしよう。

Comments

[ruuru]

Option Explicitを宣言していませんでした。
変数を宣言しないと使えないようにするものだという認識なのですが
まさかこれが抜けていると動かない...とは思いませんでした。
とても助かりました。ありがとうございました。

[hatena19]

回答の最初の３つ項目が動かない原因です。
Option Explicit があるかないかは、今回は関係ないです。
ただ、今後のためにつけておくようにした方がいいですよ、ということです。