vbsによる、ネットワークドライブ間のフォルダ移動。

Question

VBScriptについてご教授下さい。
下記ですが、どうしてもうまく動きません
わかる方いらっしゃいましたら、ご教示願います

1,作成したVbsファイルは、デスクトップに置きます。

2、指定したネットワークドライブの「フォルダA」に当日の日付フォルダを作成する
例えば2019/01/7だったら、フォルダ名「20190107」

3、指定したネットワークドライブの「フォルダB」にあるサブフォルダ及びファイル(毎日生成されます)を全て、2、で作成したネットワークドライブの「フォルダA」の日付フォルダに移動。

4,指定したネットワークドライブの「フォルダB」にあるサブフォルダ及びファイルが、無ければ、何もしない。

修正したい部分ですが以下のコードで、
・ローカルドライブのフォルダ同士だと、サブフォルダ及びファイルの移動可能。
・ネットワークドライブのフォルダ同士だとファイルの移動は、可能だが、サブフォルダは、何故か移動できないので、サブフォルダも移動したいのですが。

Option Explicit

Dim a, b, d, gf, f, m, so
Set so = CreateObject("Scripting.FileSystemObject")
gf = so.GetParentFolderName(WScript.ScriptFullName)
a = "E:\フォルダA"
b = "F:\フォルダB"
d = a & "\" & Replace(Date, "/", "")
If so.FolderExists(d) = False Then
so.CreateFolder(d)
End If
Set m = so.GetFolder(b)
For Each f In m.SubFolders
so.MoveFolder b & "\" & f.Name, d & "\" & f.Name
Next
For Each f In m.Files
so.MoveFile b & "\" & f.Name, d & "\" & f.Name
Next
Set m = Nothing
Set so = Nothing
MsgBox("Finishi!")

Answer 1

フォルダの移動、じゃなく、
・新規フォルダを作成
・そこへファイルを移動
・旧フォルダを削除
でやればいいんでは

Comments

[yukishi]

なるほど、そういう考えが、ありますか、勉強になります。

Answer 2

FileSystemObjectのコピー移動削除の仕様調査結果 - バグ取りの日々.html

MoveFolder(ドライブ間フォルダ移動)

..

OSの環境依存のようです。筆者環境(Windows10)でMoveFolderは移動不可でした。CopyFolderとDeleteFolderで代用可能です。

とのことだったので、CopyFolderとDeleteで元のコードを少し変えてみました。

a = "X:\フォルダA" ← ネットワークドライブ
b = "C:\フォルダB" ← ローカル

と

a = "D:\フォルダA" ← ローカル
b = "C:\フォルダB" ← ローカル

という環境で試した感じではうまく動いているようです。

Option Explicit

Dim a, b, d, gf, f, m, so

Set so = CreateObject("Scripting.FileSystemObject")

gf = so.GetParentFolderName(WScript.ScriptFullName)
a = "X:\フォルダA"
b = "C:\フォルダB"

d = a & "\" & Replace(Date, "/", "")

If so.FolderExists(d) = False Then
  so.CreateFolder(d)
End If

so.CopyFolder b, d, true

Set m = so.GetFolder(b)
For Each f In m.SubFolders
  f.Delete
Next

For Each f In m.Files
  f.Delete
Next

Set m = Nothing
Set so = Nothing

MsgBox("Finishi!")

Answer 3

ネットワークドライブのフォルダ同士だとファイルの移動は、可能だが、サブフォルダは、何故か移動できないので、

VBScript、Windows ScriptingのリファレンスでMoveFileメソッドの項を見ると、
MoveFile メソッド

** メモ このメソッドを使用してボリューム間でファイルを移動できるのは、オペレーティング システムでボリューム間のファイル移動がサポートされている場合だけです。 **

とあります。リモートマシンのファイルシステム上にあるネットワークドライブは、ローカル<-->リモートとマシン間をまたぐことになり、単純な移動で済まなくなり、そこまではサポートできない為でしょう。（リモートマシンのフォルダーの下のサブフォルダーが、また別のハードディスクドライブにマウントされているようなケースも考えられます）

MoveFileメソッドの内部で恐らく使われているはずのWin32 API のMoveFile では、

関数は、ファイルまたはディレクトリを（ディレクトリの場合は、その子も含め）移動し、指定された場合は名前の変更も行います。移動先は、同じディレクトリでもかまいませんし（この場合は名前の変更のみ）、他のディレクトリでもかまいません。ただし、ディレクトリを他のボリュームへ移動しようとすると、MoveFile 関数が失敗することに注意してください。

とあり、関連していそうです。先のy_waiwaiさんの回答にあるように、がんばって自力で処理する必要があると思います。

Comments

[yukishi]

私も、調べたのですが、やはり、
フォルダ移動は、出来そうも無いですね。いろいろ調べて頂きまして、ありがとうございます