【batファイル】各フォルダのサイズが取得できない

Question

任意のドライブ配下の各フォルダの名前とサイズをテキストファイルに出力したく、下記サイトを参考にバッチファイルを作成したのですが
ファイル名のみ取得できてサイズが空欄になってしまっている状況です。

https://maigo-pg.seesaa.net/article/368261283.html

フォルダ内には、「test_a」、「test_b」というフォルダがありそれぞれ90byte、10byteあります。
作成したバッチファイルは下記のとおりで、ほぼそのままなのですがどこかにミスがあるのでしょうか。

試したことは、管理人とし実行してみたり出力先やpushdを別の場所にしてみたりましたが解決できませんでした。
お手数ですがどうすればサイズが表示されるか教えていただけますでしょうか。

echo off

Set logPath=F:\user\bat\sizelist.txt

if exist %logPath% del %logPath%
set title=file name,size,byte

echo folsersize >> %logPath%
pushd F:\user\bat\
echo %title% >> %logPath%
for /D %%d in (*) do call :subrtn "%%d"

exit /b

:subrtn
for /F "tokens=3 delims= " %%a in ('dir /s %1 ^| find "個のファイル"') do set size=%%a
echo %1,"%size%",byte >> %logPath%
goto :EOF

出力されたテキストファイル

file name,size,byte
"test_a","",byte 
"test_b","",byte 

環境
Windows 10

Comments

[otn]

特に間違いは無いようです。
コマンドプロンプトで dir コマンドを実行して、
10 個のファイル 203,922 バイト
のような表示がありますか？言語が日本語になっていないとか？

Answer 1

■デスクトップの「新しいフォルダー」を調べて、sizelist.txtを作成するプログラムです

@echo off

rem ■遅延環境変数を有効にする
setlocal enabledelayedexpansion

rem ■sizelist.txtの作成先（デスクトップ）
set logPath="%userprofile%\Desktop\sizelist.txt"
if exist !logPath! (del !logPath! /q)
echo.file name,size,byte >> !logPath!

rem ■調査先のフォルダ（デスクトップの「新しいフォルダー」）
set target="%userprofile%\Desktop\新しいフォルダー"
for /f "tokens=*" %%I IN ('dir !target! /a:D /o /b /s') do (
for /f "tokens=3" %%a in ('dir /a /-c /s %%~fI  ^| find "個のファイル"') do (set size=%%a)
echo."%%~nI","!size!",byte >> !logPath!
)
pause
exit

■実行結果

file name,size,byte
"test_a","90",byte
"test_b","10",byte

■注意事項■

①遅延環境変数を有効にしています。setlocal enabledelayedexpansion命令

②カレントディレクトリを変更していません。pushd命令

③サブルーチンは使用しておりません。

④txt作成先、調査先はご自身の環境に合わせてください。

⑤分からない命令はお手数ですがご自身で調べてみてください。

Comments

[user202102]

遅延環境変数を有効にしていないのが原因のようでした。サンプルファイルも確認できました。
ベストアンサーにさせていただきます！