異なるViewControllerからTabBarControllerへの値渡し[Swift4,Xcode8]

Question

前画面で入力したプロフィール情報を画面を移動した先(TabBarControllerの内の一つのView(Profile.swift))に表示したいです。
Profile_Setting.swiftのguard let profile = tab.~
*の部分を何を書けばいいのでしょうか？

Comments

[ladybird]

「①と②のやり方がわかりません」とありますが、①と、②の途中まではできているような・・・？リストボックスを2列にする方法が分からないか、フォルダパスの取り方が分からないか、あたりでしょうか。②をもう少し分解して、分からない点を整理してみてください。（ちなみに、挙げたどちらかであれば検索で十分解決できるかと。）

[ladybird]

あ、失礼、「フォーム上に」がポイントなんですね。それは自前でゴリゴリ作るくらいしかないんじゃないかなぁ・・・。なぜ普通のダイアログじゃダメなのかを記載していただければ、別なアプローチの回答は出てくるかもしれません。

Answer 1

VBA - VBA ツリービューからファイル印刷(132027)｜teratail

上記の質問で希望に沿う回答がなかったので質問しなおしたのですね。
上記ではツリービュー以外の方法がいくつか提案されていたが、それでは満足できなかったということですね。

CheckBox付きTreeViewのTips紹介
にあるようなCheckBox付きTreeViewを使えばどうでしょう。このリンク先はC#ですが、VBAでも可能です。

かなりのスキルが必要になりますが、下記等を参考にチャレンジしてみてください。
Office TANAKA - Excel VBA Tips[TreeViewコントロールの使い方]

リストボックスの2列表示については、下記をご参考に。
Office TANAKA - Excel VBA Tips[複数列のリストボックス]

ツリービューで作成してみた

将来使うことがあるかもしれないので、ツリービューの勉強がてら作成してみました。

ユーザーフォーム上にツリービュー(TreeView1)を配置します。
配置の仕方は上記の Office TANAKA のリンク先を参考にしてください。
他に下記のコントロールを配置します。
イメージリストと連携させてアイコンも表示できるようだが、私の環境ではエラーが出てアイコンが登録できなかったのでアイコンはなしです。

コマンドボタン
cmdBookPrint　選択したブックの印刷
cmdSelectFolder　親フォルダの選択

テキストボックス
txtRootFolder　親フォルダのパス格納用

ユーザーフォームのモジュール

Option Explicit

Private Sub cmdBookPrint_Click()
    Dim n As Node
    For Each n In TreeView1.Nodes
        If n.Checked And n.Children = 0 Then
            Debug.Print n.FullPath
        End If
    Next
End Sub

Private Sub cmdSelectFolder_Click()
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = txtRootFolder.Value
        .AllowMultiSelect = False
        .Title = "親フォルダの選択"
        If .Show Then txtRootFolder.Value = .SelectedItems(1)
    End With
    TreeView1.Nodes.Clear
    InitFileTreeView
End Sub

Private Sub UserForm_Initialize()
    txtRootFolder.Value = "C:\PFolder"
    With TreeView1
        .CheckBoxes = True
        .Indentation = 14           ''インデントの幅
        .LabelEdit = tvwManual      ''ラベル編集の許可
        .BorderStyle = ccNone       ''線の種類
        .HideSelection = False      ''非アクティブ時の選択解除
        .LineStyle = tvwRootLines   ''ルート(最上位)線の表示
    End With

    InitFileTreeView
End Sub

Sub InitFileTreeView()
    Dim objFSO As FileSystemObject
    Dim strDir As String
    Dim i As Long

    strDir = txtRootFolder.Value
    'FileSystemObjectのインスタンスの生成
    Set objFSO = New FileSystemObject
    'フォルダの存在確認
    If Not objFSO.FolderExists(strDir) Then
        MsgBox ("指定のフォルダは存在しません")
        Exit Sub
    End If
    '親フォルダーの登録、展開
    TreeView1.Nodes.Add(Key:="n0", Text:=strDir).Expanded = True
    i = 1    'キーインデックス
    '再帰処理モジュールのコール
    Call GetDirFiles(objFSO.GetFolder(strDir), i, "n0")
    'オブジェクトの解放
    Set objFSO = Nothing
End Sub

Sub GetDirFiles(ByVal objFolder As Folder, ByRef i As Long, ByVal PKey As String)
    Dim objFolderSub As Folder, objFile As File
    Dim n As Node
    'サブフォルダの取得
    For Each objFolderSub In objFolder.SubFolders
        i = i + 1
        Set n = TreeView1.Nodes.Add(Relative:=PKey, Relationship:=tvwChild, _
                            Key:="n" & i, Text:=objFolderSub.Name)
        Call GetDirFiles(objFolderSub, i, "n" & i)
        If n.Children = 0 Then
            TreeView1.Nodes.Remove n.Index
        Else
            n.Expanded = True
        End If
    Next
    'ファイルの取得
    For Each objFile In objFolder.Files
        With objFile
            If  .Type = "Microsoft Excel ワークシート" Then
                i = i + 1
                TreeView1.Nodes.Add Relative:=PKey, Relationship:=tvwChild, _
                                    Key:="n" & i, Text:=.Name
            End If
        End With
    Next
    'オブジェクトの解放
    Set objFolderSub = Nothing
    Set objFile = Nothing
End Sub

Comments

[退会済みユーザー]

hatena19さん〉

回答ありがとうございます

以前質問した複数のフォルダの複数のファイルを表示させる質問で
https://teratail.com/questions/131957

①のフォルダが固定じゃないときの場合の回答で→
任意のフォルダから複数のファイルを選択するなら、リストボックスを2列表示にして、1列目にファイル名、2列目にフォルダーのパスを格納する。GetOpenFilenameメソッド選択したファイルをリストボックスに追加していくようにする。

