Processingでfill()で値を指定したら円が塗りつぶされる。ellipse()を使わない方法

Question

前提

目的：
・Processingでベジェ曲線を使って円を表現したい。(4分円以外も表現可)
*ellipse()を使えば簡単に円を描画できるが4分円である。
・fill()の値を指定したら円が塗りつぶされる。

問題：
・「発生している問題」のプログラムだと円を完全に塗りつぶせない。
・「試したこと」のプログラムなら円を塗りつぶすことができるが、簡潔にしたい。
*塗られていない部分が正多角形なので正多角形描画プログラムを追加

発生している問題

void setup()
{
  size(960, 960);
  background(255);
}

void draw()
{ 
  strokeWeight(1);
  stroke(0,0,0);
  fill(255,0,0);

  translate(x, y);
  
  int r = 400;
  int p = 4;    // p -> Num of polygon
  
  float a    = TWO_PI / p;
  float c    = tan(a * 0.25) * 4/3;
  
  pushMatrix();
    beginShape();
      for(int v = 0; v < p; v++)  // v -> vertexIndex
      {
        float x0_0 = r * cos(a * v + HALF_PI);
        float y0_0 = r * sin(a * v + HALF_PI);
        float x1_0 = r * cos(a * (v+1) + HALF_PI);
        float y1_0 = r * sin(a * (v+1) + HALF_PI);
        float x0_1 = x0_0 - (r * c * cos(a * v));
        float y0_1 = y0_0 - (r * c * sin(a * v));
        float x1_1 = x1_0 + (r * c * cos(a * (v+1)));
        float y1_1 = y1_0 + (r * c * sin(a * (v+1)));
        
        bezier(x0_0, -y0_0, x0_1, -y0_1, x1_1, -y1_1, x1_0, -y1_0);
      }
    endShape(CLOSE);
  popMatrix();
}

・上記のプログラムの場合、円が完全に塗りつぶされない。

試したこと

void setup()
{
  size(960, 960);
  background(255);
}

void draw()
{ 
  strokeWeight(1);
  stroke(0,0,0);
  fill(255,0,0);

  translate(x, y);
  
  int r = 400;
  int p = 4;    // p -> Num of polygon
  
  float a    = TWO_PI / p;
  float c    = tan(a * 0.25) * 4/3;
  
  pushMatrix();
    beginShape();
      for(int v = 0; v < p; v++)  // v -> vertexIndex
      {
        float x0_0 = r * cos(a * v + HALF_PI);
        float y0_0 = r * sin(a * v + HALF_PI);
        float x1_0 = r * cos(a * (v+1) + HALF_PI);
        float y1_0 = r * sin(a * (v+1) + HALF_PI);
        float x0_1 = x0_0 - (r * c * cos(a * v));
        float y0_1 = y0_0 - (r * c * sin(a * v));
        float x1_1 = x1_0 + (r * c * cos(a * (v+1)));
        float y1_1 = y1_0 + (r * c * sin(a * (v+1)));
        
        bezier(x0_0, -y0_0, x0_1, -y0_1, x1_1, -y1_1, x1_0, -y1_0);
      }
    endShape(CLOSE);
  popMatrix();
  
  noStroke();
  pushMatrix();
    beginShape();
      for(int v = 0; v < p; v++)  // v -> vertexIndex
      {
        vertex(r * sin(TWO_PI*v / p), -r * cos(TWO_PI*v / p));  // TWO_PI = 2 * PI
      }
    endShape(CLOSE);
  popMatrix();
}

・塗りつぶされなかった部分は正多角形になっている。
・塗りつぶされなかった部分を正多角形で塗りつぶす。

補足情報（FW/ツールのバージョンなど）

使用したソフト：Processing4

Comments

[thkana]

https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11271515476
「マルチポスト」に際してはローカルルールがあるので対処してください。
https://teratail.com/help#posted-otherservice
「やむを得ず複数のサイトに質問を投稿された場合は、質問内容にマルチポストをする理由を書き、他のサイトの投稿へのリンクを貼ってください。 また、解決した際には必ずteratail及びすべての投稿に解決した旨と、どのように解決したかを記載してください。」

[ghwchikxpgns]

取り敢えずteratailを知らない人の為に、複数のサイトに投稿した方がどちらかに回答がつくと考え投稿しました。
そして片方に回答が付き、解決したら未回答の方のサイトに解決URLを貼るつもりで考えていました。
マルチポストの推奨がされていないことから、teratailで解決した為、知恵袋の方は削除しました。

[1T2R3M4]

>マルチポストの推奨がされていないこと
登録した時からわかっていたことでは。
質問する時にも項目は表示されていたような気がしますが。

[thkana]

> 知恵袋の方は削除しました。
解決には至らなかったにしても、あなたの質問に多少なりとも時間を使った回答者の行為?好意は無に帰しても構わない、という考えなのですね。

Answer 1

bezierではbeginShapeは効いていないというか、それぞれ単独の曲線になっている気がします。
bezierVertexなら一連の曲線と認識されます。
bezier() / Reference / Processing.org
bezierVertex() / Reference / Processing.org

void setup() {
  size(960, 960);
}

void draw() {
  background(255);
  fill(255, 0, 0);
  translate(width/2, height/2);

  int r = 400;
  int p = 4;
  float a = TWO_PI / p;
  float c = tan(a * 0.25) * 4 / 3;

  beginShape();
  vertex(r * cos(HALF_PI), -r * sin(HALF_PI));
  for (int v = 0; v < p; v++) {
    float x0_0 = r * cos(a * v + HALF_PI);
    float y0_0 = r * sin(a * v + HALF_PI);
    float x1_0 = r * cos(a * (v + 1) + HALF_PI);
    float y1_0 = r * sin(a * (v + 1) + HALF_PI);
    float x0_1 = x0_0 - (r * c * cos(a * v));
    float y0_1 = y0_0 - (r * c * sin(a * v));
    float x1_1 = x1_0 + (r * c * cos(a * (v + 1)));
    float y1_1 = y1_0 + (r * c * sin(a * (v + 1)));

    //bezier(x1, y1, cpx1, cpy1, cpx2, cpy2, x2, y2);
    //bezier(x0_0, -y0_0, x0_1, -y0_1, x1_1, -y1_1, x1_0, -y1_0);

    //bezierVertex(cpx1, cpy1, cpx2, cpy2, x, y);
    bezierVertex(x0_1, -y0_1, x1_1, -y1_1, x1_0, -y1_0);
  }
  endShape();
}

---

目的がよくわかりませんがarcは使えないでしょうか。
arc() / Reference / Processing.org

Answer 2

「Processingで正n角形を描画し、塗りつぶせ。」という問題が出されたとき、
本来ならvertex()を使わなければならないところをline()でやっているのと似たような問題でしたね。

わざわざ回答ありがとうございます。
無事に解決しました。