batファイルで、先頭や末尾以外に文字を追加したい

Question

大量のファイル名に文字を追加したいと考えております。

文字列の先頭や末尾では無く、拡張子を除いて末尾から三番目以前に文字（_hoge）を追加したいのです。
以下は末尾に入れるコードなのですが、

@echo off

rem 実行バッチファイル名を取得
set add=%~n0

for %%i in (*) do (
    rem 実行バッチファイル自身以外に実行
    if not %%i==%~n0%~x0 (
        rem ファイル名の末尾に追記
        ren %%i %%~ni_%add%%%~xi
    )
)

pause

例：
abc_01.jpg
abcdef_01.jpg
hogehoge_01.jpg

を、下記のように
abc_hoge_01.jpg
abcdef_hoge_01.jpg
hogehoge_hoge_01.jpg

とするにはどのように書き替えたら良いでしょうか？
お力を貸して下さい。

宜しくお願い致します。

Answer 1

@echo off
set add=%~n0
for %%i in (*) do (
    if not %%i==%~nx0 (
        call :rename %%i
    )
)
pause
goto :EOF

:rename
set A=%~n1
ren %1 %A:~0,-3%_%add%%A:~-3%%~x1
goto :EOF

Comments

[arimura]

感謝してます。早々と本当にありがとうございました。

[Turkis_Mond]

:rename
の最後はgoto :EOF
ではなく
exit /b
だと思います。

[otn]

exit /b がなくても、ファイル末尾に到達すると終わります。

[Turkis_Mond]

同じくで
goto :EOFがなくとも終わりますが、
callされた処理での終端は exit /b 付与がスタンダードと思います。

[otn]

> goto :EOFがなくとも終わりますが、
はい。自分で使うときは書きません。
相手が、後ろにコードを継ぎ足したときに、あれ？と思わないように、こういう場では書いています。

> callされた処理での終端は exit /b 付与がスタンダードと思います。
好みでは？私は、リターンコードを返すときだけexit /bを使っています。
常にexit /bを使えば、goto :EOFという機能は不要なので、そういう方針も賛成です。

[Turkis_Mond]

好みと言われればそれまでかも知れません。
メインルーチンのラストのみgoto :EOF
サブルーチンラストはexit /b とする規約で可読性と分割時の移植性や拡張性を担保しておりました。
書き捨てコードならどうでもいい話かと思います

[otn]

exit /bで統一というのなら分かりますが、その使い分けは分からない。気分の問題でしょうか。

Answer 2

@echo off
rem for文ループ内で変数へ代入しその後値参照するため遅延変数展開を用いる
setlocal enabledelayedexpansion
for %%i in (*) do (
	rem 実行バッチファイル自身は除外
	if not "%%i"=="%~nx0" (
		rem %%iのファイル名部文字列を変数fnに代入
		set fn=%%~ni
		rem 新ファイル名はfnの0文字目より右から4文字目までの切り出しと_hogeとfnの右端3文字の切り出し
		ren "%%i" !fn:~0,-3!_hoge!fn:~-3,3!%%~xi
	)
)
pause

Comments

[arimura]

感謝してます。早々と本当にありがとうございました。

Answer 3

%%iを一旦別の変数に格納し、更に遅延環境変数にする必要があります。
遅延環境変数は先頭でsetlocalをするのと、ループ内では!で囲みます。

@echo off
setlocal enabledelayedexpansion

rem 実行バッチファイル名を取得
set add=%~n0

for %%i in (*) do (
    rem 実行バッチファイル自身以外に実行
    if not %%i==%~n0%~x0 (
        rem ファイル名の末尾に追記
        set str=%%i
        echo %%i !str:~0,-7!_hoge!str:~-7!
    )
)

pause

Comments

[arimura]

感謝してます。早々と本当にありがとうございました。

Answer 4

「_01.jpg」の文字数が固定（７文字）の場合に限る。

@echo off
setlocal enabledelayedexpansion

for %%f in ("*.jpg") do (
   set STR=%%f
   echo !STR:~0,-7!_hoge!STR:~-7!
)

参考：BATファイルで文字列の切り出し

Comments

[arimura]

感謝してます。早々と本当にありがとうございました。