バッチファイルでの&がエスケープできない場合の解決策

Question

前提・実現したいこと

&のエスケープについて。
下記は、現在の日時がファイル名になり、ファイルの内容にログを書き込むというバッチファイルのプログラムです。
ログに&を含む文言を書き込みたいです。
（本当に実現したい内容は別ですが、これが解決すれば実現できます。）

発生している問題・エラーメッセージ

下記が実行できません
call :log_command aaa^&bb

該当のソースコード

@echo off
setlocal enabledelayedexpansion

set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%
set now_date=%year%%month%%day%

call :log_command aaa^&bb
exit /b


:log_command

set hour=%TIME:~0,2%
set minute=%TIME:~3,2%
set second=%TIME:~6,2%
set now_time=!hour!:!minute!:!second!

echo !now_time! %1
echo !now_time! %1 >> %~dp0%now_date%.log
exit /b

試したこと

下記のようにするとaaaまでしか書き込めません。

call :log_command aaa&bb

全角にすれば書き込めますが、求めているものと違います。

call :log_command aaa&bb

""を使えばエスケープできますが、""が残ってしまいます。
変数に入れて切り出せば""は消去できますが、やっぱり&は出力できません。

call :log_command "aaa&bb"

どこを読んでも、&は^でエスケープできると書いてありますが、どうしても&が出力できません。
お力添えいただければ幸いです。よろしくお願いします。

補足情報（FW/ツールのバージョンなど）

windows7

Answer 1

こんな漢字で、

call :log_command "aaa&bb"

for %%a in ("%~1") do echo !now_time! %%~a
for %%a in ("%~1") do echo !now_time! %%~a >> %~dp0%now_date%.log

Comments

[kobayashitomoya]

回答をお寄せいただきありがとうございます。
非常に勉強になりました！ありがとうございました！

Answer 2

これ、前に調べたんですけど、現象が解明できませんでした。
今回だと、下記で出来ると思います。
本来やりたいことも同様に出来れば良いのですが。

別案としては、引数で渡さずに、グローバル変数として環境変数にセットして渡し、遅延展開で参照する。

@echo off
setlocal enabledelayedexpansion

set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%
set now_date=%year%%month%%day%

call :log_command "aaa&bb"
exit /b

:log_command

set hour=%TIME:~0,2%
set minute=%TIME:~3,2%
set second=%TIME:~6,2%
set now_time=!hour!:!minute!:!second!

set "ARG=%~1"
echo !now_time! !ARG!
echo !now_time! !ARG! >> %~dp0%now_date%.log
exit /b

Comments

[kobayashitomoya]

このたびは、教えていただいてありがとうございます！
いただいたコードを元に、コネコネしたところ、本来やりたいことの方も無事解決しました！
私一人なら、50時間以上かかって途方にくれていたと思います。
ベストアンサーにさせていただきます。