Processingでゲームを作っています。マップチップを使って描画する方法について

Question

マップチップを使って、processing上でシューティングゲーム用の背景を描画しようと思いますが

マップチップに番号をつけると言うのは、マップチップエディタを使うと言うことでしょうか？

言語はjavaになります。

なるべく自分で考えて作りたいので、そういった技術のある方が居りましたらご教示いただきたいと思います。

可能でしたら、サンプルソースが置かれてるURL等教えていただけたら幸いです。

Answer 1

「マップチップに番号をつける」というのがプログラムの中での扱いなら「マップチップエディタ」なんて出てこないし、ファイルを加工する話ならプログラミングの話ではないので、ちょっとやりたいことが把握できないのですが...

やりたいことは「番号をつける」ことではなく、「プログラムの中で、連番をキーにマップチップの集合画像から任意の1個を取り出したい」という意味だと解釈して、「マップチップビューワー」とでもいうようなことをしてみましたが参考になりますでしょうか。

final int CHIPSIZE=16; //マップチップの一辺のドット数

//マップチップの集合画像をクラスとする
class MapChip {
  //集合画像本体
  PImage mapChipArray;
  //マップチップの総数、並びの幅、縦の数
  int mCount, mWidth, mHeight;

  //コンストラクタには集合画像のファイル名を与える
  MapChip(String file) {
    mapChipArray=loadImage(file);
    mWidth=mapChipArray.width/CHIPSIZE; //画像に含まれるマップチップの横並び数
    mHeight=mapChipArray.height/CHIPSIZE; //マップチップの縦の数
    mCount=mWidth * mHeight; //画像に含まれるマップチップの総数
  }    

  //「番号」を与えて画像を得る
  PImage getMapChip(int number) {
    if (number>=mCount) {
      return null;
    }
  //「番号」から画像の位置を求める
    int w=(number % mWidth)*CHIPSIZE;
    int h=(number / mWidth)*CHIPSIZE;
    return mapChipArray.get( w, h, CHIPSIZE, CHIPSIZE);//PImage::get()で画像を切り出す
  }
}

MapChip mp1;
boolean showOneTime;
int number;

void setup() {
  //画像は'マップチップ画像 無料'でググってトップにヒットしたものというだけで他意はありません
  mp1=new MapChip("http://img-cdn.jg.jugem.jp/93b/1453728/20120219_4859043.png");
  surface.setSize(mp1.mapChipArray.width, mp1.mapChipArray.height);
}

void draw() {
  if (!showOneTime) { //最初3秒間全体画像を表示
    image(mp1.mapChipArray, 0, 0);
    if (millis()>3000) {
      showOneTime=true;
      surface.setSize(320, 320);
    }
    return;
  }    

  PImage mapChip=mp1.getMapChip(number);
  //背景タイル表示
  for (int y=0; y<height; y+=CHIPSIZE) {
    for (int x=0; x<width; x+=CHIPSIZE) {
      image(mapChip, x, y);
    }
  }

  fill(0);
  rect(90, 40, 140, 180);
  fill(255);
  text("MapChip: "+number+" / "+mp1.mCount, 100, 50);
  image(mapChip, 100, 100, CHIPSIZE, CHIPSIZE);//原寸表示
  image(mapChip, 100, 150, CHIPSIZE*4, CHIPSIZE*4);//拡大表示
}

void keyPressed() {
  if (keyCode==DOWN) {//↓キーで前のマップチップ
    if (--number<0) {
      number=mp1.mCount-1;
    }
  } else if (keyCode==UP) {//↑キーで次のマップチップ
    if (++number>mp1.mCount-1) {
      number=0;
    }
  }
}

Comments

[kuriboros]

ありがとうございます。とっかかりがつき辛かったので。助かりました。実行しながら勉強続けてみます。