エクセルVBAでチェックボックスのチェック状態を取得したい

Question

前提・実現したいこと

エクセルのVBAでチェックボックスにチェックが入っているかを確認するマクロを作りたいです。

発生している問題・エラーメッセージ

動くには動くのですが、チェックボックスの有無に関わらず「true」が返ります。

該当のソースコード

Sub test()

Dim rc As Boolean

rc = Sheets("Sheet1").CheckBoxes(1)
MsgBox rc

End Sub

試したこと

いろいろ書きなおしてみたのですが、出来ず・・・
こんな簡単そうなコードも書けず恐縮です。

補足情報（FW/ツールのバージョンなど）

Answer 1

フォームコントロールのチェックボックスですよね。

フォームコントロールのチェックボックスの Value はBoolean型でなく、
定数 xlOn, xlOff で判断します。

Sub test()
    Dim rc As Boolean

    rc = WorkSheets("Sheet1").CheckBoxes(1).Value = xlOn
    MsgBox rc

End Sub

補足
ちなみに、上記はコードは
WorkSheets("Sheet1").CheckBoxes(1).Value = xlOn の結果(True/False)を rcに代入しています。
下記のコードと同じ意味になります。

Sub test()
    Dim rc As Boolean
    
    If WorkSheets("Sheet1").CheckBoxes(1).Value = xlOn Then
        rc = True
    Else
        rc = False
    End If
    MsgBox rc

End Sub

追記
フォームコントロールのチェックボックスを名前で参照する場合は、
「オブジェクトの選択と表示」に表示される名前で、
Worksheets("Sheet1").CheckBoxes("check box 4")
としてもいいし、選択した時に「名前ボックス」に表示される名前でもOKです。
Worksheets("Sheet1").CheckBoxes("チェック 4")

ちなみに、チェックボックスの横のテキストは右クリックの「テキストの編集」で編集できますが、
その文字列は、
Worksheets("Sheet1").CheckBoxes("check box 4").Text
で取得できます。

Comments

[sanson914]

お返事ありがとうございます！
なるほど！
では上記のコードだと
rc=xlOn（xlonは「チェックなし」の意味か・・・？）
でメッセージボックスに「false」が返るのですね！

では、メッセージボックスにチェックの状態を出すにはどうすればいいでしょうか・・・？
ここまで教えて頂きながらピンとこずすみません

[hatena19]

xlOn はチェックありの意味です。
ですので、CheckBoxes(1) にチェックが入っていれば(ValueがxlOn)

CheckBoxes(1).Value = xlOn

は、xlOn = xlOn となってTrueになります。
CheckBoxes(1) にチェックが入っていなければ(ValueがxlOff)、
xlOff = xlOn は成立しないので、False になります。

ということで、提示のコードでメッセージボックスにチェックの状態を表示できると思いますが。

[sanson914]

お返事ありがとうございます！
上記をマクロ登録して、全てのチェックボックスで試した所、「オブジェクトの選択と表示」で「check box４」となっている場所のチェック状況でチェックが入っていると「true」、入っていないと「false」の反応が返ってきました。ありがとうござます！

CheckBoxes(1)が、『「オブジェクトの選択と表示」で「check box４」』の事を指しているのでしょうか・・・だとすれば、複数のチェックボックスを作っている場合、任意のチェックボックスを選択する為に、そのチェックボックスの本当の名前を知る方法はありますでしょうか・・・

[hatena19]

回答の方に追記しておきました。

Answer 2

ども＾＾

早とちりばかりして、
理解あるいは納得されているような返答をされていますが、
言葉の意味を全く理解しているように見えません。

すでに他の方が指摘されていますが、
フォームコントロールのチェックボックスは、
True/FalseというBoolean型の値を持っていません。
つまり、xlOn/xlOff というLong型のVBAで定義されている定数を保持しています。

この定数というのは、コード上では文字で表現できる名前がついていますが、
実際はただのLong型の整数となっています。
xlon →　1
xloff →　-4146

この数値をBoolean型の変数に代入したとき、
暗黙のうちに型変換がされるのですが、このとき、
0　→　False
それ以外　→　True
と型変換されます。
（逆にやると、False→0、True→-1となります。）
なので、単に返り値をBoolean型の変数に代入したら、
どっちでもTrueになってしまいます。
この辺は理屈だけでなく自分で実験されて納得いだだくといいと思います。

Sub test()
    Dim rc As Boolean

    MsgBox Sheets("Sheet1").CheckBoxes(1).Value
End Sub

なので、

Sub test()
    Dim rc As Long

    rc = Sheets("Sheet1").CheckBoxes(1).Value
    
    If rc = xlOn Then
        'なにか
    Else
        'なにか
    End If
End Sub

と、条件分岐をしてください。
（xlonを１と書いても同じ意味ですが、
xlonと書いたほうがon/offの評価をしているのだということが
読み易いですよね？そのために定数というものが事前に定義されています。）

それから、名前の件ですが、
CheckBoxes(1)
と、１番目のチェックボックスを指定しているのですから、
２番目は、CheckBoxes(2)と表現できます。
もちろん名前でも指定できます。
名前は各コントロールを選択して、名前ボックスで確認するか、
VBAでコードを書いて名前を調べるかですが、
単にシート上に配置して自動で名前が付けられた状態だと、
名前ボックス→日本語
VBA→英語
の表記になるので気を付けてください。
（ただし、使うときはどっちでもOK）
新たに付け直すと、直した値に統一されるようです。

Answer 3

Valueをお忘れですよ。

Comments

[sanson914]

ご回答ありがとうございます！
確かにそうですね。
ですが、今「Value」を後ろにくっ付けても、
チェックボックスにチェックが有ろうが無かろうが「true」が返ってくるのです。

・・・そもそも論として、エクセルのチェックボックスの名前は、「オブジェクトの選択と表示」で出てくる名前でいいですよね・・・？

[sysjojo]

失礼しました。hatena19さんご指摘のとおり値の受け方に問題がありましたね。
名前はご推察の通り、「オブジェクトの選択と表示」で出てくるものでよいです。
CheckBoxes(1)のNameをDebug.Printなどすれば確認できるかと思います。
試しに、チェックボックスのチェックがついてる項目だけメッセージボックスを出すようにサンプル書いてみましたが

Sub test()

Dim cb As Variant
For Each cb In ActiveSheet.CheckBoxes
If cb.Value = 1 Then
MsgBox ActiveSheet.Shapes(cb.Name).AlternativeText
End If
Next
End Sub

↑のcb.Nameが名前ですね。チェックボックスにつけたキャプション文字列はShapesからとれそうですがもっといい方法があるかもしれません。

[hatena19]

> チェックボックスにつけたキャプション文字列は
cb.Text でとれるようです。

[sysjojo]

> cb.Text でとれるようです。
ですよね。
寝起きでちゃんと確認してなかったけど、なんか上手く行かなかった気がしたのでウォッチ式でプロパティ眺めて、それっぽい値が入っている項目使ってしまいました。