自身が存在している同じフォルダのフォルダを開きたい

Question

こんにちわ

Excelでマクロ(VBA)をかいています

実行するとまずファイルを選択するダイヤログを開くのですが、そのファイルを自身が存在しているフォルダと同じフォルダがデフォルトで表示されるようにしたいです
同じフォルダが開けばよくて、ファイルまでは指定しません

Sub Run()
    Dim OpenFileName As String
    Dim wb As Workbook

    'ファイルを開くダイアログ
    'OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls")
    Workbooks.Open Filename:=ThisWorkbook.Path & "Microsoft Excelブック,*.xls"
    
    'If OpenFileName = "False" Then
    'Exit Sub
    'End If
    
    Set wb = Workbooks.Open(OpenFileName)
    
    Dim nameFile As String
    Dim Filenum As Long
    Dim msg As String
    
    nameFile = Format(Now(), "yyyymmdd") & ".csv"
    nameFile = ActiveWorkbook.Path & "\" & nameFile
    
    '同じファイル名があるとき警告
    If Dir(nameFile) <> "" Then
     msg = "同じ名前のファイルが存在します。上書きしますか?"
    If MsgBox(msg, vbYesNo) = vbNo Then wb.Close
    Exit Sub

    End If
    
    Filenum = FreeFile()
    Open nameFile For Output As #Filenum
                
    
--省略---

End Sub

もともと、今コメントアウトしているOpenFileNameをつかっていたときはエラーがなく稼働してました
調べてWorkBook~を記述したのですがエラーが出てうまく動きません

何が原因でしょうか？
何かが足りないのでしょうか？

アドバイスお願いいたします

Answer 1

方法はいくつかあると思いますが、2つほど紹介しておきます。

まず元々使われていたGetOpenFilenameを使う方法です（なぜやめてしまったのでしょうか）
これは他の回答にもあるように事前にカレントフォルダを移動しておけば解決です。

' ワークブックがあるフォルダをカレントフォルダにする
ChDir ThisWorkbook.Path

'ファイルを開くダイアログ
OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls")

但し、カレントフォルダを移動することになるので、それを嫌うのであれば次の方法で。

Applicationオブジェクトに含まれるFileDialogを使う方法です。
こちらの方が細かくダイアログの制御ができそうですが、手間は増えてしまいます。

'ファイルを開くダイアログ
With Application.FileDialog(msoFileDialogOpen)
    .AllowMultiSelect = False
    .Filters.Clear
    .Filters.Add "Microsoft Excelブック", "*.xls; *.xlsx", 1
    .InitialFileName = ThisWorkbook.Path & "\"
    .Show
    OpenFileName = .SelectedItems(1)
End With

※どちらの場合でもキャンセルの制御は必要です。

Comments

[pro-poke5]

回答ありがとうございます

また別で質問するべきだとは思いますがファイルを開いたときそのエクセルを非表示にさせたいです

' ワークブックがあるフォルダをカレントフォルダにする
ChDir ThisWorkbook.Path

'ファイルを開くダイアログ
OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls")
ActiveWindow.Visible = False　←これ

付け足したのですが非表示なりません
場所がわるいのでしょうか…

[ttyp03]

「そのエクセル」って何でしょう？
自分自身？

[pro-poke5]

自分自身ではなく、フォルダから選択して開いたExcelです
画面上に表示されてしまうのですが非表示にさせたいです

[ttyp03]

ファイル選択ダイアログはファイルを選択しファイル名を得るだけですので、Excelファイルはオープンされていません。
Openで開いた後にVisible=Falseをやればよいと思います。
なので順番としては、以下でよいはず。

ChDir ThisWorkbook.Path
OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls")
Set wb = Workbooks.Open(OpenFileName)
ActiveWindow.Visible = False

[ttyp03]

以下のような書き方の方がアクティブウィンドウに影響されずに済みのでよいかもしれません。
Application.Windows(wb.Name).Visible = False

[pro-poke5]

回答ありがとうございます

ファイルを開く前に非表示にしようとしてたのでできなかったみたいです
アクティブウィンドウに影響されない方法で解決いたしました！

Answer 2

カレントディレクトリを移動するんじゃなかったかな

ChDir ThisWorkBook.Path & "¥"
'ファイルを開くダイアログ
OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls")

元に戻したい場合はCurDirで予めとっておいて元に戻せばいいと思う

Comments

[pro-poke5]

回答ありがとうございます
シンプルに解決いたしました