VBAのシェイプオブジェクトを結合セルに生成する

Question

前提・実現したいこと

エクセルを利用した報告書形式のxlsmファイルに評価・判定用の丸型のシェイプオブジェクト
を背景色の付いたセルに生成するマクロを作成する。

発生している問題

結合セルに背景色が付いている場合に、結合前の単体セル単位で〇がついてしまう。

該当のソースコード

Sub 丸object書き込み()
    Dim myShp As Shape
    Dim cell As Variant
    Dim c As Variant
    For Each c In ActiveSheet.Range(Cells(1, 24), Cells(45, 300))
        If c.MergeCells And c.Interior.Color = RGB(255, 0, 0) Then
        With ActiveSheet.Range(c.Address)
            Set myShp = ActiveSheet.Shapes.AddShape _
            (Type:=msoShapeFlowchartConnector, Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
        
            With myShp
                .Name = "丸印"
                .Line.ForeColor.SchemeColor = 0 '黒
                .Line.Weight = 1    '線の太さ
                .Fill.ForeColor.RGB = RGB(255, 0, 0)
                .Fill.Transparency = 1 '透過
            End With
        End With
        
        ElseIf c.Interior.Color = RGB(255, 0, 0) Then
        With c
            Set myShp = ActiveSheet.Shapes.AddShape _
            (Type:=msoShapeFlowchartConnector, Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
        
            With myShp
                .Name = "丸印"
                .Line.ForeColor.SchemeColor = 0 '黒
                .Line.Weight = 1    '線の太さ
                .Fill.ForeColor.RGB = RGB(255, 0, 0)
                .Fill.Transparency = 1 '透過
            End With
        End With
            Set myShp = Nothing
        End If
    Next
End Sub

結果

試したこと

7行目にoffsetプロパティで2列単位で〇オブジェクトを指定出来るようにした。
'''vba
With ActiveSheet.Range(c.Address, c.Offset(0, 1)) '7行目
'''

結果（offset後）

芳しくありません。
結合セル内のセルにオフセット指定セルがついてきてしまうだけで、狙い通りにはいかない。
書き込まれた2種類の〇のうち、ひとつでも結合セルに当てはまっていれば片方を消せばいいのですが
悪いことに結合セルであっても一つのセルと見なされているのか3列に渡って丸が付けられてしまいます。

検索を含め、かなりの時間、頭をひねって考えましたが解決策が見つかりません。
何卒宜しくお願い致します。

Answer 1

こんな感じに、個々のセルのアドレスと
そのセルを含む結合セルの範囲の中の左上のセルと
アドレスで比較して、不要なセルを操作対象から外します。

Sub 丸object書き込み2()
    Dim c As Range
    Dim shp As Shape

    For Each c In ActiveSheet.Range("AD25:AJ60")
        '見ているセルが結合セルの左上の時だけ
        '（それ以外は無効化されているので無視）
        If c.Address = c.MergeArea(1).Address Then
            '塗りつぶしの色が赤かの判定をする
            If c.Interior.Color = vbRed Then
                '真面目に引数を与えると右に長くなるから0で仮に書いて後で変える
                '1でもいいけど＾＾；あと丸はOvalでいいと思う。
                Set shp = ActiveSheet.Shapes.AddShape(msoShapeOval, 0, 0, 0, 0)
                With shp
                    .Top = c.Top
                    '結合セル範囲の真ん中に
                    .Left = c.Left + c.MergeArea.Width / 2 - c.Height / 2
                    'セルの高さに幅を合わせて真ん丸に。長丸がいい？
                    .Width = c.Height
                    .Height = c.Height
                    .Line.ForeColor.SchemeColor = vbBlack   '線の色＝黒
                    .Line.Weight = 1                        '線の太さ＝1
                    .Fill.Visible = msoFalse                '塗りつぶし＝なし
                End With
            End If
        End If
    Next
End Sub

Comments

[hokosugi]

早速のご返答ありがとうございます。
おーー、結合セル内のセルアドレスを指定できるプロパティ（MergeArea)があるんですね。
VBA始めて間がないので知りませんでした。これだけでも有難いのに、コピペするだけで
完成してしまうコードまで書いていただき感謝いたします。あとでシッカリ読みます。
取り急ぎお礼まで。