ExcelVBAで複数のファイルのシートをひとつのファイルにまとめる方法を教えてください！

Question

###前提・実現したいこと
現在、毎月複数のExcelファイルでおくられてくる売上シートがありましてこれを、1つのファイルでシート別にまとめたいのですが、どのような文を作成すればよいのかお教えいただきたいです。
今は、手作業で移動またはコピーを選択して対象のファイルに追加しております。

Comments

[Tak1wa]

VBAにて実現したいのですか？それともVBA以外のアプリケーションの作成も可、ですか？

[rio]

VBAにて行いたいです

[wakuwaku]

「1つのファイルでシート別にまとめたい」とは
複数のファイルにあるデータをシート別に集計したいということですか。
単純にシートをコピーして一つにまとめたいということですか。

Answer 1

こんにちは。

シートの並び順だとか、いろいろと考慮するべきことはありますが
とりあえずシートをコピーするには、例えば以下のようなマクロで実現できます。

Sub Matomeru()
    'フォルダを指定
    Dim dirPath As String
    dirPath = Application.InputBox("フォルダ指定", "", "C:\")
    
    'ファイル毎にシートをコピー(フォルダの存在チェックとかしたほうが良い)
    Dim fileName As String
    fileName = Dir(dirPath & "\*.xlsx")
    Do While fileName <> ""
        Call CopySheet(dirPath & "\" & fileName)
        fileName = Dir()
    Loop
End Sub

Sub CopySheet(fileName As String)
    'シートをコピーする。このサンプルではシート名の重複などは考慮しない
    Dim mainBook As Workbook
    Set mainBook = ActiveWorkbook
    
    Dim currentBook As Workbook
    Set currentBook = Workbooks.Open(fileName)
    
    Call currentBook.Worksheets.Copy(After:=mainBook.Worksheets(1))
    Call currentBook.Close
End Sub

Answer 2

私も同様な質問をして、回答いただきました。質問者さまにも役立つかもしれませんので
参照してみてください。

https://teratail.com/questions/171219#

Answer 3

Excelにはマクロの記録という機能があります。
マクロの記録中に行った操作はVBAコードに変換されて記憶されますので、それでVBAコードは把握できます。