【Excel VBA】フィルターをかけた後のデータ範囲で、1行目の見出しを選択できません。

Question

今日はVBAについてになります。
最終的に欲しい結果を記載します。

■欲しい結果
掲題の件の通り、フィルタリング後、I列の１行目（見出し）から一つ下セルに移動して、
そのセルから、最終行まで選択して削除するVBAを作成すること。です。

■できているところ
I列から一つ下のセルを選択する箇所以外

■できていないところ
0. 上記記載のI１セルを選択する

range("I1").select, range("A1").offset(0,8).select
```など
0. その下のセルを選択する箇所
色々調べていくうちに、.entireRow.HiddenやxlcelltypeVisibleなどが使えるようですが、よく分かりませんでした。

VBAはまだ中級いくかいかないか、そんな程度です。

■最後に、今のコードを記載いたします。
フィルタ条件が"<1999/12/31"になっているのは、1900年代の値をプログラムが抽出するためです。この値が必要ないため、VBAでここを削除するつもりでいます。

※下記の箇所がわからないところです。
その下の、ForNextや他にもDoUntil,Whileなどももっと良い処理があればご教示いただけますと幸いです。
ちなみに、範囲は固定ではありませんので、ループ処理を行っています。
つまり、データ範囲は可変で、最終行がさらに大きくなる可能性があることを考えての処理に現在しています。

よろしくお願いいたします。
```VBA
' ################  
' ここから  
' ################  
Range("A1").Activate  
Range("A1").Offset(0, 8).Select  
' ################  
' ここまで  
' ################ 

