質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

87.60%

Excelで特定の列の値を新規Bookとして保存したい

解決済

回答 2

投稿 編集

  • 評価
  • クリップ 0
  • VIEW 7,257

score 12

前提・実現したいこと

Excelで特定の列の値を新規Bookに保存したい。

sheetをまるごと新規Bookとして保存することはできたのですが、特定の列の値のみを新規Bookに保存
する方法が分からず苦戦しています。

例えば

下記表があるとします。この表の列A1~C3には関数が入力されてあり、関数の結果が下記表の値となっ
て表示されています。
この表に対しマクロでC列の値を新規Bookに保存するVBAを記述するにはどのようにすればよいので
しょうか。

Book名:データ
Sheet名:LIST

A列 B列 C列
1行目 a001 b001 c001
2行目 a002 b002 c002
3行目 a003 b003 c003

試したこと

やり方がわからず、現状は上記表を列ごとにSHEETを分けて保存し、下記マクロで新規Bookに関数ごとコピーし作成しています。
関数ごとコピーして作成しているため、元のBook「データ」の値を参照しにいってしまう。参照させたくないため、値だけ保存
したいという所です。

Sub C_List()

Sname = Application.GetSaveAsFilename("C_List.xlsx", "Excel ファイル,*.xlsx;*.xlsm")

    If Sname = False Then Exit Sub
    Sheets("LIST").Copy 
    ActiveWorkbook.SaveAs Sname, FileFormat:=xlOpenXMLWorkbook

End Sub

補足情報(FW/ツールのバージョンなど)

office 2016

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 2

checkベストアンサー

+2

①ActiveWorkbookは現在アクティブなブック

nskydivingさんからも指摘がある通り、ActiveWorkbookは現在アクティブなワークブックを指すものです。
ActiveWorkbook("sname")では、アクティブなブックに対し、さらにブック名を指定しているような記述になってしまいますよね?

さらに変数名であるSnameを""で囲んでしまうと、変数に格納されていたブック名などとは関係ない、ただの"sname"という文字列として認識されてしまいます。

もう1点。
LISTシートのセル範囲("C:C")に対して、新規ブックのセル("A1")の値を入力する記述になっています。
この場合、LISTシートのC列のすべてのセルに、新規シートのA1セルの値が入力されることになります。
これは想定している動作(C列の値を新規ブックのA列にコピー)とは逆の動作になっていませんか?

おそらくやりたかったのは逆、つまり
Workbooks(Sname).Sheets("sheet1").Range("a:a").Value = Sheets("LIST").Range("c:c").Value
こうではないでしょうか?

②ブックやシートは明示する

ブックやシートをまたいで処理をする際は、できるだけ暗黙的な表記(ブックを省略してSheetsを指定する)とか、アクティブなシートやブックを指定した処理は行わない方がいいです。

処理の最中にアクティブなブックやシートが切り替わると、暗黙の参照先やアクティブブックなどが変わってしまい、意図しない動作の原因となるからです。

例えば新規ブックを作成するとそのタイミングで新規ブックがアクティブになりますし、処理の途中でユーザー操作によりブックやシートが切り替えられることもあるかもしれません。

対象のブックやシートは明示するのがエラー回避の第一手となります。

③どのブックを保存するのか?

現在の処理では、アクティブワークブックに対して「名前を付けて保存」をしています。
元ブックを別名で保存するということは、不要な列やシートまで一緒に保存されることになります。

今回の場合、保存したいのは現在のブックではなく、現在のブックからC列の値だけをコピーした新しいブックですよね?

つまり「現在のブックを、ファイル名を変えて保存」するのではなく、「新しいブックを作り、名前を付けて保存」するのが意図する流れだと思います。
新しいブックを作成するのはWorkbooks.Addです。

サンプルコード

以上を踏まえたサンプルです。

Sub Sample()

    '現在のブックを変数に保管(Activeなブックが変わっても参照できるように。変数は使わず、ThisWorkbookで参照するのも可)
    Dim wbSrc As Workbook
    Set wbSrc = ActiveWorkbook

    '新規ブックの作成
    Dim wbNew As Workbook
    Set wbNew = Workbooks.Add

    '元ブックのC列を、新規ブックのA列に値としてコピー
    wbSrc.Sheets("LIST").Range("C:C").Copy
    wbNew.Sheets("sheet1").Range("A:A").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

    'wbNew.Sheets("sheet1").Range("A:A").Value = wbSrc.Sheets("LIST").Range("C:C").Value      '←コピーはこれでも可。これだとクリップボードは使用しないが少し処理が遅くなる

    '名前を付けて保存
    Dim Sname As String
    Sname = Application.GetSaveAsFilename("C_List.xlsx", "Excel ファイル,*.xlsx;*.xlsm")
    If Sname <> "False" Then
        wbNew.SaveAs Sname, FileFormat:=xlOpenXMLWorkbook
    End If

    wbNew.Close

End Sub


以上です。

それぞれの処理で主要な命令については一度調べて、理解してからご利用されることをお勧めします。
参考になれば幸いです。

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2019/03/17 11:46 編集

    ご回答ありがとうございました。また、返信大変遅れ、ご心配をおかけしました。
    今回、教えて頂いたコードを使い、無事に問題を解決することができたのに加え、アドバイス頂いた点を活かし、他の処理にも水平展開することができたので、大変助かりました。
    また機会がありましたら、どうぞよろしくお願いします。

    キャンセル

0

セルの値のみをコピーしたい場合は、Value プロパティを使用します。

例:
ブックはあらかじめ開いておいてください。

Workbooks("book1.xlsx").Sheets("Sheet1").Range("A1").Value = Workbooks("book2.xlsx").Sheets("Sheet1").Range("A1").Value

今回の場合は、

  • 最初から値のみをコピーする。
  • セルをコピーしてから参照を値に変換する。

のどちらかになるかと思います。

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2019/03/03 15:36

    回答ありがとうございます。
    ”最初から値のみをコピーする”でいくことにします。
    早速以下を実行しましたが、エラー「実行時エラー'438'オブジェクトはこのプロパティまたはメソッドをサポートしていません。」
    となってしまいます。実際に書くコードを教えてもらうこと可能でしょうか。


    ```vba

    Sub C_List()

    Sname = Application.GetSaveAsFilename("C_List.xlsx", "Excel ファイル,*.xlsx;*.xlsm")

    If Sname = False Then Exit Sub
    Sheets("LIST").Range("c:c").Value = ActiveWorkbook("sname").Sheets("sheet1").Range("a1").Value
    ActiveWorkbook.SaveAs Sname, FileFormat:=xlOpenXMLWorkbook

    End Sub

    ```

    キャンセル

  • 2019/03/04 10:53

    「ActiveWorkbook("sname")」の書き方が間違っています。
    もし直すなら「Workbooks(Sname )」ですが、それでも全体としてはまだおかしいように思います。

    回答欄のコードをブック間コピーに変更しましたので、参考にしてください。

    キャンセル

  • 2019/03/07 21:46

    試したのですが、結局うまくいかなかったため、踏み台のシートに値のみコピーし、そのシートを新規Bookとして保存する方法に切り替えることにしました。

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 87.60%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

同じタグがついた質問を見る