質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

87.59%

VBAで文字をクリックしたら丸囲みになるようにしたいです。

受付中

回答 1

投稿

  • 評価
  • クリップ 3
  • VIEW 5,427

score 12

現在、以下VBAを組んでおりますが、「実行エラー13 型が一致しません。」というのが、「Case ""」の部分で出てしまい原因不明でデバックできません。
恐れ入りますが、ご対策を御存じの方ご教授頂けないでしょうか。何卒よろしくお願い申し上げます。

win10 64bit
office 2016ただし2010でも対応のVBAで構築したいです。何卒よろしくお願い申し上げます。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Cancel = True
If Intersect(Target, Range("a1:af99")) Is Nothing Then Exit Sub
'↑の("a1:af99")の部分に、対象の範囲を自分で書き込む

Select Case Target.Value
Case ""
Target.Value = "○"
Case "○"
Target.Value = ""
End Select
End Sub

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

質問への追記・修正、ベストアンサー選択の依頼

  • date

    2019/02/27 11:57

    エラーが出るセルの状態は結合セルですか?

    キャンセル

  • nagadora

    2019/02/27 13:05

    結合セルではありません。

    キャンセル

  • takito

    2019/02/27 13:18

    ご提示のコードは私の手元では動きました。win10,64bit,excel2013
    Date さんのおっしゃるように結合セルの場合は同エラーが出ます。結合セルはtargetが配列になるためです。targetに何が入ってきてるか確認できますか?

    キャンセル

  • ttyp03

    2019/02/27 15:53

    質問タイトルと困っていることの内容があっていないので、タイトルの編集をお願いします。

    キャンセル

回答 1

+1

「質問への追記・修正の依頼」欄ですでにあげられているものも含めて、エラー原因がいくつか考えられます。

①引数として複数セルを受け取っている

例えばTarget引数として結合セルを受け取った場合です。
この場合Target.Valueでは値の取得ができず、エラーが発生します。

取得した複数のセルのうち、どのセルを対象に判定・書き込みを行うかを特定したコードにすることで解消できます。

②引数で受け取ったセルの値が、文字列と比較できない

例えばTarget引数として#VALUEのようなエラーとなっているセルを受け取った場合などです。
この場合、Taregt.Valueを暗黙的に文字列と比較することができず、エラーが発生します。
※エラー発生個所からみて今回はこちらが原因と思われます。

多くの場合Taregt.Textで比較することで回避できます。

サンプル

最終的に、上記2点はどちらも対応しておいた方がいいものです。
下記は、これを考慮したサンプルコードです。

サンプル① 複数セルの場合、先頭セルで処理をする

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Cancel = True

    'If Intersect(Target, Range("a1:af99")) Is Nothing Then Exit Sub
    ''↑の("a1:af99")の部分に、対象の範囲を自分で書き込む

    Dim rngArea As Range
    Dim c As Range

    '対象範囲内のセルを抽出
    Set rngArea = Intersect(Target, Range("a1:af99"))
    If rngArea Is Nothing Then Exit Sub

    '先頭セルを対象として取得
    Set c = rngArea.Cells(1)

    '対象セルを判定し、書き込みを行う
    Select Case c.Text
    Case ""
        Target.Value = "○"
    Case "○"
        Target.Value = ""
    End Select

End Sub

DoubleClickイベントにおいて、引数で複数セルを受け取るのは結合セルを指定したときくらいかと思います。
結合セルの対応であればサンプル①で事足りますが、他のイベントなどで「複数セルを受け取った時は、全てのセルを処理したい」ということもあるかと思いますので、参考までにサンプルコード②も作ってみました。

サンプル② 複数セルの場合、全てのセルに処理をする

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Cancel = True

    'If Intersect(Target, Range("a1:af99")) Is Nothing Then Exit Sub
    ''↑の("a1:af99")の部分に、対象の範囲を自分で書き込む

    Dim rngArea As Range
    Dim c As Range
    Set rngArea = Intersect(Target, Range("a1:af99"))
    If rngArea Is Nothing Then Exit Sub

    '複数のセル範囲から対象セルを1つずつ取り出すループ処理
    For Each c In rngArea.Cells
        '結合セルの場合、先頭セルのみ処理を行う
        If c.Address = c.MergeArea.Cells(1).Address Then

            '対象セルを判定し、書き込みを行う
            Select Case c.Text
            Case ""
                Target.Value = "○"
            Case "○"
                Target.Value = ""
            End Select

        End If
    Next

End Sub


注意しなければいけないのは、結合セルでもそれぞれのセルに対してループ処理が行われるという点です。
A1とA2を結合したセルに対してはA1で1回、A2で1回ループ処理が行われます。
このためA1で""⇒"○"に書き換えても、その後のA2の判定で"○"⇒""に戻されたりしかねません。

これを回避するため、結合セルではその先頭セルでのみ処理するようc.MergeArea.Cells(1).Addressの判定を追加しています。
結合セルであればその先頭セルの座標が返されますし、単一セルの場合はそのセルの座標が返されます。
これにより結合セルの先頭以外のセルでは処理が行われないようになります。

参考になれば幸いです。

投稿

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 87.59%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

関連した質問

同じタグがついた質問を見る