【エクセルマクロ】エキスポート済みのシートモジュールへインポートする為には

Question

実現したいこと

保存してある、以下のコードをシートモジュールへ入れたい。コピーしたいです
やり方は、ハンド作業であれば

インポート⇒クラスモジュールとしてインポートされる⇒同モジュールをコピー
⇒シートモジュールへ貼付⇒完成です

上記、一連の作業を、VBAにて記述したいです
ご存じのかた、アドバイスやコードを教えて下さい

前提

以下のソースコードをシートモジュールへ、ハンド作業ではなく
VBAを使ってコピーしたい

該当のソースコード

エクセル マクロ
エクセル VBA

【入れたいシートモジュール】
Sheet1(Sheet1)

【データ】
Sheet1.cls

【ソースコード】

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim ws As Worksheet
Set ws = Me

'既存の条件付き書式をクリア
ws.Cells.FormatConditions.Delete

' アクティブセルの行をハイライト

With ws.Rows(Target.Row).FormatConditions.Add(Type:=xlExpression, Formula1:="=ROW()=" & Target.Row)

.Interior.Color = RGB(255, 255, 153) ' ハイライト色（黄色）

End With

Answer 1

外部にSheet1.clsファイルが存在しているってことですよね？

Sub ImportCodeToSheetModule()
    Dim VBProj As Object
    Dim VBComp As Object
    Dim CodeModule As Object
    Dim FileNum As Integer
    Dim FilePath As String
    Dim Code As String
    Dim Line As String

    ' ファイルのパスを設定（適宜修正）
    FilePath = ThisWorkbook.Path & "\Sheet1.cls"

    Set VBProj = ThisWorkbook.VBProject

    Set VBComp = VBProj.VBComponents("Sheet1")
    Set CodeModule = VBComp.CodeModule

    ' 既存のコードをクリア
    CodeModule.DeleteLines 1, CodeModule.CountOfLines

    FileNum = FreeFile
    Open FilePath For Input As FileNum

    Do Until EOF(FileNum)
        Line Input #FileNum, Line
        Code = Code & Line & vbCrLf
    Loop
    Close FileNum

    CodeModule.AddFromString Code

    MsgBox "コードのインポートが完了しました", vbInformation
End Sub

Comments

[meg_]

参考になります。1点「FileNum = FreeFile」は何をしているのでしょうか？

[Black_Velvet]

テキストファイル等を開くときOpenを使用しますが、その時に任意の『ファイル番号』を振ります。(open MyFile for input as #1など) その時に固定番号(#1など)でもいいのですが、複数開いたとき番号が被るとエラーになるので、慣習的にfreefileを使用して『使用されていないファイル番号』を取得します。 今回は1個しか開かないのであまり関係ないです。

[hatena19]

ファイルを1行目から読み込んでいますが、
エクスポートしたファイルの先頭部分にコード以外の情報がありますので、その部分をとばして読み込む必要があると思います。

[meg_]

@Black_Velvet
解説ありがとうございます。FreeFileという関数があるんですね。勉強になりました。

Answer 2

インポート⇒クラスモジュールとしてインポートされる⇒同モジュールをコピー
⇒シートモジュールへ貼付⇒完成です

上記、一連の作業を、VBAにて記述したいです

この作業をVBA化すると下記になります。

Public Sub ImportSheetModule()
    Dim impFile As String: impFile = ThisWorkbook.Path & "\Sheet1.cls" 'インポートファイルパス
    Dim dstSheet As String: dstSheet = "Sheet1" 'インポート先シート名

    Dim WB As Workbook: Set WB = ThisWorkbook    
    Dim cmps As Object: Set cmps = WB.VBProject.VBComponents
    Dim srcCmp As Object: Set srcCmp = cmps.Import(impFile) ' モジュールファイルのインポート
    Dim srcMod As Object: Set srcMod = srcCmp.CodeModule    'インポートしたモジュールのコード
    Dim dstMod As Object: Set dstMod = cmps(WB.Sheets(dstSheet).CodeName).CodeModule
    dstMod.DeleteLines 1, dstMod.countOfLines                 ' シートモジュールのコードを全削除
    dstMod.AddFromString srcMod.Lines(1, srcMod.countOfLines) ' シートモジュールへ貼り付け
    
    WB.VBProject.VBComponents.Remove srcCmp 'インポートしたモジュールを開放
End Sub

インポートしたクラスモジュールを開放するコードを追加しておきましたので、不必要なら削除してください。