指定範囲内のセルから数字を含まないセルを削除したい

Question

VBAを使ってエクセルの指定範囲内のセルから数字を含まないセルを削除したいと考えています。

具体的にはシート名”抽出”のJ列2行目から最終行までで、セル内に0～9の数字が入っていれば残す、入ってなければ削除と
したいです。最終行は1000行くらいです。

コードを考えてみましたが、上手くできません。
以下のコードでは"0"を含まないセルは全て削除されます。
どのようなコードが良いか教えて下さい。
できれば全角半角関係なく処理したいです。

Sub test()

Dim maxrow As Long '最終行
Dim cnt As Long, i As Long

Dim ws As Worksheet

    Set ws = Sheets("抽出")
    
    With ws
        maxrow = .Cells(Rows.Count, 10).End(xlUp).Row
        For cnt = 2 To maxrow
            i = 0
            Do While i < 10
                If WorksheetFunction.CountIf(.Cells(cnt, 10), "*" & i & "*") = 0 Then
                    .Cells(cnt, 10).Value = ""
                Else: End If
                i = i + 1
            Loop
        Next cnt
    
    End With

End Sub

Answer 1

正規表現を使うという程ではないので、Like 演算子の判定を使えば良いかと思います。
参考：
正規表現のようなマッチング
VBAで文字列から数字のみを抽出する

    With ws
        maxrow = .Cells(Rows.Count, 10).End(xlUp).Row
        For cnt = 2 To maxrow
            If .Cells(cnt, 10).Value Not Like "*[0-9]*" Then
                .Cells(cnt, 10).Value = ""
            End If
        Next cnt
    End With

Comments

[cd987456]

早速の回答ありがとうございます。
like演算子の使い方、新たに勉強になりました。ありがとうございました。

Answer 2

0～9を含むかのループ処理は良いのですが、条件にマッチしたら即値をクリアし、それを繰り返してしまうのが問題と思われます。
以下のように修正すると正しく動作します。

Sub test()

Dim maxrow As Long '最終行
Dim cnt As Long, i As Long

Dim ws As Worksheet

    Set ws = Sheets("抽出")

    With ws
        maxrow = .Cells(Rows.Count, 10).End(xlUp).Row
        For cnt = 2 To maxrow
            i = 0
            Do While i < 10
                If WorksheetFunction.CountIf(.Cells(cnt, 10), "*" & i & "*") > 0 Then  ' 条件変更
                    Exit Do    ' ループを抜けるように変更
                Else: End If
                i = i + 1
            Loop
            If i = 10 Then           ' この3行追加
                .Cells(cnt, 10).Value = ""
            End If
        Next cnt

    End With

End Sub

以下は少しシンプルに書き直したものです。
参考にしてみてください。
本来なら数値を含むか否かの処理は正規表現にしたいところですが、VBAで正規表現を使うとそれだけでステップ数が増えてしまうので、質問者様のコードを流用しました。
ちなみにどちらのコードでも全角に対応できてました。
VBAが優秀なのか余計なことまでしてくれているのか…。

Sub test()

    Dim r As Range
    Dim i As Long

    With Sheets("抽出")
        Set r = .Range(Cells(2, 10), Cells(Rows.Count, 10).End(xlUp))
        For Each c In r
            For i = 0 To 9
                If c.Value Like "*" & i & "*" Then Exit For
            Next
            If i > 9 Then
                .Cells(c.Row, c.Column).Value = ""
            End If
        Next
    End With

End Sub

Comments

[cd987456]

回答ありがとうございます。
ループに抜ける処理を加えれば良かったのですね。
勉強になりました。
ありがとうございます。