Accessフォームのデータタブのコントロールソースの値をテキスト出力したい

Question

https://teratail.com/questions/140150
において他のAccessファイルのマクロをテキスト化する方法は
分かったのですが、似たような方法でフォームのデータタブの
コントロールソースの値をテキスト出力する方法は
ありますでしょうか？

宜しくお願いいたします。

Answer 1

とりあえず指定したデータベースファイルの全フォームのコントロールのコントロールソースをイミディエイトウィンドウに出力するコード例です。

Sub ExportControlsource()
    
    Dim strDB As String
    strDB = "C:\TEST\テスト.accdb"

    Dim appAccess As Access.Application
    Set appAccess = CreateObject("Access.Application")
    '対象のAccessデータベースを開く
    appAccess.OpenCurrentDatabase strDB

    '全フォームを参照する
    Dim acObj As AccessObject
    For Each acObj In appAccess.CurrentProject.AllForms
        'フォームをデザインビュー/非表示で開く
        appAccess.DoCmd.OpenForm acObj.Name, acDesign, , , , acHidden
        Debug.Print "フォーム名: " & acObj.Name
        Debug.Print "コントロール名 / コントロールソース"
        
        'フォーム上の全コントロールの参照
        On Error Resume Next 'ControlSourceがない場合エラーになるのを無視する
        Dim acCtl As Access.Control
        For Each acCtl In appAccess.Forms(acObj.Name).Controls
            Debug.Print acCtl.Name & " / " & acCtl.ControlSource
        Next
        On Error GoTo 0
        appAccess.DoCmd.Close acForm, acObj.Name, acSaveNo
    Next
    appAccess.CloseCurrentDatabase
    appAccess.Quit
    Set appAccess = Nothing

    MsgBox "処理終了"
End Sub

テキストに出力する場合は、下記のリンク等をご参考に。

エクセルVBAでテキストファイルに書き出す最も簡単なプログラム

Comments

[kamiyui_bidan]

ご回答ありがとうございます。
上記コードのパスを、調査対象のパスに変えて実行してみたところ、サブフォームが無いフォームではうまくいくのですが、サブフォームがあるフォームですと、
DoCmd.Close acForm, "acObj.Name, acSaveNo"
を実行しているのに(""無しバージョンでも改善されず)
appAccess.DoCmd.OpenForm acObj.Name, acDesign, , , , acHidden
の所で「実行時エラー　7784　選択したオブジェクトは、サブフォームまたはサブレポートとしてデザインモードで既に開かれています。～」が発生します。

回避方法はありますでしょうか？

[hatena19]

「実行してみたところ」って何を実行したのか不明なのですが、
どちらにしても、サブフォームや帳票フォーム等の連結フォームは使用していないと思います。非連結フォームに表レイアウトにあるようにコントロールを配置していると思われます。でないと、ドラッグ& ドロップは不可能。
また、動的にコントロールを配置するのではなく設計時に必要数のコントロールを配置しておいて、必要に応じて表示、移動する設計にすべきだと思います。（そうすればデザインビューでなくても可能。）
動画ではどのようにしているのか、ソースがないので、推測でしてないですし、どのようにしているのか私にはわからない部分もあります。

[kamiyui_bidan]

＞「実行してみたところ」って何を実行したのか不明

「教えていただいたコードのファイルパスをこちらの環境に合わせて、VBAを実行」の意味でした。

＞サブフォームや帳票フォーム等の連結フォームは使用していないと思います。

サブフォームのレコードソースにSelect文が設定されてるので、「連結されている」って認識でいいでしょうか？

因みに手動で親フォームを開いて、そのまま子フォームを開こうとすると、手動なのでエラーコードは出ないですが、VBA実行時と同じ「選択したオブジェクトは～」メッセージが表示されます。

acSubform　という予約語をネットで見つけましたので、これを使って試行してみます。

＞移動する設計にすべきだと思います。

既存システムなので、私の方ではどうしようもない状態です（データの取得元変更などの改修の為の調査）

＞動画

動画とは？

[hatena19]

前のコメントは、別の質問と勘違いしてのコメントでしたので無視してください。

[hatena19]

DoCmd.Close acForm, "acObj.Name, acSaveNo"

上記ののコードが間違ってました。
下記に修正してください。（回答の方も修正しておきました。）

appAccess.DoCmd.Close acForm, acObj.Name, acSaveNo

Answer 2

"ControlSource/コントロールソース" プロパティから取得できます。

フォームやコントロールの一覧から取得する場合は、以下を参考に。
フォームのコントロール一覧を取得する
Controls オブジェクト (Access)
Forms object (Access)