正方形と直線の当たり判定について

Question

### 実現したいこと

図のようにrectを描画したい

前提

添付している図のように、直線が枠内を通る正方形のみ描画するプログラムを書きたいです。今書いてるのだと斜め方向に描画されることもありますが、横一文字みたいに描画されてしまうこともあります。

該当のソースコード

//正方形の接触判定
int wNum = (int)random(20,30);
int hNum = (int)random(40,60);
float m = wNum/hNum;
int boxSize = 10;

size(800,800);
translate(width/2,height/2);
rectMode(CENTER);


for(int rx=0; rx<wNum; rx++){
  for(int ry=0; ry<hNum; ry++){
    int x = rx*boxSize;
    int y = -ry*boxSize;
      float d = abs(m*x+y)/sqrt(m*m+1);//点と直線の距離公式
       if (d <= boxSize/2*sqrt(2)) {
       rect(x, y, boxSize, boxSize);
     }
  }
}

試したこと

接触判定というか、枠内を直線が通るかどうかを点と直線のきょりを用いて調べていますがこれがあっているかがそもそも不安です。何かいい方法あれば教えてください。

補足情報（FW/ツールのバージョンなど）

Processing4.3

Comments

[actorbug]

直線が枠内を通らないのに塗られているマスがありますが、間違いないでしょうか。
右上隅から数えて、左に3、下に3のマスと、左に5、下に6のマスです。

あと、ご提示の図からすると、やりたいことはこちらの質問に近いように思います。
https://teratail.com/questions/149396

Answer 1

float m = wNum/hNum;

int同士の割り算はintです。
どちらかをfloatにキャストしてから割ってください。

外形を描画すると何か角度が（縦横）逆な気がします。
mの割り算が逆なんじゃないですかね？（数学的なことは何にもわかっていませんがｗ

void setup() {
  size(800, 800);
  rectMode(CENTER);
  noLoop();
}

void draw() {
  background(255);
  translate(width / 2, height / 2);

  int wNum = (int) random(20, 30);
  int hNum = (int) random(40, 60);
  float m =  hNum / (float)wNum;
  int boxSize = 10;

  translate(-wNum * boxSize / 2, hNum * boxSize / 2);

  for (int rx = 0; rx < wNum; rx++) {
    for (int ry = 0; ry < hNum; ry++) {
      int x = rx * boxSize;
      int y = -ry * boxSize;
      fill(255);
      square(x, y, boxSize);

      float d = abs(m * x + y) / sqrt(m * m + 1);
      if (d <= boxSize / 2f * sqrt(2)) {
        fill(#88CCFF);
        square(x, y, boxSize);
      }
    }
  }
}

void mouseClicked() {
  redraw();
}

Answer 2

線が図形上を通っているかの判定として正しいかは見ていませんが、
float m = wNum/hNum;
の右辺は、wNumとhNumがintなので整数演算になっている、というのはきっと見落としなのだろうと思います。