ACCESS VBA ボタンのIF分岐処理について

Question

フォームに３つのトグルボタン(A,B,C)を設置し、それぞれの出力処理を１つのボタンでコントロールしています。

出力ボタンにVBAで、押されたトグルボタン(A,B,C)でそれぞれの出力処理を書いています。
Aだけ押された場合〜ABC全て押された場合などの網羅した処理を書くにはIF文でしか方法は無いのでしょうか？？
また、
出力したものがわかるようにメッセージを吐くようにしていますが、一つ一つ出すのではなく、まとめて出したいと思っております。その時の処理コードをおしえていただきたいです。
よろしくお願いいたします。

追記
Ifの処理記載します

IF A.value = true and A.value = false and A.value = false

DoCmd.openquery “クエリ名”
module1.mkmkd(保存先フォルダ作成処理)
DoCmd.TransferText(csv出力処理)

msgbox “出力メッセージ”

上記の処理をAだけ、Bだけ、Cだけ、ABだけ、選択されていない等網羅して書いております。

Comments

[sazi]

＞Aだけ押された場合〜ABC全て押された場合などの網羅した処理を書くにはIF文でしか方法は無いのでしょうか？？

[sazi]

上記について、なぜそう思うのか？目的のために不都合な点などがあれば説明を追記して下さい。

[Iris_777]

試しにIF文で書いてみたところ、非常に長い構文になってしまうこと。この点に関しては処理の実現の上妥協するべきだとは思いました。フォームで実際にトグルを選択して、出力しましたが最初の１つのボタンだけ選択した時の処理が反応しないため、他の手段があるのではと思いここに至りました。

[sazi]

withを使えば省略可能なのと、動作に不備があるなら尚更問題のコードを質問に追記したほうが良いですね。

[Iris_777]

withについて少し調べてみます！

[sazi]

コードはマークダウンで括った方が好いですね。それから実際のコード書かないと意味ないですよ。全然長くないし、どこを省略したのかも分かりません。

Answer 1

やりたいとこが不明瞭なので、最大限想像して下記のような仕様と仮定して回答します。
ちがう場合は、ロジックを参考にご自身で作成してください。
トグルボタン名は、繰り返し処理しやすいように規則的なものに変更してます。

コマンドボタン「cmdCSVOutput」をクリックしたら、
トグルボタン「tgl1」 が押されているとき、「クエリA」 を出力、ファイル名は「クエリA.csv」
トグルボタン「tgl2」 が押されているとき、「クエリB」 を出力、ファイル名は「クエリB.csv」
トグルボタン「tgl3」 が押されているとき、「クエリC」 を出力、ファイル名は「クエリC.csv」
最後に出力されたクエリ名の一覧をメッセージボックスで表示する。

トグルボタンの標題(Caption)は出力したいクエリ名とします。

Private Sub cmdCSVOutput_Click()
    Dim i As Long, sMsg As String  

    For i = 1 To 3
        With Me("tgl" & i) 
            If .Value Then
                Module1.mkmkd (保存先フォルダ作成処理)
                DoCmd.TransferText acExportDelim, , .Caption, _
                                   "C:\test\" & .Caption & ".csv"
                sMsg = sMsg & .Caption & vbCrLf
            End If
        End With
    Next
    
    If sMsg = "" Then
        MsgBox "出力するクエリが選択されていません。"
    Else
        MsgBox sMsg & " をCSVで出力しました。"
    End If
End Sub

Forループの使い方、Withステートメントの使いのご参考に。

Comments

[Iris_777]

お返事遅くなり申し訳ございません。自身でコード組んでいたのですが、改修が必要となりましたので、こちらのご回答を参考に作成してみます！ありがとうございます！

Answer 2

＞等網羅して書いております。
あぁ、6パターンでしたね。＾＾；

Private Sub CommandButton1_Click()
    Dim i As Long
    Dim j As Long
    Dim o As MSForms.ToggleButton
    Dim p As String

    '各ボタンの値チェック
    For i = 1 To 3
        Set o = Me.Controls("ToggleButton" & i)
        If o Then
                j = j + 2 ^ i
        End If
    Next
    
    '条件分岐
    Select Case j
        Case 0: p = 全部False
        Case 2: p = "1番だけ"
        Case 4: p = "2番だけ"
        Case 8: p = "3番だけ"
        Case 6: p = "1番・2番"
        Case 10: p = "1番・3番"
        Case 12: p = "2番・3番"
        Case 14: p = "全部"
    End Select
    
    MsgBox p
End Sub

こういうことかなぁ・・・

Answer 3

Private Sub CommandButton1_Click()
    Dim i As Long
    Dim o As MSForms.ToggleButton
    Dim p As String
    
    For i = 1 To 3
        Set o = Me.Controls("ToggleButton" & i)
        If o Then
            '---ONの時の処理----------
            'ログの記録
            s = s & "・" & o.Caption
        End If
    Next
    
    'ログの出力
    MsgBox Mid(s, 2) & "　を出力しました。"
End Sub

こういうことですかね？
トルグボタンがFalseの時も何かするとか、

AのボタンとCのボタンがTrueの時に特別な処理をするんですか？
つまり、3個のON/OFFだから有り得る状態が
9パターンになると思うんですが、それらに特別な処理を紐づけるのですか？
それとも、
AがONのとき→何かする
BがONのとき→何かする
CがONの時→何かする
と続いて3パターンチェックで
最後だけ結果を合わせて表示出来ればいいのかな？

よくわかんなかったです＾＾；

Comments

[hatena19]

私もやりたいことは、こっちかなと思いました。
ちなみに、Accessタグが付いているので、Accessのフォームだと思いますので、
Dim o As Access.ToggleButton
かな。