perlが馴染めず、awkでなんとかしていたのですが、汎用的なプログラムを作る必要があり、質問させていただきました。

data.csv

No |var1|var2|var3|
|:--|:--:|--:|
|1|10|A|1000
|2|10|B|1000
|3|10|B|2000
|4|10|A|2000
|5|10|A|1000

cat data.csv | awk -F ',' `{print $3}' | sort | uniq -c によって、下記の結果が得られます。
3 A
2 B

これをawkではなく、perlで列数とファイルを指定して同じような結果を得るperlプログラムを作成したいです。
perl test.pl data.csv 3

行動規範の内容に同意します

回答4件

#!/usr/bin/perl
use strict;
use warnings;

my ($file, $colnum) = @ARGV;

my %stash;

open my $fh, '<', $file
    or die "Can't open $file: $!";

while (my $line = <$fh>) {
    my @cols = split /,/, $line;
    my $var = $cols[$colnum - 1];
    $stash{$var}++;
}

close $fh
    or die "Can't close $file: $!";

my @summary = sort { $b->[1] <=> $a->[1] }
              map { [$_, ($stash{$_} || 0)] }
              keys %stash
              ;

for my $row (@summary) {
    printf "%d %s\n", reverse @{$row};
}

1;

投稿2018/07/25 06:56

ernix

総合スコア20

汎用的な、というのがどの程度を言っているのか分りませんが、

perl
1#!/usr/bin/env perl -F, -lan
2use vars qw($c %h);
3BEGIN{ $c = ( pop @ARGV ) -  1}
4    $h{$F[$c]} ++
5}{
6    print "$h{$_} $_" for keys %h ;

これを保存して実行すれば、望みの形にはなります。

本格的なスクリプトを作りたいのであれば、

bash
1$ perl -MO=Deparse THIS.pl data.csv 3

で、内部解釈を文字列化して、そこからスクリプトを作成してください。

私のスクリプトが使いずらいと感じたら、先の御二方のワンライナーを同様の手段でスクリプト化して、
改造するのが良いでしょう。

投稿2018/07/01 05:11

bunzaemon

総合スコア118

Perlはあまり詳しくないですが、

Bash
1perl -nle '@a=split(/,/,$_);$b{$a[2]}++;END{foreach $i(keys %b){print "$b{$i} $i"}}' data.csv

投稿2018/06/27 14:13

otn

総合スコア84557

sheng

2018/06/27 15:04

ご回答ありがとうございます。説明が不足しておりました。申し訳ございません。 perl test.pl data.csv 3 のように、ワンライナーではなく、perlスクリプトにて処理したいと思っております。何卒よろしくお願い致します。

otn

2018/07/25 11:15

'～～’ の部分がスクリプトです。

行動規範の内容に同意します

まずawk互換モードから覚えるといいでしょう。

sh
1$ perl -F"," -ane 'print "$F[2]\n"' data.csv |sort |uniq -c

カウントを取りたいだけならuniqは必要ありませんね。

# awk
awk -F"," '{n[$3]++}END{for(i in n){print i,n[i]}}' data.csv
# perl
perl -F"," -ane '$n{$F[2]}++; END{foreach $k (keys %n){print "$k $n{$k}\n"}}' data.csv

項目がアルファベット順に並ばないのが気持ち悪いなら

perl -F"," -ane '$n{$F[2]}++; END{foreach $k (sort keys %n){print "$k $n{$k}\n"}}' data.csv

perlスクリプトファイルを作る簡便な方法

コメント欄にも書きましたが、こちらに補足しておきます。
まず、perlスクリプトファイルの呼び出し方。ワンライナーで対処しているうち、より複雑なことをやりたくなって結局スクリプトファイルの作成を始めるという事態はままあることです。その場合、ワンライナー部分を単純に新規ファイルにコピーし、コマンドラインのワンライナー部分をそのファイル名に置き換え、最後にコマンドラインの-eを消すだけです。awk では逆に-fをつけなければなりませんがperlは異なります。

次に、perlのパッケージの中に標準で含まれているコンバータがあります。
awkはわかるけどperlはちょっと、という回答者氏のような方は、awkスクリプトをperlスクリプトに変換するa2pというコンバータを使えば、簡単にperlスクリプトファイルを得ることができます。同様に、sedスクリプトをperlスクリプトに変換するs2p、findコマンドと同じことをするperlスクリプトを生成するfind2perlがあります。

私は個人的にはa2pやs2pはほとんど使いませんが、find2perlはちょくちょく使います。「ディレクトリを下までたどりながら、条件に合うファイルが見つかったらそこそこ複雑な何らかの処理を行う」という作業にはとても便利です。find2perlを覚えてしまうと、findやxargsを使ったシェル芸など、まだるっこしくて覚える気にはならないくらいです。

参照: http://perldoc.jp/docs/perl/5.10.1/perlutil.pod

投稿2018/06/27 13:47

編集2018/06/28 04:28