Untiy ASE ライトが当たっていない時に表示されるシェーダを作成したい。

Question

こんにちは
シェーダの勉強をしているものです。
Amplify Shader Editorを私用してライトの影響がないときにテクスチャが表示されるシェーダを作成したいと考えております。

Amplify Shader EditorのサンプルにあるUVLightRevealのライトに照らされるとテクスチャが浮かび上がってくる表現を応用してできないか試行錯誤していますが、うまくいきません。画像のどこを調整すればいいのでしょうか。

周りには詳しい人はおらず、ネットでもなかなか出できません。
どなたか回答をいただけると大変助かります。
よろしくお願いいたします。

Answer 1

すみませんがAmplify Shader Editorを持っていないため、通常のシェーダーでの案となってしまいますがご容赦ください...

実験の題材として、「地球儀をスポットライトで照らし、照らされていない部分にのみ夜の明かりを描く」というのをやってみました。
Amplify Shader Editorで作れるかどうかは不確かですが、このようなプロセスでやれないでしょうか?

• ライトで照らされている領域を求めるため、まず強制的にアルベドを白、メタリック・スムースネスを0にしてレンダリングし、結果をグラブする。

わざわざこうしたのは、テクスチャが貼ってあったり余計なものが映り込んでいたりすると、本当にライトが当たっていないため暗いのか、アルベドや映り込みのために暗いのか区別できないためです。

• 通常通り、アルベドなど表面の特性を適用してレンダリングする。
• 先にグラブした結果を用いて照らされた領域をマスキングし、影部分にのみ加算用テクスチャを合成する。

Shader "Custom/Phosphorescence" {
    Properties {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        _Metallic ("Metallic", Range(0,1)) = 0.0
        _PhosphoTex ("Phosphorescence", 2D) = "black" {} // 暗い部分に加算するテクスチャ
        _IlluminanceExp ("Illuminance Exponent", Range(0,16)) = 8.0 // 白黒反転後の冪指数
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200

        // まず、アルベドを強制的に1にして全ライトの照明効果をレンダリング
        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows
        #pragma target 3.0

        struct Input {
            float2 uv_MainTex;
        };
        
        void surf (Input IN, inout SurfaceOutputStandard o) {
            o.Albedo = 1.0;
            o.Metallic = 0.0;
            o.Smoothness = 0.0;
            o.Alpha = 1.0;
        }
        ENDCG

        // ここまでのレンダリング結果をグラブ
        GrabPass {}

        // 通常のレンダリング（処理内容はデフォルトのサーフェイスシェーダーと同様）
        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows
        #pragma target 3.0

        sampler2D _MainTex;

        struct Input {
            float2 uv_MainTex;
        };

        half _Glossiness;
        half _Metallic;
        fixed4 _Color;
        float _ColorExp;

        void surf (Input IN, inout SurfaceOutputStandard o) {
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
            o.Albedo = c.rgb;
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;
            o.Alpha = c.a;
        }
        ENDCG

        // 最後に、グラブした結果の影部分だけに加算用テクスチャを加算する
        Pass
        {
            // ブレンドモードは加算合成にしておく
            Blend One One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 grabCoord : TEXCOORD1;
                float4 vertex : SV_POSITION;
            };

            sampler2D _PhosphoTex;
            float4 _PhosphoTex_ST;
            sampler2D _GrabTexture;
            float _IlluminanceExp;
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _PhosphoTex);
                o.grabCoord = ComputeGrabScreenPos(o.vertex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // 加算用テクスチャから色を取得
                float3 phosphorescence = tex2D(_PhosphoTex, i.uv).rgb;

                // グラブ結果から色を取得
                float3 grabbed = tex2Dproj(_GrabTexture, i.grabCoord).rgb;

                // グラブ結果のRGBのうち最大の量を、このピクセルがライトで照らされている強さとする
                float illuminance = max(max(grabbed.r, grabbed.g), grabbed.b);

                // ライト強度を白黒反転し、さらに適当に冪乗することで多少薄暗い領域には加算効果が発生しないようにした上で
                // 加算用テクスチャ色と乗算し、これをピクセルへの加算値とする
                fixed3 result = phosphorescence * pow(1.0 - illuminance, _IlluminanceExp);
                
                return fixed4(result, 0.0);
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}