vbaで今日の日付から30日前までの日付を抽出したい

Question

VBA初心者です。

今日の日付から30日前までの日付を出力したいです。

例　
D10,E10,F10,G10.....AG10
2019/1/4,2019/1/5,2019/1/6,2019/1/7...2019/2/3

調べても解決できませんでした。

宜しければご教授下さい。

Answer 1

＞調べても解決できませんでした。
ということですが、具体的にはどう調べて、何が解決できなかったのでしょうか？
参考になるサイトが見つからなかったのか、何かを参考にコードを書いてみたけどエラーが発生したとか、期待する結果にならなかったとか。

もう少し質問内容を具体的に書き足していただかないと、ほぼ丸投げの質問となってしまっていますよ。

やりたいことを整理する

今回やりたいことは多くの人が普通に使う内容なので、ネット上でも簡単な検索でたくさん情報が見つかるはずです。

これが見つけられなかったのであれば「検索の仕方の問題」であり、実現しようとしていることに対して「具体的にイメージができていない」から効率的な検索ができないのかもしれません。

今回やりたいことを整理すると、大きく分けて３つの内容があると思います。

①当日の日付を取得する
②日付の減算をする
③②の処理を繰り返す(30日分)

これらをそれぞれ検索してみることがまず第一歩になると思います。

以下は①～③についてのアドバイスです。
セルに日付を出力し、そのセルの値から減算する方法はttyp03さんから提供されていますので、私からはVBA上で計算する方法でご紹介します。

①当日日付の取得

これは「VBA 当日日付の取得」で検索すればすぐにいくつかの方法が見つかります。

当日日付を取得する関数はDate関数です。
ちなみに現在日時で取得したい場合はNow関数、時間だけ取得したい場合はTime関数というものを使います。

'当日日付の取得
Dim dtToday As Date
dtToday = Date()

②日付の減算

これも「VBA 日付の計算」のような検索すれば情報が見つかります。

VBAで日時の加減算をする関数はDateAdd関数です。
この関数を使うと、単位(年・月・日・時・分・秒など)を指定して日時の加減算が行えます。

ただし、日付型の値に対して単純に+1とか-1をするだけでも"日付"の単位で加減算してくれますので、今回の場合はこちらでも算出できます。

'当日日付の取得
Dim dtToday As Date
dtToday = Date()

'1日前
Dim dtYesterday As Date
dtYesterday = DateAdd("D", -1, dtToday) '"日付"を単位として-1"日"します
'dtYesterday = dtToday - 1              '"日付"単位の加減算の場合はこれでも同じ結果になります

③処理を繰り返す（ループ処理）

これは「VBA ループ処理」のような検索すれば情報が見つかります。

ループ処理には「For～Next」「For Each～Next」「Do～Loop」などいくつかありますが、今回のように決められた回数をループする場合は「For～Next」が最適だと思います。

    '当日日付の取得
    Dim dtToday As Date
    dtToday = Date
    
    '30回のループ処理（iCntを29から-1ずつ0になるまで繰り返す）
    Dim iCnt As Integer
    For iCnt = 29 To 0 Step -1
        'D10セルからAG10セルに値が出力される
        Cells(10, 33 - iCnt) = DateAdd("D", -iCnt, dtToday)
        'Cells(10, 33 - iCnt) = dtToday - iCnt                  'こちらでも同じ結果になります
    Next

---

以上、参考になれば幸いです。

Answer 2

VBAを使うまでもないと思いますが、使うのであれば次のようにループで回せばよいでしょう。

Dim ws As Worksheet
Dim AG As Long
Set ws = Worksheets("Sheet1")
AG = 33
ws.Cells(10, AG).Value = Now
For n = 1 To 29
    ws.Cells(10, AG - n).Value = ws.Cells(10, AG - n + 1).Value - 1
Next

VBAを使わない場合、Excelシートで上で数式を使えば簡単です。

AG10セル
=NOW()

AF10セル
=AG10-1

あとはAF10セルをD10セルまでコピペすればOK。

Answer 3

AutoFillとか、RangeのDataSeriesを使うとできるようです。

https://www.moug.net/tech/exvba/0050165.html

Answer 4

ありがとうございます。

漠然とした質問ではなくもう少し調査した内容などを記載し、質問する事とします。

丁寧にありがとうございました。