VBAにおける日付入力のループ処理

Question

前提・実現したいこと

こんにちは。

VBAで週次で更新するデータファイルを作成しようとしています。
週次で更新するとはいえ、固定の曜日に毎週出来るわけではないので
前回の最終記入日を特定してその日付に+1を行い、その+1日付を起点にして
実際にマクロを起動する日である作業日から-1をした日付を終点として日付を更新、
その後に別ファイルから日付と特定コード（C列の数字です）をキーにしてデータを持ってきて転記。
という手順でマクロを作成しようとしたところ日付の記入でつまづいてしまいました。
解決策を教えていただけるとうれしいです。
よろしくお願いします。

参考資料：実行先ファイル（本来AとBの3行目以降には色々項目が入ってます）

発生している問題・エラーメッセージ

Do untilを用いて終点日付まで来たらループを抜ける、という処理をしたかったのですが
終点を認識できずに列上限まで入力をし続ける状態です。

該当のソースコード

Option Explicit

Sub testfiled()

Dim alma As Range
Dim bore As Range
Dim cent As Variant
Dim dome As Variant
Dim i As Long

i = 1

Set alma = Range("AMO2").End(xlToRight)
alma.Offset(0, 1).Value = DateAdd("d", 1, alma)

Set bore = alma.Offset(0, 1)
cent = DateAdd("d", -1, Date)
dome = CStr(bore)


Do Until dome = cent
bore.Offset(0, i).Value = DateAdd("d", i, bore)
i = i + 1
Loop

End Sub

試したこと

最初はDo Until RANGE("2:2") = cent　としていたのですが、
データ型不一致エラーでこのコードに一時的に変更しています。
多分このループもデータ型の問題なような気がするのですがイマイチわかりません。

Answer 1

変数名の意味がよくわからない(単にイニシアルabcd？)ですが、見たところcentが今回の最終日付（システム日付の前日）、domeが今回作成する起点の日付（前回終端日の翌日）だと思います。

ttyp03さんからも指摘がある通り、Doループの中でdomeに加算する日数iは変動していますが、ループを抜ける条件であるdomeとcentはいずれもループ内で変動してません。
このため永久に条件を満たすことがなく無限ループしているものと思います。

対策

このままDoループを使用するのであれば、ループ内でdomeを取得しなおす必要があると思います。
しかしご覧のとおりDoループは一歩間違えると無限ループとなってしまうため、取扱には注意が必要です。

今回の場合、ループ回数は今回作成する日数です。
これはDateDiff関数を使えばdomeとcentから求めることができるものです。
このように事前にループ回数がわかっている場合には、For～Nextのような有限ループでの実装のほうが安全です。

もうひとつ、これもttyp03さんから指摘が出ていますが、centを日付型で取得しているのに対しdomeは文字列型で取得しています。
変数の宣言はVariant型で曖昧に宣言されていますが、目的がはっきりしているものは明確に型を指定しておいたほうが、エラーなどの場合にも原因がわかりやすくなります。
今回の場合、日付型でそろえて日付として扱ったほうが取り回しがしやすいのではないでしょうか。

以上を踏まえて、提示コードを整理してみました。※机上ロジックなのでそのまま動かなかっらたすみません。

Option Explicit

Sub testfiled()
    Dim alma As Range	'前回最終セル
    Dim bore As Range	'今回開始セル
    Dim cent As Date	'終了日付
    Dim dome As Date	'開始日付
    Dim i As Long		'ループ処理用
    
    Set alma = Range("AMO2").End(xlToRight) '前回最終セル
    Set bore = alma.Offset(0, 1)            '今回開始セル
    
    cent = DateAdd("d", -1, Date)           '終了日付
    dome = DateAdd("d", 1, alma.Value)      '開始日付
    
    bore.Value = dome
    
    For i = 1 To DateDiff("d", dome, cent) 
        bore.Offset(0, i).Value = DateAdd("d", i, bore)
    Next
End Sub

参考になれば幸いです。

Comments

[sazi]

>今回の場合、ループ回数は今回作成する日数です。
日数は固定ではなくて、セルに記入されている日付欄を終端の日付が来るまで、と思ったけど、違うのかな？

[sobameshi]

>>jawaさん
回答ありがとうございます。
頂いたコードを実装してみたところ無事に動き、求めていた結果が出てきました。
これでデータ転記の動き出しが決まったので後作業も進みます。
データ型については疑問を自分でも持っていたのですがハッキリしなかった部分がこれでハッキリしました。やはりループ処理の実装はもう少し理解を深めないと難しいですね。
変数についてはご指摘の通り適当にabcdで頭に浮かんだ物でつけているだけです。テスト環境だしこれで良かろうの思考でした。

>>saziさん
日数は固定ではありませんが、既に記入されている最後の日付+1（つまりこれから更新する必要のある日付）を始点にして、作業日ｰ1（集計データなので当日分はないため）を終点にします。なのでjawaさん指摘の通り事前にループ回数を特定できる状況でした。

[sazi]

了解しました。
セルの日付が連続ではないケースがあるのかと思っていました。

Answer 2

ループ内で、domeもcentも更新されていないようですが。
またループ直前で値を格納してますが、centはDate型、domeは文字列型になっているので、正しく判定できるか怪しいところです。

Comments

[sobameshi]

回答ありがとうございます。
ループ処理の知識がまだ薄いのが原因で、ループ内で変数を更新する必要があることを認識できていなかったのが致命的でした。
データ型も試しに変えて別の方のコードを走らせてみたところ事故を起こしたので、正しく判定できないようでした。