ExcelでSQLite3を使うModuleのエラーの対処方法を教えて下さい。

Question

前提・実現したいこと

前提：
Excelで簡単にSQLiteを使用できるということで、これらのリンクを参考にしました。

ExcelからODBCなしでSQLiteを操作する(設定編）
ExcelからSQLite３を操作する方法(1.使用準備)
ExcelからSQLiteを使う方法
Excel VBAからSQLite3のデータベースを触ってみたところ、それなりにハマったのでメモ。
SQLite for Excel

SQLite For Excel Version 1.0にあるSQLiteForExcel_64.xlsmを起動し、AllTestsプロシージャを実行します。
特に何も設定せずとも動くものと理解しています。

'\Sqlite3Demo.bas
Option Explicit

Dim TestFile As String

Public Sub AllTests()
    ' Check that this location can be written to
    ' Note that this file will be deleted after the tests complete!
    TestFile = Environ("TEMP") & "\TestSqlite3ForExcel.db3"
        
    Dim InitReturn As Long
    #If Win64 Then
        ' I put the 64-bit version of SQLite.dll under a subdirectory called x64
        InitReturn = SQLite3Initialize(ThisWorkbook.Path + "\x64")
    #Else
        InitReturn = SQLite3Initialize ' Default path is ThisWorkbook.Path but can specify other path where the .dlls reside.
    #End If
    If InitReturn <> SQLITE_INIT_OK Then
        Debug.Print "Error Initializing SQLite. Error: " & Err.LastDllError
        Exit Sub
    End If
    
    TestVersion
    TestOpenClose
    TestOpenCloseV2
    TestError
    TestInsert
    TestSelect
    TestBinding
    TestDates
    TestStrings
    TestBackup  ------------------ここで落ちます。---------------------
    TestBlob
    TestWriteReadOnly
    SQLite3Free ' Quite optional
        
    Debug.Print "----- All Tests Complete -----"
End Sub

再現方法

「SQLite for Excel」 Excel VBAからSQLiteデータベースを使用する SQLポケリ　[SQLポケリ]を参考にします。

①Excel2016 64bitをインストールします。

②SQLite For Excel Version 1.0をダウンロード、任意のフォルダに展開。

③SQLiteForExcel-1.0\DistributionSQLiteForExcel_64.xlsmを起動

④マクロ→"AllTest"→実行

⑤該当のソースコード部分でエクセルが強制終了します。

発生している問題・エラーメッセージ

通常実行時 :
      エラーメッセージ：無し
      １：エクセルが落ちます。エラーはありません。
      ２：たまにエクセルが再起動します。

該当のソースコード

'//Sqlite3.bas

#If Win64 Then
Public Function SQLite3BackupStep(ByVal backupHandle As LongPtr, ByVal numberOfPages) As Long
#Else
Public Function SQLite3BackupStep(ByVal backupHandle As Long, ByVal numberOfPages) As Long
#End If
　　------------------------ここで落ちます。------------------------------
    SQLite3BackupStep = sqlite3_backup_step(backupHandle, numberOfPages)
　　--------------------------------------------------------------------
End Function

補足情報（FW/ツールのバージョンなど）

Excel2016 64bit
Microsoft???? Excel???? for Office 365 MSO (16.0.11601.20184)64ビット

VBA Ver1088

SQLite For Excel Version 1.0

Comments

[jkjksan]

Excel2016 32bitと
SQLite For Excelの32bit版（.xls）の組み合わせではAllTestが正しく動作する事を確認出来ています。

64bit混在環境での対応は出来ていません。

Answer 1

キータのコメントにありました。

@waka-hoihoi

2018-12-26 06:50
今現在(2018/12/26)、サンプルExcelのSQLiteForExcel_64.xlsmのAllTestsはこのままでは失敗します(EXCELが死にます)。以下のsqlite3_backup_init の宣言の関数の戻り値のタイプをLongPtrに変更する必要があるようです。

'Sqlite3_64.bas
'もしくは
'SQLiteForExcel_64.xlsmの標準モジュール"Sqlite3"

'Private Declare PtrSafe Function sqlite3_backup_init Lib "SQLite3" (ByVal hDbDest As LongPtr, ByVal zDestName As LongPtr, ByVal hDbSource As LongPtr, ByVal zSourceName As LongPtr) As Long
'↓
Private Declare PtrSafe Function sqlite3_backup_init Lib "SQLite3" (ByVal hDbDest As LongPtr, ByVal zDestName As LongPtr, ByVal hDbSource As LongPtr, ByVal zSourceName As LongPtr) As LongPtr

Comments

[ManabuWatanabe]

同じ事象で悩んでいたところ、ここのQ&Aに辿り着き、無事解決できました。ありがとうございます。