Selenium Basicで、ブラウザウィンドウを指定する記述方法

Question

前提・実現したいこと

お忙しい中恐れ入ります。
Selenium BasicをVBE上で起動し、指定したセルに記述したURLを
1,自動で開く →　2,指定したウィンドウサイズに変更　→　3,画面キャプチャ取得　→　4,指定した名前で保存
まで行いたいですが、2,指定したウィンドウサイズに変更 を行う記述をどうすればよいかわかりません。

下記は、親切な方が公開頂いている、2を除く処理を実行することができるソースですが、
こちらのどこにどのような記述をすればよいかご教授いただけないでしょうか？

Sub takeScreenShot()
Dim driver As ChromeDriver
Dim i As Long
Dim destURL As String
Dim flag As Boolean
Dim imageFileName As String

Set driver = New ChromeDriver
Call driver.Start
driver.Manage.Window.Maximize
driver.Timeouts.ImplicitWait = 10000           'Seleniumの読み込み待機時間
'driver.Window.Maximize
driver.baseUrl = "www.google.co.jp"
driver.manage().window().maximize()
With ThisWorkbook.Worksheets("Sheet1")
    For i = 1 To .Cells(1, 1).End(xlDown).Row
        If .Cells(i, 1) = "" Then
        Else
            If InStr(.Cells(i, 1), "//") = 0 Then
                destURL = "//" & .Cells(i, 1)
            Else
                destURL = .Cells(i, 1)
            End If
         
            flag = driver.Get(destURL)
            If Not flag Then
                MsgBox (.Cells(i, 1).Value & "のページの読み込みに失敗しました。")
            End If
            
              'URLにスラッシュが入るとフォルダごとに分けられるので、アンダーバーに置換
              'スラッシュごとにフォルダに分けたい場合は、次行のimageFileName を.cells(i, 1).Valueに置き換え
            driver.takeScreenShot.SaveAs "C:\Users\ユーザー名\Desktop\テスト\" & .Cells(i, 2) & ".jpg"
        End If
    Next
End With
driver.Close

End Sub

恐れ入りますが、ご回答お待ちしております。

Comments

[mix-peach]

古いですが、似た質問を見つけました。。。https://teratail.com/questions/1463
「画面の最大化」の仕方が同じようなので、サイズ変更も同じようにできるかも？

Answer 1

初めてSelenium Basic使いましたが、ActiveXでIEを操作するよりも簡単でできることが多い印象で、便利ですね。

さて、ご希望の内容ですが、以下のような感じでしょうか

Sub takeScreenShot_edited()
    Dim driver As ChromeDriver
    Set driver = New ChromeDriver
    
    Dim i As Long
    
    Dim url(1) As String
    url(0) = "/tags/VBA"
    url(1) = "/questions/163641"
    
    With driver
        .Start
        '***ココがご希望の部分かと思います SetSize(width, height)のようです
        .Window.SetSize 1024, 768
        '***
        .baseUrl = "https://teratail.com"
        
        For i = 0 To 1
            .Get url(i)
            .takeScreenShot.SaveAs "C:\Users\test\Desktop\123\" & i & ".jpg"
        Next

        .Close
    End With
End Sub

なんか、いろいろ無駄な処理が多いように感じましたが、苦労の痕なのかな？と理解し、コードだけで動くように、最低限の記述とし、URLを配列に入れて処理していますので、セルからのURL取得などはご自身で工夫してみてください。

ご確認くださいませ。