vbaにおける可視セルの選択（複数行の場合）

Question

質問させていただきます。
Excelでデータベースを作成中です。（来店記録のようなものです）
現在、A列に名前、B列に住所が入っており、C列には日付、D列には○か☓が必ず入る予定の構造になっております。
現在は入力作業中で、C列が去年以前、かつD列が空白という条件でオートフィルタをかけています。

別途、ユーザーフォームを用意しており、コマンドボタンを押すと、AB2列分（アンバサンドで繋げて、名前と住所を一括表示）×アクティブセルのある行以降の可視行5つ分のデータがテキストBOX1〜5に入るようにしたいのですが、範囲指定がうまく行きません。
loop文の中に
entirerow.hidden=False〜の条件を入れて、そこから下方向にoffsetしようと思いましたが、飛び飛びのため、なかなかぴったり五行選択することができず困っています。（3行だったり7行だったりバラバラです）
最終目的は、テキストBOXの横にあるドロップダウンリストから○×を選ぶと、対応する行のD列にその値が入るようにすることです。
列の非表示はありませんので、可視行の選択→テキストBOXに代入、さえできれば、最後の部分はなんとかなりそうな気がします。（横にずらすだけで終わりそうな気がします）

何か良い方法はありますでしょうか？

vbaに詳しい方、どうぞお力をお貸しいただけたら幸いです。

【これまでにやってみたこと】
getfromclipboardと、gettextプロパティを使って、選択可視行のデータをクリップボードに抜き出し→改行コードでSPLIT→for next文で順番に代入する流れ
テキストBOXのオブジェクト名は後ろに1〜5がつくだけで一定ですが、抜き出したデータを配列に入れたとき、変数カウントのスタートが0からになるので、一つずれて出力されてしまった上に、改行を表すマークまで一緒に表示されてしまっています。

Answer 1

別途、ユーザーフォームを用意しており、コマンドボタンを押すと、AB2列分（アンバサンドで繋げて、名前と住所を一括表示）×アクティブセルのある行以降の可視行5つ分のデータがテキストBOX1〜5に入るようにしたいのですが、範囲指定がうまく行きません。

SpecialCells(xlCellTypeVisible) で可視セルのみ取得できます。

Private Sub CommandButton1_Click()
    Dim r As Range, c As Range, n As Long, EndR As Range

    Set EndR = Cells(Rows.Count, 1).End(xlUp)
    
    If EndR.Row < ActiveCell.Row Then
        MsgBox "データのあるセルを選択してください。"
        Exit Sub
    ElseIf EndR.Row = ActiveCell.Row Then
        Set r = Cells(ActiveCell.Row, 1)
    Else
        Set r = Range(Cells(ActiveCell.Row, 1), EndR).SpecialCells(xlCellTypeVisible)
    End If
    
    For Each c In r
        n = n + 1
        Me("TextBox" & n) = c.Value & c.Offset(, 1).Value
        If n = 5 Then Exit For
    Next
    
    For n = n + 1 To 5
        Me("TextBox" & n) = ""
    Next
End Sub

追記

最終目的は、テキストBOXの横にあるドロップダウンリストから○×を選ぶと、対応する行のD列にその値が入るようにすることです。

この仕様にも対応するようにしてみました。

Option Explicit

Private Sub CB_Change()
    With Me.ActiveControl
        If .Tag <> "" Then Cells(.Tag, 4).Value = .Value
    End With
End Sub

Private Sub ComboBox1_Change()
    CB_Change
End Sub

Private Sub ComboBox2_Change()
    CB_Change
End Sub

Private Sub ComboBox3_Change()
    CB_Change
End Sub

Private Sub ComboBox4_Change()
    CB_Change
End Sub

Private Sub ComboBox5_Change()
    CB_Change
End Sub

Private Sub CommandButton1_Click()
    Dim r As Range, c As Range, n As Long, EndR As Range

    Set EndR = Cells(Rows.Count, 1).End(xlUp)
    
    If EndR.Row < ActiveCell.Row Then
        MsgBox "データのあるセルを選択してください。"
        Exit Sub
    ElseIf EndR.Row = ActiveCell.Row Then
        Set r = Cells(ActiveCell.Row, 1)
    Else
        Set r = Range(Cells(ActiveCell.Row, 1), EndR).SpecialCells(xlCellTypeVisible)
    End If
    
    For Each c In r
        n = n + 1
        Me("TextBox" & n).Value = c.Value & c.Offset(, 1).Value
        Me("ComboBox" & n).Tag = c.Row 'コンボボックスのTagに行インデックスを格納
        If n = 5 Then Exit For
    Next
    
    For n = n + 1 To 5
        Me("TextBox" & n).Value = ""
        Me("ComboBox" & n).Tag = ""
    Next
End Sub

Private Sub UserForm_Initialize()
    Dim i As Long
    
    For i = 1 To 5
        With Me("ComboBox" & i)
            .AddItem ("○")
            .AddItem ("×")
        End With
    Next
End Sub

Comments

[LUCIA]

回答ありがとうございます！無事に思ったとおりの動作をするユーザーフォームができあがりました。大変お世話になりました。