という回答を頂いたのですがGetOpenFilenameメソッドでは１つのフォルダが対象で複数のフォルダに対しては対象にできませんが、フォーム上ではなくファイルを開くダイアログでリストボックスに複数のフォルダの複数のファイルを表示させることは可能ですか？

よろしくお願い致します

[退会済みユーザー]

hatena19さん〉
すみません質問を変えます。

以前質問した
https://teratail.com/questions/131198
質問した時のコードでリストボックスないファイルの印刷はできますでしょうか？

[退会済みユーザー]

以前質問したコードに下記のコードを付けてリストボックス内のファイルを印刷しようとしたのですが
フォルダが違うファイルがあるとエラーになってしまいました。
https://teratail.com/questions/131198

Private Sub btn_Cilck()
dim wb As Variant
dim Fn As Variant,i As Long

with Me.BookInput
For i = 0 To .ListCount -1
Set wb = Workbooks.Open(.List(i,0))
wb.PrintOut
wb.Close
Next
End With
Application.ScreenUpdating = True
End Sub

[hatena19]

今までの回答やほかの方の回答で十分ヒントは出ていると思います。

この質問のコード(以前私が回答したもの)の btn_FileOpen_Click で、
.Clear（リストボックスのクリア）を削除して、
For Each の部分を、ttyp03 さんの回答のものに置き換えて、
Me.lblPath.Caption = .List(0, 1)を削除すれば、
ファイルダイアログで選択したファイル名とパスがリストボックスに追加されていきます。

印刷ボタンでワークブックを開く部分のコードは、

Set wb = Workbooks.Open(.List(i,1) & .List(i,0))

というようにパスとファイル名を & で結合すればいいでしょう。

あとは「リストのクリア」ボタンを追加して、リストボックスをクリア出来るようにすればいいでしょう。

[退会済みユーザー]

hatena19さん〉
回答ありがとうございます
ファイルのリスト表示、印刷、リスト削除
できることができました。

また質問があるのですが…

'カレントディレクトリを指定
ChDrive "C"
ChDir "C:\test"

上記のカレントディレクトリを指定仕方で
サーバー(ネットワーク)のフォルダをカレントディレクトリとして指定することはできますか？

パス→¥¥◯◯¥■■¥△△¥～

よろしくお願い致します

[hatena19]

「chdir ネットワークパス」をキーワードでネット検索すればすぐに見つかりますよ。
ここで質問して回答をまっているより解決が早いと思います。

[退会済みユーザー]

hatena19さん〉

下記を参考にしてカレントディレクトリをネットワークにしようとしたのですが、カレントディレクトリがローカルのままになってしまいました。

https://excwlvba.blogspot.com/2013/07/blog-post_24.html?m=1

Private Declare Function SetCurrentDirectory Lib "kernel32" Alias "SetCurrentDirectoryA" (ByVal lpPathName As String) As Long Sub S2_ChDir() '変更後パスFilePathの宣言 Dim FilePath As String '変更するファイルパスの指定 FilePath = "¥¥◯◯¥■■¥△△～" '変更の実行 Call SetCurrentDirectory(FilePath) End Sub

[hatena19]

当方の環境では問題なくネットワークのフォルダーがカレントになりましたよ。
Private Sub btn_FileOpen_Click()
    Dim OpenFileName As Variant, Target As Variant
    'カレントディレクトリを指定
    Call SetCurrentDirectory("\Server\myFolder")
    OpenFileName = Application.GetOpenFilename(FileFilter:="Microsoft Excelブック,*.xls?", _
                                               MultiSelect:=True)

Answer 2

①ユーザーフォーム上にファイルを開くダイアログ、もしくはエクスプローラのような画面を表示

もしくはって言っててダイアログのは実現できているのでいいですよね。
もしフォーム上でエクスプローラー風の画面を作りたいなら、TreeViewコントロールなんかで実現できると思います。
TreeView自体は汎用的なものなので、自力でファイルを取得してツリーを構築する必要があります。
そこまでする必要があって自力でできなさそうなら改めて質問をあげてください。

②

パス名の取得は既にラベルに設定しているのでわからないわけではないですよね。
よってリストボックスの使い方がわからない、ということでよろしいでしょうか。
With内のみ抜粋ですが、こんな感じにすればよいかと思います。

        With Me.BookInput
            .Clear
            'リストボックスにファイル名を表示
            For Each Target In OpenFileName
                Filename = Dir(Target)
                Pathname = Replace(Target, Filename, "")
                .AddItem ""
                .List(BookInput.ListCount - 1, 0) = Filename
                .List(BookInput.ListCount - 1, 1) = Pathname
            Next Target
            'ファイルのあるフォルダーのパスをラベルに表示
            Me.lblPath.Caption = .List(0, 1)
        End With

ただこれって意味あります？
ファイル選択ダイアログで取得できるファイルは、同じフォルダが対象なので、全部の行に同じパスが設定されますし、ラベルにもパスが設定されます。
何がしたいのか要件を見直してみてください。

追記
リストボックスのColumnCountプロパティは2にしておいてください。

Answer 3

「vba ファイル選択ダイアログ」でぐぐってみればどうでしょう

Comments

[退会済みユーザー]

y_waiwaiさん
回答ありがとうございます
ファイル選択ダイアログでファイルの選択はできますが、フォーム上にファイル選択ダイアログを表示する方法は質問する前に探してもなかったので質問致しました。

[y_waiwai]

フォーム上にダイアログを表示するとはどういうことでしょう
ふつうはフォームを表示した上にダイアログを表示しますが、そうではないということ？