```VBA
Option Explicit
Dim MaxRow As Long
Dim MaxColumn As Integer
Public Sub フィルターで1900年代の値は削除する()
'
' 1900年代の値は、更新日、公開日ではないため、削除する。
    MaxRow = Range("A1").SpecialCells(xlLastCell).Row
    MaxColumn = Range("A1").SpecialCells(xlLastCell).Column
    
    'フィルターが既に設定されている場合、解除をして処理を抜ける。
    If ActiveSheet.AutoFilterMode = True Then
        Selection.AutoFilter
        Exit Sub
    End If
    
    ' フィルターが設定されていない場合の処理
    If ActiveSheet.AutoFilterMode = False Then
        Range("A1").Select
        Selection.AutoFilter
        '"I9"列の値<1999/12/31より前の日付でフィルターを掛ける。
        Range("A1").CurrentRegion.AutoFilter field:=9, Criteria1:="<1999/12/31", Operator:=xlAnd
        ' ################
        ' ここから
        ' ################
        Range("A1").Activate
        Range("A1").Offset(0, 8).Select
        ' ################
        ' ここまで
        ' ################
        Dim i As Long
        For i = 1 To MaxRow Step 1
            If Cells(i, 9).EntireRow.Hidden = False Then
                Exit For
            End If
                i = i + 1
        Next i
        ActiveCell.Select
    End If
        
    Range(Selection, Selection.End(xlDown)).Select
    ' 選択範囲をクリア
    Selection.ClearContents
    Selection.AutoFilter
    Range("A1").Select
End Sub

Answer 1

Sub test()
    With ActiveSheet
        If .AutoFilterMode Then .AutoFilter.Range.AutoFilter
        With .Range("A1").CurrentRegion
            .AutoFilter field:=9, Criteria1:="<1999/12/31"
            .Offset(1).Delete xlShiftUp
            .AutoFilter
        End With
    End With
End Sub

こんな感じでいいと思います。
フィルターモード中は非表示行は操作対象になりませんので、
ざっくり、表全体を指定しても大丈夫です。
さらにタイトル行を除いて操作対象にするなら、
これもざっくり1行分オフセットしてやればいいと思います。
まぁ比較的簡単にタイトル行を除外できますが、
1行余分に下の行を削除したところで空白行なので、
何の問題もないですよね？

With句の意味＆使い方は解りますかね？
.AutoFilter.Range.AutoFilter
↑の意味解りますかね？

Comments

[rara]

ありがとうございます。

こちらも検証しました。
上記の方と同じ理由で、
フィルター後の可視セル（表）全体がクリアされてしまってました????

.Offset(1)　これが１行分オフセットなら、
その位置から、
Range(Selection, Selection.End(xlDown)).Select
を使って最終行まで選択できそうかなと思ってます。

With句は　最初に対象となるオブジェクトを記載して、
そのあとにプロパティを記載していくって思ってます。

今、時間がなくて調べられないので、とりあえずご連絡まで。
ありがとうございます。続きを読む ∨

Answer 2

ご希望のことを簡潔にいうと、
I列の1900年代(1999/12/31以前)の値をクリアしたい。
ということだと解釈しましたが、あってますか。

非表示セルはClearContentsの対象外ですの下記でいいかと。

Sub フィルターで1900年代の値は削除する()
    With ActiveSheet.Range("A1").CurrentRegion
        'フィルターが既に設定されている場合、解除をして処理を抜ける。  
        If ActiveSheet.AutoFilterMode Then
            .AutoFilter
            Exit Sub
        End If
        .AutoFilter Field:=8, Criteria1:="<=1999/12/31"
        .Resize(, 1).Offset(1, 7).ClearContents
        .AutoFilter 'オートフィルター解除
    End With
End Sub

上記のコードを理解するのに参考になると思われるリンク

Office TANAKA - VBA高速化テクニック[Selectしない]

Office TANAKA - 今さら聞けないVBA[Withって何ですか？]

Office TANAKA - セルの操作[セル範囲の取得]

Excel VBA Offset とResizeを使いこなそう

Comments

[rara]

お返事ありがとうございます。

＞I列の1900年代(1999/12/31以前)の値をクリアしたい。
はい、その認識で間違いありません。

そのうえで、検証してみましが、
I列にフィルターをかけるようにしてもうまくいかなかったです。
何がうまくいかなかったのかは、
フィルター後のI列のデータはすべてクリアするのはいいのですが、
他の列のデータは残しておきたいです。

I列には日付が１列に入力されていて、他の列には他のデータが入っているので、
他のデータまで消されちゃうような形は困ってしまいます。

参考サイトありがとうございます。
リサイズは知らなかったです。大変参考になります。

[hatena19]

コードがテストに作成したデータ(C列に日付)のものだったので、I列に日付の場合に変更しておきました。変更したコードで試してみてください。

[rara]

ありがとうございます。
列が一つずれてましたが下記コードでしっかり１９９９年以降のものは削除されました。
'''VBA
End Sub
Sub フィルターで1900年代の値は削除するz()
With ActiveSheet.Range("A1").CurrentRegion
'フィルターが既に設定されている場合、解除をして処理を抜ける。
If ActiveSheet.AutoFilterMode Then
.AutoFilter
Exit Sub
End If
.AutoFilter Field:=9, Criteria1:="<=1999/12/31"
.Resize(, 1).Offset(1, 8).ClearContents
.AutoFilter 'オートフィルター解除
End With
End Sub
'''

最後に、
I列で１９９９年以前の日付のデータのみを抽出して、
このあとに、隣の、（隣でなくとも）J列、K列と２行はそのまま条件指定なしで、
.clearContetentsやDeleteできるようにするには、どうすればよいでしょうか。
詳細については下記になります。
１．I列を１９９９年以前でフィルタをかけて、I列のみ削除する　⇒　ここまで現在成功
２．J列、K列も上記フィルタを解除しないで、そのまま選択して、最終行までデータ削除を行う。　⇒　今回知りたい箇所

大変申し訳ございませんが、よろしくお願いいたします。続きを読む ∨

[rara]

自己解決にいたしましたが、
もとになったのは、教えていただいたコードになります。

上記質問の２のケースが今回解決したコードになっています。
ありがとうございました。

Answer 3

教えていただいたコードを結果的に下記のような形にして、
今回のご質問は無事解決いたしました。

教えていただき、ありがとうございます。

Sub Delete_DataBefore1999()
    With ActiveSheet.Range("A1").CurrentRegion
        'フィルターが既に設定されている場合、解除をして処理を抜ける。
        If ActiveSheet.AutoFilterMode Then
            .AutoFilter
            Exit Sub
        End If
        'I列のUpdated（更新日カラム）において、1999/12/31以前の日付のみを絞り込む
        .AutoFilter field:=9, Criteria1:="<=1999/12/31"
        .Resize(, 1).Offset(1, 8).ClearContents
        'J列の値が空でない場合、フィルタがかかっている表示J列の値をクリア
        .AutoFilter field:=10, Criteria1:="<>"""
        .Resize(, 1).Offset(1, 9).ClearContents
        .AutoFilter field:=11, Criteria1:="<>"""    '上記同様に、K列もクリア
        .Resize(, 1).Offset(1, 10).ClearContents
        .AutoFilter 'オートフィルター解除
    End With
    Range("A1").Select
End Sub