Range型を返す関数でエラーがでる。

Question

こんばんは、数時間考えても解決できなかったため質問させていただきます。
下に表と問題のコードを載せています。

表から、「あいう」を検索し、結果のセルに「はじめ」or「おわり」が含まれていたらそのセル位置をRange型で返す関数を作ったのですが、最後の「END FUNCTION」の部分で『実行時エラー '91': オブジェクト変数または With ブロック変数が設定されていません。』というエラーが出ます。

Range型を代入する際は"set"を頭につけるというのは下記コード内では全てやっているはずですが、このエラーの原因はなんでしょうか…？

必要な変数の型は間違ってないように見えるのですが、「END FUNCTION」でエラーがでるということは、上手く値を返せてないということでしょうか？

	A	B	C
1
2	あいう はじめ	6
3	あいう おわり	10

' 計算結果の表示処理
Sub displayResult()
    ' 開始セル、終了セルの場所を格納する変数を宣言
    Dim 開始セル As Range, 終了セル As Range
    ' 計算に必要な値が格納されているセルを検索
    開始セル = fnSchWord("あいう", "はじめ")
    終了セル = fnSchWord("あいう", "おわり")
    ' 両方とも結果ありの場合、計算結果を表示
    If Not 開始セル Is Nothing And Not 終了セル Is Nothing Then
        ' C3セルに計算結果を表示
        Range("C3").Value = 終了セル.Offset(1, 0).Value - 開始セル.Offset(1, 0).Value
    End If
End Sub

' A列からWord1を検索し、そのセルにWord2が含まれている場合、セルの場所を返す処理
Function fnSchWord(ByVal Word1 As String, ByVal Word2 As String) As Range
    ' 変数宣言
    Dim rngSearchPlace As Range, rngFirstCell As Range
    ' A列からWord1を検索
    Set rngSearchPlace = Range("A:A").Find(What:=Word1, LookAt:=xlPart)
    ' 結果有無判定
    If Not rngSearchPlace Is Nothing Then
        ' 比較用に1つめのセルの場所を保管
        Set rngFirstCell = rngSearchPlace
        ' ループで検索
        Do
            ' 検索したセルにWord2が含まれているか
            If InStr(rngSearchPlace.Text, Word2) > 0 Then
                ' そのワードの場所を返す
                Set fnSchWord = rngSearchPlace
            End If
            ' 次のWord1を検索してセルの場所を代入
            Set rngSearchPlace = Range("A:A").FindNext(rngSearchPlace)
        ' セルのアドレスが同じになった場合、ループを抜ける
        Loop While rngSearchPlace.Address <> rngFirstCell.Address
    Else
        ' 結果がない場合の処理
        Debug.Print Word1 & "の検索結果がありません"
    End If

End Function

Answer 1

返す方のRangeにもSetが必要になります。

    開始セル = fnSchWord("あいう", "はじめ")
    終了セル = fnSchWord("あいう", "おわり")

↓

    Set 開始セル = fnSchWord("あいう", "はじめ")
    Set 終了セル = fnSchWord("あいう", "おわり")

Comments

[cafeore_nmti]

盲点でした。こんな簡単なことに時間を取られてしまうとは…。
ありがとうございました(__)

[crowmt]

解決できて何よりです。

十分、分かってはいらっしゃってると思います。
「Range型を代入する際は"set"を頭につける」ってご自分でおっしゃってますので。
あと一捻りが結構でないですよね(^^;)

Offsetのところもエラーになるかと思いますが、サクッと修正できると思います。