WordのテーブルをExcelに転記するときに出てくる黒丸の正体について

Question

WordのテーブルをExcelに転記するツールを作成しています。
Excelに転記をした際に、おそらくテーブルの一枠毎に『・』より少し大きいぐらいの黒丸が現れました。
この黒丸が何なのかを教えていただきたいです。

Comments

[m.ts10806]

画面キャプチャか何か添付していただけますか？これだけでは状況と現象が分かりません。プログラミングに関係のない質問のようにも思いますが、その辺りはいかがでしょうか。

Answer 1

WordのテーブルをExcelに転記するツールを作成しています。

その転記するコードを提示してください。
回答者が検証するにしても、一からコードを書くのは負担です。

いちおう一般的なコードを記述して検証してみました。
確かに、各セルの最後に黒丸が付加されました。
そこで、最後の２文字分の文字コードを調べるコードを追加しました。

Public Sub ImportWordTable()
    Dim myWord As Object    'Word.Application
    Dim myWordDoc As Object    'Word.Document
    Dim docFilePath As String
    Dim r As Long, c As Long
    Dim s As String

    Set myWord = CreateObject("Word.Application")
    docFilePath = "C:\TEMP\テーブル.docx"
    Set myWordDoc = myWord.Documents.Open(docFilePath)

    With myWordDoc.Tables(1)
        For r = 1 To .Rows.Count
            For c = 1 To .Columns.Count
                s = .Cell(r, c).Range.Text
                Debug.Print Asc(Mid(s, Len(s) - 1, 1)); Asc(Mid(s, Len(s), 1))
                If s Like "*" & Chr(13) & Chr(7) Then s = Left(s, Len(s)-2) '制御コード(黒丸)削除
                Cells(r, c).Value = s
            Next
        Next
    End With

    myWordDoc.Close
    Set myWordDoc = Nothing
    myWord.Quit
    Set myWord = Nothing
End Sub

結果、文字コード 13 と 7 が付加されていました。
下記によると、
13 は Carriage Return　行頭復帰
7 は Bell 警告音を鳴らす
だそうです。

ASCII文字コード - IT用語辞典

行頭復帰 はなんとなくわかりますが、警告音を鳴らすコードが埋め込まれているのか、Wordの開発者に聞かないとわからないですね。

追記
Chr(13) & Chr(7) の制御コードを削除するコードを追加しました。

Comments

[ExcelVBAer]

ワードでは、セル内の末尾に必ず Chr(13)+Chr(7) があります。

文献で見たわけではないですが、
恐らくセルの区切りとしての制御文字だと推測されます。

なのでセル内の値を取得した際には、
末尾に制御文字があったら除去する処理が必要となります。

[hatena19]

Word独自の制御コードなんでしょうね。

Answer 2

不明な文字のデバッグは、その文字が本当は何であるかを確認するところから始まります。

見た目が[・][?] であっても、文字コードが[・][?]と同じとは限りません。

VBAで、ASC関数を使って文字コードが分かれば、
その文字コードでぐぐって調べると、
何の文字がExcelに出力されてるのかが分かります。

恐らく、Wordで使われている何らかの制御文字が、
Excelでは対応してないのだと推測されます。