textファイルを文字列でエクセルに貼り付けたい

エクセルのマクロで下記のようなコードを書いて動かしているのですが、文字列でシート1に貼り付けされません。
読み込むtextファイルは、タブ形式で区切られており、その区切りごとに各列に読み込ませる形式にしたいです。
下記の形式だと、各列ごとに読み込みはされますが、文字列になりません。
textファイルの中身全てを文字列形式でコピーするにはどうしたら良いのでしょう
か？

Sub csvFile_get()

Dim openCsv As String

Worksheets("Sheet1").Activate
openCsv = Application.GetOpenFilename("textファイル,*.txt")
If openFile = "False" Then Exit Sub

With Workbooks.Open(openCsv)
.Sheets(1).Cells.Copy ThisWorkbook.Sheets("Sheet1").Range("A1")
.Close (SaveChanges = False)

End With

End Sub

hirano_7

2018/03/15 20:45

皆様、ご回答本当にありがとうございました。ベストアンサーを選ぶのが遅くなってしまって申し訳ありません。本当に助かりました！

回答5件

ベストアンサー

手元のExcel 2013で試してみましたが、外部データの取り込み機能でも実現できそうです。
以下、文字コードがSJIS、タブ区切り、各行が3カラム、全カラムをテキスト形式として読み込むサンプルです。

なお、外部データの取り込み機能を使うと、取り込み範囲に名前が付きます（「数式」タブの「名前の管理」に並びます）。また、CSVファイルと接続されて、CSVファイルの中身が変更された時に「更新」で自動反映できるようになります（「データ」タブの「接続」に並びます）。
便利な機能ですが邪魔になる場合は、名前と接続を削除してください。以下のサンプルでは削除するようにしています。

visual
1Sub csvFile_get()
2    
3    '外部データの取り込み機能で読み込み
4    With ActiveSheet.QueryTables.Add(Connection:="TEXT;textファイル.txt", Destination:=Range("A1"))
5    
6        ' 文字コードセットはSJIS
7        .TextFilePlatform = 932
8        
9        'タブ区切り
10        .TextFileTabDelimiter = True
11        
12        '各カラムの形式（この例では3カラム分をテキスト形式と指定）
13        .TextFileColumnDataTypes = Array(xlTextFormat, xlTextFormat, xlTextFormat)
14        
15        '取り込みの実行
16        .Refresh
17        
18        '取り込み範囲に付けられた名前の削除
19        ActiveWorkbook.Names(.Name).Delete
20        
21        'ファイルとの接続を解除
22        ActiveWorkbook.Connections("textファイル").Delete
23
24    End With 
25End Sub
26```

投稿2018/03/10 14:59

segavvy

総合スコア958

ワークブックとして読み込んでしまうと、その時点で数字は数値化されてしまい、例えば0123のような文字列は123に変換されてしまいます。
なので、通常のファイル読み込みで文字列として取り込み、面倒ですが1行ずつ貼り付けていくのが無難かと思います。
その際、念のためセルの表示形式を文字列に設定しておくとよいと思います。
上記のものに修正してみたコードを貼っておきます。
あまりチェックしていないので、あとはご自分で確認をお願いします。

VBA
1Sub csvFile_get()
2
3    Dim openCsv As String
4    Dim toSh As Worksheet
5    Dim buf As String
6    Dim cols As Variant
7    Dim row As Long
8    
9    openCsv = Application.GetOpenFilename("textファイル,*.txt")
10    If openFile = "False" Then Exit Sub
11    
12    Set toSh = Worksheets("Sheet1")
13    
14    row = 1
15    Open openCsv For Input As #1
16    Do Until EOF(1)
17        Line Input #1, buf
18        cols = Split(buf, vbTab)
19        With toSh.Range(Cells(row, 1), Cells(row, UBound(cols) + 1))
20            .NumberFormatLocal = "@"
21            .Value = cols
22        End With
23        row = row + 1
24    Loop
25    Close #1
26
27End Sub

投稿2018/02/14 00:54

ttyp03

総合スコア16992

テキストファイルの拡張子が".csv"ではなく、".txt"であれば、Workbooks.OpenTextを使うと001などを数値ではなく、"001"の文字列として取り込むことが可能となります。

OpenTextの引数の中にfieldInfoがあります。このfieldInfoは、配列形式の引数ですが、読み込む全てのﾌｨｰﾙﾄﾞの型を定義することができます。このフィールドの型として文字列型(xlTextFormat=2)を指定すれば、文字列として読み込むことが可能です。
詳しくは、以下のURLをご確認ください。
http://excel.style-mods.net/tips_vba/tips_vba_9_03.htm

なお、上記のURLでは、読み込むファイル名の拡張子が".csv"となっていますが、"001”を"1"ではなく、"001"にするには、拡張子が".txt"でないと動作しないようです。
私の場合は、拡張子が違っている場合には、一度、拡張子が".txt"のファイルにコピーしてからOpenTextを呼んでいます。

投稿2018/03/10 12:32

編集2018/03/10 12:35