awkで１つのファイルを条件によって２つのファイルに分割したい

Question

＃プログラム初心者です。

前提・実現したいこと

awkを使用して、以下のファイルを２つに分割したいと思っています。

cat org.txt

@@@@@@@@@@@@
商品：りんご
産地：青森
補足：値引きあり
出荷状況：済み
@@@@@@@@@@@@
商品：みかん
産地：静岡
出荷状況：未
@@@@@@@@@@@@
商品：ぶどう
産地：山梨
出荷状況：済み

このファイルの“出荷状況”が“済み”と“未”の場合で以下のようにファイルを分割したいのです。

cat syukka.txt

@@@@@@@@@@@@
商品：りんご
産地：青森
補足：値引きあり
出荷状況：済み
@@@@@@@@@@@@
商品：ぶどう
産地：山梨
出荷状況：済み

cat misyukka.txt

@@@@@@@@@@@@
商品：みかん
産地：静岡
出荷状況：未

試したこと

awk初心者なのですが、配列を使うのかと試したのですが、太刀打ちできませんでした・・・
どのようにすればよいかご教授下さい。

以上、宜しくお願いします。

Answer 1

いわゆる「複行レコード」ですね。レコードセパレータの設定を変更すれば対応できます。

test.awk:

BEGIN{
  FS="\n"
  RS="@@@@@@@@@@@@\n"
}
/出荷状況：済み/{print RS,$0}

$ awk -f test.awk org.txt > syukka.txt

Comments

[jjjr]

ご回答ありがとうございます。
この発想はありませんでした。
色々と使えるテクニックだと思います。

Answer 2

こんな漢字で、

$ cat org.txt|awk '/^@/{if(a)print a;a=$0};!/^@/{a=a"&"$0}END{print a}'|grep '出荷状況：済み'|tr '&' '\n' > syukka.txt
$ cat org.txt|awk '/^@/{if(a)print a;a=$0};!/^@/{a=a"&"$0}END{print a}'|grep '出荷状況：未'|tr '&' '\n' > misyukka.txt

$ cat syukka.txt
@@@@@@@@@@@@
商品：りんご
産地：青森
補足：値引きあり
出荷状況：済み
@@@@@@@@@@@@
商品：ぶどう
産地：山梨
出荷状況：済み

$ cat misyukka.txt
@@@@@@@@@@@@
商品：みかん
産地：静岡
出荷状況：未

Comments

[jjjr]

ご回答有難うございます。
後から特定文字を改行コードに変換して修正しているのですね。
勉強になります。

Answer 3

awk '
/^@@*/{save=$0;next}
/^出荷状況：済み/{print save>"syukka.txt";print > "syukka.txt";next}
/^出荷状況：未/{print save>"misyukka.txt";print > "misyukka.txt";next}
{save=save "\n" $0}
' org.txt

Comments

[jjjr]

早々のご回答、有難うございます。
大変恐縮なのですが、一点サンプルに漏れがありました。
”出荷状況”の下にも、場合によってコメントが入るケースがありました。
現状ご提示頂きましたコードの場合、出荷状況で区切っているのですが、
次の”＠＠＠”が来る手前までで一つの纏まりとなるように認識させる方法はございますか？
お手数をお掛け致しますが宜しくお願いします。

Answer 4

KojiDoi さんの回答を元にして書いてみました。

a.awk

BEGIN {
  FS="\n"
  RS="@@@@@@@@@@@@"
}
/出荷状況：済み/ {print RS,$0 > "syukka.txt"}
/出荷状況：未/   {print RS,$0 > "misyukka.txt"}

実行例

追記：
org.txt の先頭に

＃○○店
＃出荷状況について

があった場合、 syukka.txt, misyukka.txt の先頭にもそれを出力するようにしてみました。
(上のコードでは、余分が改行が出力されていたので、 print -> printf に変更して余分な改行がでないよう修正もしています)

BEGIN {
  FS="\n"
  RS="@@@@@@@@@@@@"
  out_0="misyukka.txt"
  out_1="syukka.txt"
}

/＃出荷状況について/ {printf $0 > out_0; printf $0 > out_1}
/出荷状況：未/   {printf "%s%s", RS,$0 > out_0}
/出荷状況：済み/ {printf "%s%s", RS,$0 > out_1}

実行例

Comments

[jjjr]

ご回答ありがとうございます。
私も先ほどご提案頂いたようなコードにしたところでした。
余談ですが、org.txtの先頭行に以下の行があった場合、
＃○○店
＃出荷状況について
”(空白)”

この３行を作成した２つのファイルの先頭にも入れたいと思います。
(現在は別ファイルに分割しておき、catで足しています)
今回のawkのファイル中に併せて追加できるのでしょうか?
やはり今回はレコードセバレータの設定を変更しているので、別コマンドの方が
いいのでしょうか？
一旦解決済みにしていたのにすみません。

[KojiDoi]

そのケースだと、RS変更後の「1行目」にそれらがまるごと入っているはずですね。NR==1のときにはそれらをそのままそれぞれのファイルに出力してあげるルールを追加し、既存のルールはNR>1 && /出荷状況：済み/{...}のように変更すればいいと思います。

[jjjr]

ご返信ありがとうございます。
ただ今帰社した所なので、明日また挑戦してみます。

[katoy]

回答に対処例を追記しました。

Answer 5

デバッグしてないので、なんかあったらすんません

BEGIN{
  s = ""
  f = 0
}
/出荷状況：済み/ {
  f = 1
}
/出荷状況：未/ {
  f = 2
}
/@@@@@@@@@@@@/ && s != "" {
  if (f == 1) outf = "syukka.txt"
  if (f == 2) outf = "misyukka.txt"
  n = split(s, ss)
  for (i=1; i<=n; i++) {
    print ss[i] >> outf
  }
  s = ""
  f = 0
}
{
  s = s,$0
}
END {
  if (f == 1) outf = "syukka.txt"
  if (f == 2) outf = "misyukka.txt"
  n = split(s, ss)
  for (i=1; i<=n; i++) {
    print ss[i] >> outf
  }
}

もし空白を含む行があったら改行がふえます。
--- 追記 ---

head -n 3 src.txt >syukka.txt
cp syukka.txt misyukka.txt
x=`wc -l src.txt`
x=`expr $x - 3`
tail -n $x src.txt | awk -f hoge.awk

Comments

[jjjr]

ご回答有難うございます。
すみませんが、下記の行はどのような動作を目的としているのでしょうか？
　s = s,$0
以上、宜しくお願いします。

[takasima20]

s = s $o だと直接連結になりますが、
s = s,$0 は間に空白を挟んだ連結になります。

[jjjr]

ご返信ありがとうございます。
明日またテストしてみます。

[takasima20]

失礼。tail のとこミスってました。