VBAで「数字が1文字のとき全角で表示する」マクロを作成したいです

Question

VBAを使用して「1文字の数字は全角、2文字以上の数字は半角」になるようなマクロを作成したいと考えています。

当方初心者のためプロシャージャの考え方がまだ完全に理解できておりません。
以下のコードにおいて、おそらくSub Macro1()とEnd Subの間の行に
何かしらを入れるのだと思いますが、何が正しいか分からず困っております。
2行目にいれるコードについてご教授いただきたいです。
どうぞよろしくお願いいたします。

＝＝＝＝＝＝＝＝以下作成途中のコード＝＝＝＝＝＝＝＝＝＝＝

Sub Macro1()
    
End Sub

'文字列中の１桁の数字のみ全角にする関数
Function Num1ColWide(Source) As String

End Function
Dim Buf As String, flg As Boolean, i As Integer
    If IsNull(Source) Then Exit Function
    Num1ColWide = StrConv(Source, vbNarrow)
    For i = 1 To Len(Num1ColWide)
        Buf = Mid(Source, i, 1)
        If IsNumeric(Buf) And Not flg Then
            If Not IsNumeric(Mid(Source, i + 1, 1)) Then
                Mid(Num1ColWide, i, 1) = StrConv(Buf, vbWide)
            End If
        End If
        flg = IsNumeric(Buf)
    Next
End Function

Answer 1

まず、簡単な説明として、
procedure(プロシージャ)＝返り値(戻り値)がないもの、
Function(ファンクション)＝返り値(戻り値)があるものとお考え下さい。
回答には届きませんが、個人的に気になったので少々添削させていただきます。
あと、VBAといってもAccessかExcelかでだいぶ変わると個人的には思うので、そこらへんも記載していただけると回答者的には助かります。

加えて、質問者様の「1文字の数字は全角、2文字以上の数字は半角」のマクロを作成したあとが気になります。
Excelならセルに記載するのでしょうか？　Accessならフォームに転記するのでしょうか？
そこによってSub Macro1()の内容も変動しますことをご承知おきください。
下はあくまでも一例です。

Sub Macro1()
    
  Dim source, txt As String
  
  source = Worksheets("sheet1").Cells(1, 1).Value
  txt = Num1ColWide(source)
  Worksheets("sheet1").Cells(1, 2).Value = txt
  

End Sub

'文字列中の１桁の数字のみ全角にする関数
Function Num1ColWide(ByVal source As String) As String

Dim Buf As String, num As Integer

    If IsNull(source) Then Exit Function
    Buf = StrConv(source, vbNarrow)
    If Len(Buf) > 1 Then
    Num1ColWide = Buf
    End
    Else
    Num1ColWide = StrConv(Buf, vbWide)
    End If
    
End Function

Answer 2

まず、関数の方に、余分なEnd Functionがあるのでそれを削除します。

'文字列中の１桁の数字のみ全角にする関数
Function Num1ColWide(Source) As String
    Dim Buf As String, flg As Boolean, i As Integer
    If IsNull(Source) Then Exit Function
    Num1ColWide = StrConv(Source, vbNarrow)
    For i = 1 To Len(Num1ColWide)
        Buf = Mid(Source, i, 1)
        If IsNumeric(Buf) And Not flg Then
            If Not IsNumeric(Mid(Source, i + 1, 1)) Then
                Mid(Num1ColWide, i, 1) = StrConv(Buf, vbWide)
            End If
        End If
        flg = IsNumeric(Buf)
    Next
End Function

これで関数が使えるようになります。
で、この関数を使った何をしたいかが、不明ですが、
例えば、A1セルに入力されいるテキストを変換して、B1セルに表示させたいのなら、下記のようなコードになります。

Sub Macro1()
    Range("B1").Value = Num1ColWide(Range("A1").Value)
End Sub

列に入力されているセルを変換してB列に表示する場合は、ループ処理で1セルずつ変換します。

Sub Macro1()
    Dim r As Range
    For Each r In Columns("A").SpecialCells(xlCellTypeConstants)
        r.Offset(, 1) = Num1ColWide(r)
    Next
End Sub

Comments

[miya_machi]

回答ありがとうございました！！！大変助かりました。
質問が言葉足らずで申し訳ありませんでした。
ちなみに、「A1セルに入力されているセルを変換してB1セルに表示」ではなく、「A列に入力されているセルを変換してB列に表示」の場合はどのような書き方になりますでしょうか…
Columnsなど試行錯誤したのですが、そうするとその後のFunctionとの型が合わなくなってしまって…

[hatena19]

ループで1セルずつ処理することになります。
回答にコードを追記しましたので参照ください。