質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

90.48%

  • VBA

    1865questions

    VBAはオブジェクト指向プログラミング言語のひとつで、マクロを作成によりExcelなどのOffice業務を自動化することができます。

  • Excel

    1598questions

    Excelは、マイクロソフト社が開発しているデータ集計や分析を行う表計算ソフトの一つです。文書作成や表計算、資料作成などの多彩な機能を備えており、統合パッケージであるMicrosoft Officeに含まれています。

vbaにおける可視セルの選択(複数行の場合)

解決済

回答 1

投稿 編集

  • 評価
  • クリップ 0
  • VIEW 912

LUCIA

score 8

質問させていただきます。
Excelでデータベースを作成中です。(来店記録のようなものです)
現在、A列に名前、B列に住所が入っており、C列には日付、D列には○か☓が必ず入る予定の構造になっております。
現在は入力作業中で、C列が去年以前、かつD列が空白という条件でオートフィルタをかけています。

別途、ユーザーフォームを用意しており、コマンドボタンを押すと、AB2列分(アンバサンドで繋げて、名前と住所を一括表示)×アクティブセルのある行以降の可視行5つ分のデータがテキストBOX1〜5に入るようにしたいのですが、範囲指定がうまく行きません。
loop文の中に
entirerow.hidden=False〜の条件を入れて、そこから下方向にoffsetしようと思いましたが、飛び飛びのため、なかなかぴったり五行選択することができず困っています。(3行だったり7行だったりバラバラです)
最終目的は、テキストBOXの横にあるドロップダウンリストから○×を選ぶと、対応する行のD列にその値が入るようにすることです。
列の非表示はありませんので、可視行の選択→テキストBOXに代入、さえできれば、最後の部分はなんとかなりそうな気がします。(横にずらすだけで終わりそうな気がします)

何か良い方法はありますでしょうか?

vbaに詳しい方、どうぞお力をお貸しいただけたら幸いです。

【これまでにやってみたこと】
getfromclipboardと、gettextプロパティを使って、選択可視行のデータをクリップボードに抜き出し→改行コードでSPLIT→for next文で順番に代入する流れ
テキストBOXのオブジェクト名は後ろに1〜5がつくだけで一定ですが、抜き出したデータを配列に入れたとき、変数カウントのスタートが0からになるので、一つずれて出力されてしまった上に、改行を表すマークまで一緒に表示されてしまっています。

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

checkベストアンサー

+1

別途、ユーザーフォームを用意しており、コマンドボタンを押すと、AB2列分(アンバサンドで繋げて、名前と住所を一括表示)×アクティブセルのある行以降の可視行5つ分のデータがテキストBOX1〜5に入るようにしたいのですが、範囲指定がうまく行きません。

SpecialCells(xlCellTypeVisible) で可視セルのみ取得できます。

Private Sub CommandButton1_Click()
    Dim r As Range, c As Range, n As Long, EndR As Range

    Set EndR = Cells(Rows.Count, 1).End(xlUp)

    If EndR.Row < ActiveCell.Row Then
        MsgBox "データのあるセルを選択してください。"
        Exit Sub
    ElseIf EndR.Row = ActiveCell.Row Then
        Set r = Cells(ActiveCell.Row, 1)
    Else
        Set r = Range(Cells(ActiveCell.Row, 1), EndR).SpecialCells(xlCellTypeVisible)
    End If

    For Each c In r
        n = n + 1
        Me("TextBox" & n) = c.Value & c.Offset(, 1).Value
        If n = 5 Then Exit For
    Next

    For n = n + 1 To 5
        Me("TextBox" & n) = ""
    Next
End Sub

追記

最終目的は、テキストBOXの横にあるドロップダウンリストから○×を選ぶと、対応する行のD列にその値が入るようにすることです。

この仕様にも対応するようにしてみました。

Option Explicit

Private Sub CB_Change()
    With Me.ActiveControl
        If .Tag <> "" Then Cells(.Tag, 4).Value = .Value
    End With
End Sub

Private Sub ComboBox1_Change()
    CB_Change
End Sub

Private Sub ComboBox2_Change()
    CB_Change
End Sub

Private Sub ComboBox3_Change()
    CB_Change
End Sub

Private Sub ComboBox4_Change()
    CB_Change
End Sub

Private Sub ComboBox5_Change()
    CB_Change
End Sub

Private Sub CommandButton1_Click()
    Dim r As Range, c As Range, n As Long, EndR As Range

    Set EndR = Cells(Rows.Count, 1).End(xlUp)

    If EndR.Row < ActiveCell.Row Then
        MsgBox "データのあるセルを選択してください。"
        Exit Sub
    ElseIf EndR.Row = ActiveCell.Row Then
        Set r = Cells(ActiveCell.Row, 1)
    Else
        Set r = Range(Cells(ActiveCell.Row, 1), EndR).SpecialCells(xlCellTypeVisible)
    End If

    For Each c In r
        n = n + 1
        Me("TextBox" & n).Value = c.Value & c.Offset(, 1).Value
        Me("ComboBox" & n).Tag = c.Row 'コンボボックスのTagに行インデックスを格納
        If n = 5 Then Exit For
    Next

    For n = n + 1 To 5
        Me("TextBox" & n).Value = ""
        Me("ComboBox" & n).Tag = ""
    Next
End Sub

Private Sub UserForm_Initialize()
    Dim i As Long

    For i = 1 To 5
        With Me("ComboBox" & i)
            .AddItem ("○")
            .AddItem ("×")
        End With
    Next
End Sub

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2018/05/02 17:24

    回答ありがとうございます!無事に思ったとおりの動作をするユーザーフォームができあがりました。大変お世話になりました。

    キャンセル

関連した質問

同じタグがついた質問を見る

  • VBA

    1865questions

    VBAはオブジェクト指向プログラミング言語のひとつで、マクロを作成によりExcelなどのOffice業務を自動化することができます。

  • Excel

    1598questions

    Excelは、マイクロソフト社が開発しているデータ集計や分析を行う表計算ソフトの一つです。文書作成や表計算、資料作成などの多彩な機能を備えており、統合パッケージであるMicrosoft Officeに含まれています。