AccessからExcelファイルを作成すると必ず非表示の状態で保存されてしまう

Question

前提・実現したいこと

AccessからVBAで雛形となるExcelファイルを使って新規Excelファイルを出力させたいです。

発生している問題・エラーメッセージ

出力されたファイルを開くと必ず非表示の状態で開かれます。
そのため、Excel画面の「表示タブ」→「再表示」からブックを表示させないと内容を見ることができません。
再表示させた状態で上書き保存をし、ファイルを閉じてもう一度開くと普通に表示されます。

該当のソースコード

標準モジュールに記載して実行

Option Compare Database

Public Function test01()
    Dim strReadPath As String, XL As Object, WB As Object, WS As Object
    Set XL = CreateObject("Excel.Application")
    XL.Visible = False
    XL.DisplayAlerts = False
    Set WB = GetObject(CurrentProject.Path & "\test.xlsx") '雛形を取得
    Set WS = WB.Sheets(1)
    WS.Name = "Sheet1"
    WS.Cells(1, 1) = "サンプルテキスト"
    WB.SaveAs FileName:=CurrentProject.Path & "\output.xlsx" '保存
    'XL.Windows("output.xlsx").Visible = True
    'WB.Save
    If Not WB Is Nothing Then WB.Close: Set WB = Nothing
    If Not XL Is Nothing Then XL.Quit: Set XL = Nothing
End Function

試したこと

全く新しいAccessファイルと、全く新しい雛形ファイルを用意して同じプログラムを実行しましたが同じ症状になりました。
上記ソースコードの下から4行目と5行目、コメント化されている箇所のコメントを解除して実行すると、きちんと表示されるのですが、他のExcelブックを開いた状態で実行するとそこでエラーになります。

補足情報（FW/ツールのバージョンなど）

Windows 10 Home 64bit
Microsoft Access 2013
Microsoft Excel 2013

Accessの参照設定：
Visual basic For Applications
Microsoft Access 15.0 Object Library
OLE Automation
Microsoft Office 15.0 Access database engine Object Library
Microsoft Excel 15.0 Object Library

Answer 1

対策としては、hatena19さんの回答が個人的にはベストだと思います。

---

以下補足（蛇足）を

質問のコードではCreateObject("Excel.Application")とGetObject("Excelブック")の両方を行っていますが、これらはどちらか一方にするべきです。

両方行っているため「他のExcelブックを開いた状態で実行するとそこでエラーになります。」などのエラー発生の原因となります。

それぞれの動作を確認しておくと
CreateObject("Excel.Application")は常にExcelの新規インスタンスを生成します。

対してGetObject("Excelブック")は
"Excelブック"がすでに開かれている場合は、開かれているブックを捕捉。
"Excelブック"が開かれていない場合は、Excelが起動していないければ起動、起動していれば既存のインスタンスを取得し、取得したExcelのインスタンスで**「ブックのウィンドウを非表示にして」**ブックを開きます。

そのため、CreateObjectで生成したExcelのインスタンスと、GetObjectで取得したブックが開かれているExcelのインスタンスが一致しない可能性があります。
そして、一致しない場合にXL.Windows("output.xlsx").Visible = Trueでエラーが発生します。

また前述の通り、GetObjectでは編集中のブックを捕捉する可能性があるため、WB.Closeで強制的に閉じるのはユーザーにとって思わぬ動作となる可能性があります。

改めての確認として、対策としてはhatena19さんの回答にあるように、「新規生成したExcelのインスタンス」で、ブックを開いて処理するのがベターだと思われます。

Workbooks.OpenならGetObjectのようにウィンドウを非表示にしませんし、
新規生成したExcel内で処理するため、ユーザーの操作に影響が出にくいと思われるためです。

---

「雛形」ということを明示するのであれば、Workbooks.Openではなく、既存のブックを元に新規ブックを生成するWorkbooks.Addの方が良いかもしれませんね。

    Set WB = XL.Workbooks.Add(CurrentProject.Path & "\test.xlsx") '雛形を取得

Comments

[Himamura]

ご回答ありがとうございます。

GetObjectとCreateObjectの違いを細かく解説していただきありがとうございます。
明確に違いがあって、私は使い方を間違えていたんですね^^;
数年勘違いしながら使っていたのですが、ようやく理解できたように思います。

Answer 2

    Set WB = GetObject(CurrentProject.Path & "\test.xlsx") '雛形を取得

を、下記に修正

    Set WB = XL.Workbooks.Open(CurrentProject.Path & "\test.xlsx") '雛形を取得

でどうでしょうか。

Comments

[Himamura]

ご回答ありがとうございます。いつもhatena19さんのブログ、拝見しています。hatena19さんに回答いただけて嬉しいです^_^

ご回答の方法で解決しました！
他のブックを開いている状態でも正常に動作いたしました。

一番早く回答をいただけたのでベストアンサーとさせていただきます。

Answer 3

こんにちは。
https://teratail.com/questions/160186?modal=q-comp

私の質問に関係していると思いました。URLを貼っておきます。

Comments

[Himamura]

ご回答ありがとうございます。

おかげさまでGetObjectとCreateObjectの違いがよくわかりました。
CreateObjectのほうが私の意図するように動くように思いましたので、これからはCreateObjectを使っていこうと思います。