VBAにて空白を含むRangeの並び替え

Question

前提・実現したいこと

エクセルのマクロでTreeViewにて表示したい内容があるのですが、
ノードの順番を入れ替えるのにつまづいています。

添付画像の左側がDBよりRecordsetで取得してきた情報をシートに反映したものなのですが、
この状態のまま、上の行より読み込んでいくと、
２行目のParentID=A900の親ノードがまだ存在していないため、エラーとなります。

なので、添付画像の右側のように並び替える必要があります。
並び替えの優先順位としては
①ParentIDがnullのものはルートノードとなるので一番先頭に移動したい
②NodeIDがParentIDに存在しているものは下に移動したい
③NodeIDがParentIDに存在しないものは一番下に移動したい

上記の中でも①だけでもできれば幸いです。
Range.Sort メソッドだとあくまで昇順、降順しか選択できないのでしょうか？
昇順、降順だとKeyに指定したセルに空白がある行は下に移動してしまうのですが、上に表示する方法があれば知りたいです。

If Cells（i , 3).Value="" Then
先頭に移動
Else
のようなことが書ければよいのですが・・・

どうかご教示お願いいたします。

補足情報（FW/ツールのバージョンなど）

Office2013

追加

①であれば

If Cells（i , 3).Value=""  Then
Cells（i , 3).Value="0"

にすれば昇順でいけました。

Answer 1

階層の浅い順に並べたいということですよね。

まずは使用していない列（例えばD列）に階層を出力してみてはどうでしょうか。
手順としては、
①ルートノード(C列が空)を階層１としてセット
②階層１の各ID（A列の値）が親ノード(C列の値)に指定されているものを階層２としてセット
③階層２の各ID（A列の値）が親ノード(C列の値)に指定されているものを階層３としてセット
④同様の処理で１件もセットされなくなるまで階層を掘り下げていく。

これで親子関係にあるものは階層の深度を取ることができると思います。

以下、D列に階層を書き込むサンプルです。

Sub Make_Sortkey()
    Dim iCnt As Integer     '処理件数
    Dim iLevel As Integer   '階層

    iLevel = 0
    Do
        iCnt = Make_NodeLevel(iLevel)  '階層の書き込み処理

        If iCnt = 0 Then Exit Do  '処理されなくなったらループ終了
        
        iLevel = iLevel + 1   '階層を１つ深くする
    Loop
End Sub

Function Make_NodeLevel(viLevel As Integer) As Integer
    Dim iCnt As Integer     '検出カウンタ
    Dim sParent As String   '検索する親ノードID
    
    iCnt = 0
    
    Dim PRow As Integer '親ノード検索のループ行
    Dim CRow As Integer '子ノード検索のループ行
    
    For PRow = 2 To 11
        If viLevel = 0 Then
            'ルートノード検索
            If Cells(PRow, "C").Value = "" Then
                Cells(PRow, "D").Value = viLevel + 1
                iCnt = iCnt + 1
            End If
            
        ElseIf Cells(PRow, "D").Value = viLevel Then
            '親ノード検索
            sParent = Cells(PRow, "A").Value
            
            For CRow = 2 To 11
                '子ノード検索
                If Cells(CRow, "C").Value = sParent Then
                    Cells(CRow, "D").Value = viLevel + 1
                    iCnt = iCnt + 1
                End If
            Next
            
        End If
    Next
    
    Make_NodeLevel = iCnt

End Function

こうして作成したD列でソートしてみてはどうでしょうか？

Answer 2

例示のデータでは、親、子、孫 の3階層までですが、階層を限定しないとすると、並べ替えるといっても条件が難しそうです。

単純に先頭からループで登録を試みて、親ノードが見つからないエラーがなくなるまで、繰り返すという発想でコーディングしてみました。

Private Sub CommandButton1_Click()
    Dim TV As TreeView, ND As Node
    Set TV = Me.TreeView1
    With Worksheets(1)
        Dim LastRow As Long
        LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
               
        Dim i As Long
        'ルートノードの登録
            If .Cells(i, 3).Value = "" Then
                Set ND = TV.Nodes.Add(, , .Cells(i, 1).Value, .Cells(i, 2).Value)
                ND.Expanded = True
            End If
        Next
        
        Do
            Dim retry As Boolean
            retry = False
            On Error Resume Next
            '子ノードの登録をトライ
            For i = 2 To LastRow
            If .Cells(i, 3).Value <> "" Then
                Set ND = TV.Nodes.Add(.Cells(i, 3).Value, tvwChild, _
                                      .Cells(i, 1).Value, .Cells(i, 2).Value)
                If Err = 35601 Then    '"Element not found" Error
                    Err.Clear
                    retry = True
                ElseIf Err = 0 Then
                    ND.Expanded = True
                End If
            End If
            Next
            On Error GoTo 0
        Loop Until retry = False
    End With
End Sub

階層数分、For Next を繰り返すので無駄が多いですが、ロジックはシンプルになります。

Answer 3

上から順番に、

ParentIDがnullのもの
NodeIDがParentIDに存在しているもの、
NodeIDがParentIDに存在しないもの、

を登録していけばいいだけ、ですね。

＃その、だけ、がむずかしい

Comments

[khr0404]

y-waiwai様

回答ありがとうございます。

確かに だけ が難しいですね・・・
下記はツリービューのコードなのですが
```TreeView
For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row

If .Cells(i, 3).Value = 0 Then 'ParentID が 0 (ルートノードの場合の処理)
Rltiv = Null
Rltsp = tvwFirst
Else 'ParentID が 0 以外 (ルートノード以外の処理)
Rltiv = "A" & .Cells(i, 3)
Rltsp = tvwChild
End If '分岐処理終わり

TV.Nodes.Add Relative:=Rltiv, Relationship:=Rltsp, Key:="A" & .Cells(i, 1), text:=.Cells(i, 2)
TV.Nodes(i - 1).Expanded = True
Next i

```
If文をもっと工夫すればなんとかいけそうですかね・・・

[y_waiwai]

ParentIDがNullのデータが登録されてる、という場面から、
２番めの実現方法。

まず先頭の登録データのNodeIDを読み出し、それと合致するParentIDを持つものを抽出して登録、
それが済んだら、登録データの次のNodeIDを読み、それと合致するものを抽出、登録、
と、登録データが尽きるまで繰り返す、という考え方でしょうか。

これが済んだらあとは未登録のものばかりが残るので、それを登録、という運びとなります