Access vba ADOでのフィルター条件の記載

Question

フィルター部分にてエラーが発生し
自身で調べた範囲では実現したい条件の抽出を
どのように記載すれば良いかが分かりませんでした。
お知恵を貸して頂きたいです。

rs1(元データは条件抽出したクエリ)の
IDフィールド-1のレコードを
rs2(元データは検索したいテーブル)から
フィルター抽出したいです。

rs2.Filter = "rs2!ID=rs1!ID-1"
このFilter構文で実行時エラー3001が
発生します。
記載内容が間違っているのか
そもそもフィルターの条件には
別のレコードセットの内容は
使えないのでしょうか。
1からVBAを書くのが初めてのレベルで
基礎的な質問かと思いますが分かりません。
抽出条件が別のクエリ、レコードセットにある場合、
どのようにフィルターの条件を表現するのか
教えて頂きたいです。

Private Sub コマンド0_Click()
Dim rs1 As New ADODB.Recordset
Dim rs2 As New ADODB.Recordset

With rs1
    .Open "fl1", CurrentProject.Connection 
    Do Until .EOF
            .MoveNext
        Loop
    .Close
End With

rs2.Open "dtrim", CurrentProject.Connection

rs2.Filter = "rs2!ID=rs1!ID-1"

Do Until rs2.EOF 
        Debug.Print rs2!d_buban
        rs2.MoveNext
Loop

rs2.Close

End Sub

Answer 1

IDフィールドは数値型だとして、構文的には下記になります。

'rs2.Filter = "rs2!ID=rs1!ID-1"
rs2.Filter = "ID=" & rs1!ID - 1

ただ、rs1 はその前で Close しているから、どちらにしてもエラーにはなります。

たぶん、やりたいことは下記ではなかろうか。

Private Sub コマンド0_Click()
    Dim rs1 As New ADODB.Recordset
    Dim rs2 As New ADODB.Recordset
    
    rs2.Open "dtrim", CurrentProject.Connection
    
    With rs1
        .Open "fl1", CurrentProject.Connection
        Do Until .EOF
            rs2.Filter = "ID=" & rs1!ID - 1
            Do Until rs2.EOF
                Debug.Print rs2!d_buban
                rs2.MoveNext
            Loop
            .MoveNext
        Loop
        .Close
    End With
    rs2.Close

End Sub

---

別案

下記で同様の結果になります。こちらの方がシンプルかつ高速です。

Private Sub コマンド1_Click()
    Dim rs As New ADODB.Recordset
    
    rs.Open "SELECT d_buban FROM dtrim INNER JOIN fl1 ON dtrim.ID=fl1.ID-1;", CurrentProject.Connection
    
    Do Until rs.EOF
        Debug.Print rs!d_buban
        rs.MoveNext
    Loop
    rs.Close

End Sub

Comments

[ukana]

回答ありがとうございます。
.closeを消し
rs2.Closeのあとに
rs1.Closeに修正し
条件変更してみました。

エラー3021の
BOFとEOFのいずれかがTrueになっているか
現在のレコードが削除されています。
要求された動作には現在のレコードが必要です。
とでました。
EOFがからむエラーということで変えてはみたのですが
おっしゃるとおりcloseの位置が正しくないのでしょうか？

[hatena19]

rs1でMoveNextして、EOFになっているので、その後で、 rs1!ID とIDを参照しても、当然エラーになりますね。
コードの意味を理解しましょう。

私の回答のコードを参考にして、意味を考えてみてください。

[ukana]

返信のタイミングを誤りました。
申し訳ないです。

先ほど動作させてみたところ
まさに得たい結果が出ました。
行き詰まっていたので本当に助かりました。

自身で理解できるよう、頂いたコードの意味を考えて
続きのプログラムを書いて行きたいと思います。
本当にありがとうございました。