質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

90.49%

  • VBA

    1850questions

    VBAはオブジェクト指向プログラミング言語のひとつで、マクロを作成によりExcelなどのOffice業務を自動化することができます。

VBAの配列についての質問

解決済

回答 2

投稿

  • 評価
  • クリップ 0
  • VIEW 224

cd987456

score 24

エクセル2007を使用しています。
VBAを使って以下の事がやりたいです。

「シート1」に以下の表があります。
イメージ説明

A列に商品、B列にロットNoとあります。
CD列、EF列、GH列にそぞぞれ日付、出荷台数とあります。

VBAを実行すると、「シート2」に以下のような表を作成したいです。

イメージ説明

A列に商品、B列にロットNoとあります。
「シート1」のCD列、EF列、GH列に記載されている日付、出荷台数を
商品、ロットに合わせて、シート2のC列日付、D列出荷台数に転記したいです。

商品数が1000を超えるくらいあり高速処理したいです。

途中までコードを考えてみました。

Public Sub リスト化()

    Dim myDic As Object
    Dim i As Long, j As Long
    Dim ary1()
    Dim ary2()
    Dim maxrow As Long

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    Set myDic = CreateObject("Scripting.Dictionary")

    With Sheets("シート1")
        maxrow = .Cells(.Rows.Count, 1).End(xlUp).Row
        ary1 = .Range(.Cells(2, 1), .Cells(maxrow, 2)).Value
        For i = LBound(ary1) To UBound(ary1)
            myDic.Item(ary1(i, 1) & "," & ary1(i, 2)) = .Range(.Cells(i + 1, 3), .Cells(i + 1, 8)).Value
        Next i
    End With
    With Sheets("シート2")
        maxrow = .Cells(.Rows.Count, 1).End(xlUp).Row

        Erase ary1    '配列の初期化
        ary1 = .Range(.Cells(2, 1), .Cells(maxrow, 2)).Value

'ここにどのようなコードを書けばいいのか分かりません。
'        For i = LBound(ary1) To UBound(ary1)
'
'
'        Next

    End With

    Set myDic = Nothing

    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub


データを配列から書き出す時のコードが分かりません。
教えて下さい。

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 2

checkベストアンサー

0

重複排除や突き合わせをするわけではないので、Dictonary を使う意味はないですね。

現状のロジックだと、行毎にセル範囲にアクセスして格納してますので、
出力も行毎に縦変換してセルに代入することになりますので、
それほど高速化はしません。

単純にシート1の表全体を配列に格納して、
出力用の配列にレイアウト変換しつつ代入して、
それをシート2に出力する、
というロジックでいいと思います。
これなら、一括読み込み、一括出力になりますので、
重い処理になるシートのレンジへのアクセスが2回ですみます。

サンプルコード

Public Sub リスト化()

    Dim i As Long, j As Long, c As Long
    Dim ary1()
    Dim ary2()
    Dim maxrow As Long

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    With Sheets("シート1")
        maxrow = .Cells(.Rows.Count, 1).End(xlUp).Row
        ary1 = .Range(.Cells(2, 1), .Cells(maxrow, 8)).Value
        maxrow = WorksheetFunction.CountA(.Range(.Cells(2, 3), .Cells(maxrow, 8))) \ 2 '出力行数
    End With

    ReDim ary2(1 To maxrow, 1 To 4)    '出力用配列のサイズ確保

    For i = LBound(ary1) To UBound(ary1)
        For j = 3 To 8 Step 2
            If ary1(i, j) <> "" Then
                c = c + 1
                ary2(c, 1) = ary1(i, 1)
                ary2(c, 2) = ary1(i, 2)
                ary2(c, 3) = ary1(i, j)
                ary2(c, 4) = ary1(i, j + 1)
            Else
                Exit For
            End If
        Next
    Next

    With Sheets("シート2")
        .Cells(.Rows.Count, 1).End(xlUp).Offset(1).Resize(UBound(ary2), 4).Value = ary2
    End With

    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub

出力用配列にレイアウト変換して代入する部分のロジックが初心者には難しいかな?
コードを読んでもらえれば、それほど難しいことはしてないことがわかると思います。

あとは、CountA で空白以外のセル件数を取得して、2で割って出力行数を取得するというのを思いつくかですね。

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2018/06/05 14:15

    回答ありがとうございます。
    丁寧な説明もありがとうございます。
    CountAの部分、日付、出荷台数を丸ごと取得して・・教えてもらって初めて気付きました。
    配列は高速処理できて便利ですが、理解するのに時間が掛かりますね。
    ありがとうございました。

    キャンセル

0

自分であれば、C列以降を2列毎にシート2へコピペする方針で考えます。
最初にA,B列をコピペし、C列以降を縦方向にコピペしていき、
最後に、A,B列を埋める。

配列を使いたいのはやまやまですが、
初心者には難しい処理です。
1.シート1の1行分のデータを配列に格納
2.C列以降のセット数をカウント
3.加工配列を用意(Redim)
4.1の配列からを加工配列にデータを埋めておく
5.シート2に貼り付ける
6.シート1の次の行へ続く

Dictionaryは自分でもよく使いますが、今回のケースではあまりメリットがありません。
同じロットの行が他にもあるからまとめたい、という気持ちがあるのかもですが、
シート2のA,B列でソートをかければいいかと。

投稿

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 90.49%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

関連した質問

同じタグがついた質問を見る

  • VBA

    1850questions

    VBAはオブジェクト指向プログラミング言語のひとつで、マクロを作成によりExcelなどのOffice業務を自動化することができます。